1

我有这个 XML：

<Year>
  <Movies>
    <Add>
        <Key>movie1</Key>
        <Value>black</Value>
    </Add>
    <Add>
        <Key>movie2</Key>
        <Value>white</Value>
    </Add>
  </Movies>
</Year>

这需要转换成这个 XML，并以特殊的星号作为起始字符：

<Year>
    <MovieList>*movie1-black,movie2-white<MovieList>
</Year>

我已经尝试了几种 xslt 转换的变体，而且我到处都是。这是我最新的 hack。现在在 XML 工具中摆弄这个...

<xsl:template match="b:Year">
 <xsl:copy>
   <xsl:for-each select="*">
      <xsl:element name="MovieList">
        <xsl:for-each select="./b:Movies/b:Add">
          <xsl:if test="position() = 1">*</xsl:if>
          <xsl:value-of select="./b:Key"/>-<xsl:value-of select="./b:Value"/>
          <xsl:if test="position() != last()">,</xsl:if>
        </xsl:for-each>
      </xsl:element>
   </xsl:for-each>
  <xsl:apply-templates select="node()"/>
 </xsl:copy>
</xsl:template>

任何 xslt 专家对此有一些指导吗？谢谢！

4

2 回答 2

0

以下是您可以使用 XSLT 1.0 执行的操作：

 <xsl:stylesheet version="1.0"
     xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
     <xsl:output omit-xml-declaration="yes" indent="yes"/>

     <xsl:template match="Year/Movies">
        <Year>
          <xsl:variable name="movielist">
            <xsl:for-each select="Add">
              <xsl:value-of select="concat(Key, '-', Value, ',')"/>
            </xsl:for-each>
          </xsl:variable>
          <MovieList>
              <xsl:value-of select="concat('*',substring($movielist, 0, string-length($movielist)))"/>
          </MovieList>
        </Year>
    </xsl:template>
</xsl:stylesheet>

鉴于您的输入，它会产生：

<Year>
   <MovieList>*movie1-black,movie2-white</MovieList>
</Year>

您可以更巧妙地利用 XSLT 2.0 的separator属性，xsl:value-of正如在类似示例中所解释的那样：Dimitre 的concatenation two fields in xsl

于 2012-04-24T02:04:28.033 回答
0

I. 这个简单高效的 XSLT 1.0 转换（无变量，无结果后处理）：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="/*">
    <Year>
     <xsl:apply-templates/>
    </Year>
 </xsl:template>

 <xsl:template match="Movies">
  <MovieList>
   <xsl:apply-templates/>
  </MovieList>
 </xsl:template>

 <xsl:template match="Add">
  <xsl:value-of select="substring('*,', 2 - (position()=1),1)"/>
  <xsl:value-of select="concat(Key, '-', Value)"/>
 </xsl:template>
</xsl:stylesheet>

应用于提供的 XML 文档时：

<Year>
    <Movies>
        <Add>
            <Key>movie1</Key>
            <Value>black</Value>
        </Add>
        <Add>
            <Key>movie2</Key>
            <Value>white</Value>
        </Add>
    </Movies>
</Year>

产生想要的正确结果：

<Year>
   <MovieList>*movie1-black,movie2-white</MovieList>
</Year>

二、XSLT 2.0 解决方案：

<xsl:stylesheet version="2.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="/*">
    <Year>
     <xsl:apply-templates/>
    </Year>
 </xsl:template>

 <xsl:template match="Movies">
  <MovieList>
   <xsl:sequence select="'*'[current()/Add]"/>
   <xsl:value-of select="Add/concat(Key, '-', Value)"
        separator=","/>
  </MovieList>
 </xsl:template>
</xsl:stylesheet>
于 2012-04-24T02:42:42.730 回答