4

我需要制作一个 XML 文件——而合作伙伴对标题很感兴趣。显然，标题必须是这样的：

<?xml version="1.0"?>

但是每当我创建一个 XML 文件时，我都会得到这样的无关属性：

<?xml version="1.0" encoding="utf-8" standalone="yes"?>

我内心的黑客想要停止使用 XMLWriter 来制作文件，以便我对标题有更多的控制权；“没问题，我只写一个循环，让它自己的 XML 标记为 StreamWriter 什么的，忘记这个 XMLWriter 对象……” 但我必须承认，到目前为止，XMLWriter 使用起来相当优雅；肯定有一些东西可以让我更改 XMLWriterSettings 对象以说“请停止将您的自定义属性放入 XML 标头”，对吧？

这是相关的VB代码：

    Dim settings As New XmlWriterSettings()
    settings.Indent = True
    settings.IndentChars = "    "
    settings.NewLineChars = "\n"
    Using writer As XmlWriter = XmlWriter.Create(strFileName, settings)
            writer.WriteStartDocument(True)
            For Each kvp As KeyValuePair(Of String, String) In dictArguments

                 Dim key As String = kvp.Key
                 Dim value As String = kvp.Value

                 writer.WriteStartElement(key)
                 writer.WriteString(value)
                 writer.WriteEndElement()

            Next

    End Using

完美运行；但我找不到控制标题的方法。我当然可以找到一种完全删除它的方法，但这不是我们想要做的。

编辑：感谢您的帮助；到目前为止，一旦我们删除了 WriteStartDocument，它现在不再显示 Standalone = yes。但是，我无法停止添加编码。有任何想法吗？

4

5 回答 5

10

这样做的一种方法是使用 WriteProcessingInstruction 方法自己控制初始处理指令，因此： 

    Dim settings As New XmlWriterSettings()
    settings.Indent = True
    settings.IndentChars = "    "
    Using writer As XmlWriter = XmlWriter.Create(strFileName, settings)
        writer.WriteProcessingInstruction("xml", "version='1.0'")
        writer.WriteStartElement("root")
        For Each kvp As KeyValuePair(Of String, String) In dictArguments

            Dim key As String = kvp.Key
            Dim value As String = kvp.Value

            writer.WriteStartElement(key)
            writer.WriteString(value)
            writer.WriteEndElement()

        Next
        writer.WriteEndElement()

    End Using

请注意，我还添加了一个“根”元素，以防您的字典包含多个元素（我猜字典键值都不是“根”:)

于 2009-06-22T16:44:28.607 回答
2

我知道这个问题被问到已经几个月了，但是我觉得有必要提到一个我偶然发现的（长期存在的？）解决方案。它确实取消了整个 xmldeclaration，您需要做的只是通过编写处理指令来重写您需要的声明。

XmlFragmentWriter - 省略 Xml 声明以及 XSD 和 XSI 命名空间

这是VB中的类

Imports System.Xml
Imports System.IO
Imports System.Text

Class XmlFragmentWriter
Inherits XmlTextWriter

Public Sub New(ByVal w As TextWriter)
    MyBase.New(w)
End Sub

Public Sub New(ByVal w As Stream, ByVal encoding As Encoding)
    MyBase.New(w, encoding)
End Sub

Public Sub New(ByVal filename As String, ByVal encoding As Encoding)
    MyBase.New(New FileStream(filename, FileMode.Create, FileAccess.Write, FileShare.None), encoding)
End Sub


Private _skip As Boolean = False

Public Overrides Sub WriteStartAttribute(ByVal prefix As String, ByVal localName As String, ByVal ns As String)
    ' STEP 1 - Omits XSD and XSI declarations. 
    ' From Kzu - http://weblogs.asp.net/cazzu/archive/2004/01/23/62141.aspx
    If prefix = "xmlns" AndAlso (localName = "xsd" OrElse localName = "xsi") Then
        _skip = True
        Return
    End If
    MyBase.WriteStartAttribute(prefix, localName, ns)

End Sub

Public Overrides Sub WriteString(ByVal text As String)
    If _skip Then
        Return
    End If
    MyBase.WriteString(text)

End Sub

Public Overrides Sub WriteEndAttribute()
    If _skip Then
        ' Reset the flag, so we keep writing.
        _skip = False
        Return
    End If
    MyBase.WriteEndAttribute()

End Sub

Public Overrides Sub WriteStartDocument()
    ' STEP 2: Do nothing so we omit the xml declaration.
End Sub
End Class

以及这里的用法：

    Dim f As New XmlSerializer(GetType(OFXg))
      Dim w As New XmlFragmentWriter("c:\books1.xml", Nothing)
      w.Formatting = Formatting.Indented
      w.WriteProcessingInstruction("xml", "version=""1.0""")
      f.Serialize(w, RTofx)
      w.Close()

当然，OFXg 类是 XMLSerializable

于 2010-10-06T11:16:46.750 回答
1

为什么您认为标题中有自定义属性？

WriteStartDocument 写入带有或不带有独立属性的标题。您的代码添加了您说您的合作伙伴不接受的属性。

