c# - 在 ANTLR 中替换令牌的文本

Question

我正在尝试将输入程序中的某些令牌文本替换为特定的格式化文本。我使用 C# 作为输出语言。

输入示例：

time#1m2s

我对该输入的 lex 语法：

fragment
DIGIT : '0'..'9'
      ;

CTE_DURATION 
    : ('T'|'t'|'TIME'|'time') '#' '-'? (DIGIT ('d'|'h'|'m'|'s'|'ms') '_'?)+
    ;

我想从输入示例中获取的输出令牌文本：

0.0:1:2.0

这意味着：0 天、0 小时、1 分钟、2 秒和 0 毫秒。

有什么建议吗？先感谢您。

Answer 1

这是一种方法（它在 Java 中，但移植到 C# 应该不难）：

grammar Test;

parse
 : CTE_DURATION EOF
 ;

CTE_DURATION 
 : ('T' 'IME'? | 't' 'ime'?) '#' minus='-'?
   (d=DIGITS 'd')? (h=DIGITS 'h')? (m=DIGITS 'm')? (s=DIGITS 's')? (ms=DIGITS 'ms')?
   {
     int days = $d == null ? 0 : Integer.valueOf($d.text);
     int hours = $h == null ? 0 : Integer.valueOf($h.text);
     int minutes = $m == null ? 0 : Integer.valueOf($m.text);
     int seconds = $s == null ? 0 : Integer.valueOf($s.text);
     int mseconds = $ms == null ? 0 : Integer.valueOf($ms.text);
     setText(($minus == null ? "" : "-") + days + "." + hours + ":" + minutes + ":" + seconds + "." + mseconds);
   }
 ;

fragment DIGITS : '0'..'9'+;

time#1m2s在以下解析树中解析输入结果：

请注意，语法现在time#也接受（导致它产生0.0:0:0.0），但您可以轻松地从词法分析器规则中产生异常，以防此类输入无效。