10

我在 Fortran 可执行文件中有一个函数，我需要将其设为 dll 文件，以便可以从 C# 程序调用它的函数

      FUNCTION TSAT11(P) 
C     ** IGNORE IMPLEMENTATION **
      TSAT11 = SX*TSAT2(X) + SXL1*TSAT3-273.15 
      RETURN 
      END

P 是一个浮点数，函数返回一个浮点数

这里的事情我对fortran一无所知，也不从C#调用dll，所以请多解释一下。

我正在使用 Compaq Visual Fortran 和 C# 2008。

感谢您的时间。

（如果你喜欢你可以在这里查看完整的代码[这是一个计算水和蒸汽特性的程序]）

4

2 回答 2

11

这是一个使用单精度浮点数的示例。

Fortran 库包含：

FUNCTION TSAT11(P) 
!DEC$ ATTRIBUTES ALIAS:'TSAT11' :: TSAT11
!DEC$ ATTRIBUTES DLLEXPORT :: TSAT11
!DEC$ ATTRIBUTES VALUE :: P
REAL, INTENT(IN) :: P   
REAL :: TSAT11
    ! Examle calculation
    TSAT11 = P - 273.15
RETURN 
END FUNCTION

带调用功能

class Program
{
    [DllImport("calc.dll")]
    static extern float TSAT11(float P);

    static void Main(string[] args)
    {
        float p = 300f;
        float t = TSAT11(p);
        // returns 26.8500061
    } 
 }

同样对于数组（必须声明大小）

FUNCTION TSAT12(P,N) 
!DEC$ ATTRIBUTES ALIAS:'TSAT12' :: TSAT12
!DEC$ ATTRIBUTES DLLEXPORT :: TSAT12
!DEC$ ATTRIBUTES VALUE :: N
INTEGER, INTENT(IN) :: N
REAL, INTENT(IN) :: P(N)
REAL :: TSAT12
    ! Examle calculation
    TSAT12 = SQRT( DOT_PRODUCT(P,P) )
RETURN 
END FUNCTION

带调用C#代码

class Program
{
    [DllImport("calc.dll")]
    static extern float TSAT12(float[] P, int N);

    static void Main(string[] args)
    {
        float[] p2=new float[] { 0.5f, 1.5f, 3.5f };
        float t2=TSAT12(p2, p2.Length);
        //returns 3.84057283
    } 
 }
于 2012-04-25T14:56:54.223 回答
1

您可以使用 P/Invoke。这是一篇提供示例的文章。至于将您的 Fortran 代码编译成非托管 DLL，您可以在 CVF 中创建一个 DLL 项目。

于 2012-04-25T14:26:59.123 回答