您没有显示用于生成“utf-16”的代码，但我怀疑它写入了 StringWriter。.NET 中的字符串始终是 UNICODE，当您写入字符串时，您总是会得到 utf-16。如果您写入流，您可以控制编码。

于 2009-06-22T16:01:35.193 回答
0

死灵术。

您可以创建自己的 XmlTextWriter 并覆盖 WriteStartDocument。

例子：

public class XmlTextWriterIndentedStandaloneNo : System.Xml.XmlTextWriter
{

    public bool bStandAlone = false;
    public bool bWriteStartDocument = true;
    public bool bOmitEncodingAndStandAlone = true;


    public XmlTextWriterIndentedStandaloneNo(System.IO.TextWriter w)
        : base(w)
    {
        Formatting = System.Xml.Formatting.Indented;
    } // End Constructor 


    public XmlTextWriterIndentedStandaloneNo(string strFileName, System.Text.Encoding teEncoding)
        : base(strFileName, teEncoding)
    {
        Formatting = System.Xml.Formatting.Indented;
    } // End Constructor 


    public XmlTextWriterIndentedStandaloneNo(System.IO.Stream w, System.Text.Encoding teEncoding)
        : base(w, teEncoding)
    {
        Formatting = System.Xml.Formatting.Indented;
    } // End Constructor 


    public override void WriteStartDocument(bool standalone)
    {
        if (bWriteStartDocument)
        {
            if (bOmitEncodingAndStandAlone)
            {
                this.WriteProcessingInstruction("xml", "version='1.0'");
                return;
            } // End if (bOmitEncodingAndStandAlone) 

            base.WriteStartDocument(bStandAlone);
        }

    } // End Sub WriteStartDocument 


    public override void WriteStartDocument()
    {
        // Suppress by ommitting WriteStartDocument
        if (bWriteStartDocument)
        {

            if (bOmitEncodingAndStandAlone)
            {
                this.WriteProcessingInstruction("xml", "version='1.0'");
                return;
            } // End if (bOmitEncodingAndStandAlone)

            base.WriteStartDocument(bStandAlone);
            // False: Standalone="no"
        } // End if (bWriteStartDocument)

    } // End Sub WriteStartDocument 


} // End Class XmlTextWriterIndentedStandaloneNo

VB.NET

Public Class XmlTextWriterIndentedStandaloneNo
    Inherits System.Xml.XmlTextWriter

    Public bStandAlone As Boolean = False
    Public bWriteStartDocument As Boolean = True
    Public bOmitEncodingAndStandAlone As Boolean = True


    Public Sub New(w As System.IO.TextWriter)
        MyBase.New(w)
        Formatting = System.Xml.Formatting.Indented
    End Sub
    ' End Constructor 

    Public Sub New(strFileName As String, teEncoding As System.Text.Encoding)
        MyBase.New(strFileName, teEncoding)
        Formatting = System.Xml.Formatting.Indented
    End Sub
    ' End Constructor 

    Public Sub New(w As System.IO.Stream, teEncoding As System.Text.Encoding)
        MyBase.New(w, teEncoding)
        Formatting = System.Xml.Formatting.Indented
    End Sub
    ' End Constructor 

    Public Overrides Sub WriteStartDocument(standalone As Boolean)
        If bOmitEncodingAndStandAlone Then
            Me.WriteProcessingInstruction("xml", "version='1.0'")
            Return
        End If
        ' End if (bOmitEncodingAndStandAlone) 
        If bWriteStartDocument Then
            MyBase.WriteStartDocument(bStandAlone)
        End If
    End Sub
    ' End Sub WriteStartDocument 

    Public Overrides Sub WriteStartDocument()
        If bOmitEncodingAndStandAlone Then
            Me.WriteProcessingInstruction("xml", "version='1.0'")
            Return
        End If
        ' End if (bOmitEncodingAndStandAlone)
        ' Suppress by ommitting WriteStartDocument
        If bWriteStartDocument Then
                ' False: Standalone="no"
            MyBase.WriteStartDocument(bStandAlone)
        End If
        ' End if (bWriteStartDocument)
    End Sub
    ' End Sub WriteStartDocument 

End Class
' End Class XmlTextWriterIndentedStandaloneNo

使用示例：

//using (System.Xml.XmlTextWriter wr = new System.Xml.XmlTextWriter(System.IO.Path.Combine(strBasePath, "TestFile.xml"), System.Text.Encoding.UTF8))
//using (System.Xml.XmlWriter wr = System.Xml.XmlWriter.Create(System.IO.Path.Combine(strBasePath, "TestFile.xml"), xwsSettings))
using (System.Xml.XmlWriter wr = new XmlTextWriterIndentedStandaloneNo(System.IO.Path.Combine(strBasePath, "TestFile.xml"), System.Text.Encoding.UTF8))
{
    //wr.Formatting = System.Xml.Formatting.None; // here's the trick !

    xdoc.Save(wr);
    wr.Flush();
    wr.Close();
} // End Using wr
于 2014-10-29T12:56:55.107 回答
-1

这：

XmlWriterSettings xmlWriterSettings 
    = new XmlWriterSettings { OmitXmlDeclaration = true, };

会给你这个：

<?xml version="1.0"?>
于 2012-02-16T22:12:43.827 回答