5

我正在编写基于 comint-mode 的派生模式。该模式是命令行程序（GRASS gis）的接口，comint 模式完成适用于这些程序。我正在尝试添加对完成程序参数的支持，通过completion-at-point-functions. 一个玩具示例是：

(setq my-commands 
      '(("ls"
         ("my-completion-1")
         ("my-completion-2"))
        ("mv"
         ("my-completion-3")
         ("my-completion-4"))))


(defun my-completion-at-point ()
  (interactive)
  (let ((pt (point)) ;; collect point
        start end)

    (save-excursion ;; collect the program name
      (comint-bol)
      (re-search-forward "\\(\\S +\\)\\s ?"))
    (if (and (>= pt (match-beginning 1))
             (<= pt (match-end 1)))
        () ;; if we're still entering the command, pass completion on to
      ;; comint-completion-at-point by returning nil

      (let ((command (match-string-no-properties 1)))
        (when (member* command my-commands :test 'string= :key 'car)
          ;; If the command is one of my-commands, use the associated completions 
          (goto-char pt)
          (re-search-backward "\\S *")
          (setq start (point))
          (re-search-forward "\\S *")
          (setq end (point))
          (list start end (cdr (assoc command my-commands)) :exclusive 'no))))))

(push 'my-completion-at-point completion-at-point-functions)

这几乎可以工作。我得到程序名称的正常完成。但是，如果我ls在命令行输入，点击标签插入my-completion-并且不提供这两个选项。再次点击标签会插入my-completion-第二次，所以我现在有了ls my-completion-mycompletion-.

我的实际代码包括几行来检查多行命令，但对完成代码没有任何更改。使用此版本的代码，我在以其中一个程序名称开头的行上点击选项卡，我看到了my-commands一个可能的参数列表来完成命令，但缓冲区中没有插入任何内容，并且列表确实不要通过键入参数的前几个字母来缩小范围。

我已经阅读了手册，但我无法弄清楚编写completion-at-point函数的正确方法。有什么我想念的想法吗？

我已经简要地看了看pcomplete，但并没有真正理解“文档”，也没有取得任何进展。

4

1 回答 1

8

问题似乎出在您查找的方式上，start并end在该点返回参数的边界。我没有花足够长的时间调试它来确定细节，但我认为如果你以交互方式调用该函数，你会看到它为startand返回相同的值end，这意味着完成 UI 不知道使用参数 at point 从您传递的完成表中进行选择。

将函数的最后一部分更改为以下内容似乎是一种解决方法：

(when (member* command my-commands :test 'string= :key 'car)
  ;; If the command is one of my-commands, use the associated completions 
  (goto-char pt)
  (let ((start
         (save-excursion
           (skip-syntax-backward "^ ")
           (point))))

    (list start pt (cdr (assoc command my-commands)) :exclusive 'no)))))))

当添加为 的元素时，这给出了预期的结果completion-at-point-functions。

在这里，我使用skip-syntax-backward了 regexp search 而不是 regexp 搜索，我认为这对于这种事情来说是更惯用的 Elisp。它只是说将点向后移动到不在语法类“空白”中的任何内容。跳过语法函数返回移动的距离而不是点的值，因此我们必须point在保存游览结束时添加一个调用。

如果您确实在这样的函数中使用正则表达式搜索，通常最好传递t第四个参数 ,noerror以便在匹配失败时不会将错误传递给用户。不过，这确实意味着您必须自己检查返回值是否为nil。

最后，push您可能希望add-hook按如下方式添加完成功能，而不是添加完成功能：

(add-hook 'completion-at-point-functions 'my-completion-at-point nil t)

这做了两件有用的事情：它在添加之前检查你的函数是否已经在钩子中，并且（通过传递t第四个参数，local）它只将函数添加到完成点钩子的缓冲区本地值。这几乎肯定是您想要的，因为当您按下 TAB 键时，您不想在每个其他 Emacs 缓冲区中使用这些完成。

于 2012-04-23T09:17:52.977 回答