2

PHP 和 ColdFusion9 中的 AES 加密产生了不同的结果。有人可以帮我吗？

下面的 PHP 代码

$key = "12345678123456781234567812345678";
$iv = "1234567812345678";
$data = "This is a plain string.";

echo base64_encode(mcrypt_encrypt(MCRYPT_RIJNDAEL_128, $key, $data, MCRYPT_MODE_CBC, $iv));

给我 G+tdEOfQTtVCQGxW3N5uzkqN207OyfIPxS6zf2xrKKY=

而下面的 ColdFusion 代码

<cfset thePlainData  = "This is a plain string." />
<cfset theKey    = "12345678123456781234567812345678" />
<cfset theAlgorithm  = "AES/CBC/PKCS5Padding" />
<cfset theEncoding  = "base64" />
<cfset theIV    = "1234567812345678" />

<cfset encryptedString = encrypt(thePlainData, theKey, theAlgorithm, theEncoding, theIV) />

给我 KLt55n5/T3ee6xVq9VGFbyCacJznkHEqC/RDRhL+4nw=

知道我哪里错了吗？提前致谢。

4

2 回答 2

6

不幸的是，ColdFusion 和 PHP 实现之间在使用的纯文本填充样式方面存在轻微的不兼容。AES 要求明文块大小可被 128 整除。为此，PHP 将使用 NULL 字符填充明文输入以获得正确的块大小。ColdFusion 可以使用Java 支持的各种填充技术。不幸的是，ColdFusion 和 Java 都支持 NULL 填充模式，这使得互操作性更加困难。ColdFusion 的字符串处理不支持 NULL 字符，因此您需要在 PHP 中实现 PKCS5Padding 模式，以使它们能够正确地互操作。

此外，正如评论中提到的，ColdFusion 将期望密钥是 base64 编码的，因此您需要密钥设置如下所示：

<cfset theKey = toBase64("12345678123456781234567812345678") />

此外，默认情况下 Java（以及扩展的 ColdFusion）仅支持最大 128 位的密钥大小。在这里，您使用的是 256 位密钥，这需要 Java Unlimited Strength 扩展（对于那些试图测试代码并获得非法密钥大小错误的人）。

生成的 PHP 代码如下所示：

// Function from http://us3.php.net/manual/en/ref.mcrypt.php#69782
function pkcs5_pad ($text, $blocksize)
{
    $pad = $blocksize - (strlen($text) % $blocksize);
    return $text . str_repeat(chr($pad), $pad);
}

$key = "12345678123456781234567812345678";
$iv = "1234567812345678";
// Pad data with PKCS #5 to prevent PHP from using NULL padding.
$data = pkcs5_pad("This is a plain string.", 16);

echo base64_encode(mcrypt_encrypt(MCRYPT_RIJNDAEL_128, $key, $data, MCRYPT_MODE_CBC, $iv));

生成的 ColdFusion 代码如下所示：

<cfset thePlainData = "This is a plain string." />
<cfset theKey = toBase64("12345678123456781234567812345678") />
<cfset theAlgorithm = "AES/CBC/PKCS5Padding" />
<cfset theEncoding = "base64" />
<cfset theIV = "1234567812345678" />

<cfset encryptedString = encrypt(thePlainData, theKey, theAlgorithm, theEncoding, theIV) />

<cfoutput>#encryptedString#</cfoutput>

两者都输出相同的 base64 编码字符串：

G+tdEOfQTtVCQGxW3N5uzlu0mGabRKNxuIdAXArQE80=
于 2012-04-25T05:35:02.520 回答
0

我知道这是一个旧线程，但最近出现了类似的问题。

虽然本机不支持，但事实证明有一种方法可以在 CF 中生成空填充。Artjom B. 的这个答案同意在 PHP 中调整填充可能更简单，但指出您可以使用 0x00 将纯文本填充到算法块大小的倍数 并使用“NoPadding”方案来实现相同的结果。

在 CF 中生成空字符有点棘手，但可以使用 URLDecode("%00")来完成。由于 encrypt() 始终将输入视为 UTF-8 编码，因此您还可以使用 charsetEncode() 从单个元素字节数组（即charsetEncode( javacast("byte[]", [0] ), "utf-8").

没有经过高度测试，但这样的事情应该在 CF10 中产生相同的结果：

代码：

thePlainData = nullPad("This is a plain string.", 16);
// NB: JCE unlimited policy files required for 256 bit keys
theKey = toBase64("12345678123456781234567812345678");
theIV  = "1234567812345678";

encryptedString = encrypt(thePlainData, theKey, "AES/CBC/NoPadding", "base64", theIV);

结果：

G+tdEOfQTtVCQGxW3N5uzkqN207OyfIPxS6zf2xrKKY=

功能：

/*
   Pads a string, with null bytes, to a multiple of the given block size

   @param plainText - string to pad
   @param blockSize - pad string so it is a multiple of this size
   @param encoding - charset encoding of text
*/
string function nullPad( string plainText, numeric blockSize, string encoding="UTF-8")
{
    local.newText = arguments.plainText;
    local.bytes = charsetDecode(arguments.plainText, arguments.encoding);
    local.remain = arrayLen( local.bytes ) % arguments.blockSize;

    if (local.remain neq 0) 
    {
        local.padSize = arguments.blockSize - local.remain;
        local.newText &= repeatString( urlDecode("%00"), local.padSize );
    }

    return local.newText;
}
于 2015-03-08T18:28:12.530 回答