34

鉴于这段代码：

       swap:

            push ebp ; back up the base pointer,
            mov ebp, esp
            ; push the context of the registers on the stack

            push eax
            push ebx
            push ecx
            push edx

            mov eax, [ebp+8] ; address of the first parameter
            mov ebx, [ebp+12] ; address of the second parameter
            mov dl, [eax]
            mov cl, [ebx]

            mov [eax], cl

            mov [ebx], dl

            ; restore the context of the registers from the stack

            pop edx
            pop ecx  
            pop ebx
            pop eax
            ; restore the ebp
            pop ebp
            ret

（这只是方法。之前我们将第一个和第二个参数压入堆栈。）

我的问题是：为什么我们将 8 添加到 Base Pointer 以获取第一个参数的地址，然后 12 ？

我知道它们是双字，所以它们每个都是 4 个字节..所以从 ebp + 8 到 ebp + 12 是有意义的。但是为什么第一个是 ebp + 8 ？因为如果ESP指向栈顶，mov ebp,esp表示EBP指向栈顶。然后我们将 4 个值压入堆栈：eax、ebx、ecx 和 edx。为什么 EBP + 8 指向第一个参数？

4

2 回答 2

51

调用该函数时，堆栈如下所示：

+-------------+
| Parameter 2 |
+-------------+
| Parameter 1 |
+-------------+
| Return Addr |  <-- esp
+-------------+

然后在“堆栈框架”设置后：

+-------------+
| Parameter 2 | <-- [ebp + 12]
+-------------+
| Parameter 1 | <-- [ebp + 8]
+-------------+
| Return Addr |  
+-------------+    
| saved ebp   | <-- ebp
+-------------+ <-- esp

现在保存上下文：

+-------------+
| Parameter 2 | <-- [ebp + 12]
+-------------+
| Parameter 1 | <-- [ebp + 8]
+-------------+
| Return Addr |  
+-------------+    
| saved ebp   | <-- ebp
+-------------+ 
| saved eax   |  
+-------------+    
| saved ebx   |  
+-------------+    
| saved ecx   |  
+-------------+    
| saved edx   | <-- esp
+-------------+

不要忘记，在许多系统上堆栈是向下增长的（x86 系列肯定是这样），所以堆栈的顶部将具有最低的内存地址。

于 2012-04-22T01:41:29.210 回答
7

因为堆栈上还有另外两个项目；前一个 ebp，您在此例程的开头推送，以及返回地址，通过对例程的调用将其放入堆栈。

于 2012-04-22T01:41:54.067 回答