4

我在以下链接有网络服务：http: //abc.com/asmx

我已使用以下代码向 webservice getcustomers 发出请求：

<%
DIM PostData, strStatus, strRetVal, postUrl

PostData = _
"<?xml version=""1.0"" encoding=""utf-8""?>" &_
"<soap:Envelope xmlns:env=""http://www.w3.org/2001/XMLSchema-instance"" &_
"xmlns:xsd='http://www.w3.org/2001/XMLSchema'" &_
"xmlns:soap=""http://schemas.xmlsoap.org/soap/envelope/"">" &_
  "<soap:Body>" &_
  " <getCustomer xmlns=""http://3dcart.com/"">" &_
  "<storeUrl>www.abc.stores.com/</storeUrl>" &_
  "<userKey>sdfsf</userKey>" &_
  "<batchSize>1</batchSize>" &_
  "<startNum>1</startNum>" &_
   "<customersFilter>firstname=John</customersFilter>"&_ 
    "<callBackURL></callBackURL>"&_ 
    "</getCustomer>"&_
     "</soap:Body>" &_
"</soap:Envelope>"

response.write("req=" & Server.HTMLEncode(PostData) & "<br/>len=" & len(PostData))
postUrl = "http://abc.com/cart.asmx?op=getCustomer"
Set xmlHTTP = Server.CreateObject("MSXML2.ServerXMLHTTP")
xmlHTTP.open "POST", postUrl, false
xmlHTTP.setRequestHeader "Content-Type", "text/xml; charset=utf-8" 
'xmlHTTP.setRequestHeader "SOAPAction", "http://AvailReceive/AvailRq"
xmlHTTP.send PostData
strStatus = xmlHTTP.Status
strRetval = xmlHTTP.responseText
set xmlHTTP = nothing
response.write("<br/>") 
response.write("status=" & strStatus & "<br/>resp=" & strRetval)
%>

但我收到错误：resp=soap:ReceiverServer 无法处理请求。---> 'http' 是一个意外的标记。期待空白。第 1 行，位置 163。

你能告诉我为什么会出现这个错误，解决方法是什么。

4

1 回答 1

3

是的：

您收到 500 错误（“预期空白”）的原因是您的消息格式错误。您在 xml 消息中有几个 xmlns 声明，并且由于 vbscript 中的错误，它们之间没有空格。结果是无效的 XML，服务器因此返回错误。

还：

  • 您实际上不需要前缀env和xsd消息中的名称空间声明。它们从不使用。
  • 您也不需要soap前缀。您可以只设置默认的 XML 命名空间。
  • 您可以对 xmlns 声明使用单引号。这可以使代码更具可读性。
  • 您可以在 xml 消息中插入换行符和空格。这也可以使代码更具可读性，特别是出站消息的代码。

使用这些建议的更改，以下是一些正常工作的代码：

Dim msg, strStatus, strRetVal, postUrl

msg = "<?xml version='1.0' encoding='utf-8'?>" &_
         "<Envelope xmlns='http://schemas.xmlsoap.org/soap/envelope/'>" & VbCrLf &_
         "  <Body>" & VbCrLf &_
         "    <getCustomer xmlns='http://abc.com/'>" & VbCrLf &_
         "      <storeUrl>www.abc.com/</storeUrl>" & VbCrLf &_
         "      <userKey>345</userKey>" & VbCrLf &_
         "      <batchSize>1</batchSize>" & VbCrLf &_
         "      <startNum>1</startNum>" & VbCrLf &_
         "      <customersFilter>firstname=John</customersFilter>"& VbCrLf &_
         "      <callBackURL></callBackURL>"& VbCrLf &_
         "    </getCustomer>" & VbCrLf &_
         "  </Body>" & VbCrLf &_
         "</Envelope>"

Response.write("req=" & Server.HTMLEncode(msg) & "<br/>len=" & len(msg))

postUrl = "http://abc.com/cart.asmx?op=getCustomer"

Set xmlHTTP = Server.CreateObject("MSXML2.ServerXMLHTTP")
xmlHTTP.open "POST", postUrl, false
xmlHTTP.setRequestHeader "Content-Type", "text/xml; charset=utf-8"
'xmlHTTP.setRequestHeader "SOAPAction", "http://AvailReceive/AvailRq"
xmlHTTP.send msg

strStatus = xmlHTTP.Status
strRetval = xmlHTTP.responseText
set xmlHTTP = nothing
Response.write("<br/>")
Response.write("status=" & strStatus & "<br/>resp=" & strRetval)

但是……这段代码在 .ASMX 脚本中发现了一个运行时错误。

resp=尝试从存储中获取数据时出错。技术描述：无法解析远程名称：'www.abc.com'

如果我修改传出消息以将主机名指定为abc.com而不是www.abc.com，那么我会得到一个看起来合理的响应。

于 2012-04-25T22:13:47.277 回答