1

@solved 使用相同代码的 C# 速度是原来的两倍

我正在用 perl 解析一个 phred33 fastq 文件，这需要相当长的时间（大约 15 分钟）。fastq 文件大约 3 gigs。有什么合理的方法可以加快速度吗？

$file=shift;
open(FILE,$file);
open(FILEFA,">".$file.".fa");
open(FILEQA,">".$file.".qual");
while($line=<FILE>)
{
    chomp($line);
    if($line=~m/^@/)
    {


    $header=$line;
    $header =~ s/@/>/g;
    $seq=<FILE>;
    chomp($seq);
    $nothing=<FILE>;
    $nothing="";
    $fastq=<FILE>;

    print FILEFA $header."\n";
    print FILEFA $seq."\n";
    $seq="";
    print FILEQA $header."\n";

        @elm=split("",$fastq);
        $i=0;
        while(defined($elm[$i]))
        {
            $Q = ord($elm[$i]) - 33;
            if($Q!="-23")
            {
            print FILEQA $Q." ";
            }
            $i=$i+1;
        }
        print FILEQA "\n";
    }
}
print $file.".fa\n";
print $file.".qual\n";
4

1 回答 1

1

这里几乎没有使用 CPU。它是 IO 绑定的，所以主要是读取 3GB 的时间。可以进行微优化（和其他清理）。

首先，始终使用use strict; use warnings;.

主要代码是

my @elm = split(//, $fastq);
my $i=0;
while(defined($elm[$i])) {
    my $Q = ord($elm[$i]) - 33;
    if($Q!="-23") {
        print FILEQA $Q." ";
    }
    $i=$i+1;
}

的目的if($Q!="-23")是检查字符是否是换行符，如果你这样做了，你就不必这样做了chomp($fastq);。（周围的引号是-23什么？！）

chomp($fastq);
my @elm = split(//, $fastq);
my $i=0;
while(defined($elm[$i])) {
    my $Q = ord($elm[$i]) - 33;
    print FILEQA $Q." ";
    $i=$i+1;
}
print FILEQA "\n";

使用while循环只会使事情复杂化。当迭代次数已知时，使用 for 循环。

chomp($fastq);
for (split(//, $fastq)) {
    print FILEQA (ord($_)-33)." ";
}
print FILEQA "\n";

把它翻过来可能会有所帮助。

chomp($fastq);
print FILEQA join(' ', map ord($_)-33, split //, $fastq), "\n";

再想一想，里面还不够:)

$fastq =~ s/(.)/(ord($1)-33) . " "/eg;
print FILEQA $fastq;

但是我们预先计算的翻译是什么？这样我们就不必/e重复调用 sub（代码）了。

my %map = map { chr($_) => ($_-33)." " } 0x00..0xFF;

$fastq =~ s/(.)/$map{$1}/g;
print FILEQA $fastq;

经过一番清理后，我们得到：

use strict;
use warnings;

my %map = map { chr($_) => ($_-33)." " } 0x00..0xFF;

my $file = shift;

my $fa_file   = "$file.fa";
my $qual_file = "$file.qual";

open(my $FILE,   '<', $file     ) or die $!;
open(my $FILEFA, '>', $fa_file  ) or die $!;
open(my $FILEQA, '>', $qual_file) or die $!;

while (my $header = <$FILE>) {
    next if $header !~ /^@/;

    my $seq = <$FILE>;
    <$FILE>;
    my $fastq = <$FILE>;

    $header =~ s/@/>/g;
    $fastq =~ s/(.)/$map{$1}/g;

    print $FILEFA $header;
    print $FILEFA $seq;

    print $FILEQA $header;
    print $FILEQA $fastq;
}

print "$fa_file\n";
print "$qual_file\n";
于 2012-04-24T21:55:09.080 回答