5

我有一个使用DBI连接的 Perl 脚本。我使用子例程打开并读取 SQL 脚本文件。我只打印一条记录，我应该再打印两条（总共三条记录）。如何获取所有记录？

结果：

Alert:OUTBOUND_DATA:0

脚本：

my $dbh_oracle = DBI->connect(
          $CFG{oracle_dbi_connect},
          $CFG{db_user},
          $CFG{db_cred},
          {AutoCommit => 0,
           RaiseError => 0,
           PrintError => 0}) or die ("Cannot connect to the database: ".$DBI::errstr."\n");

my ($val1, $val2) = get_data();
print "Alert:$val1:$val2\n";

send_email("Alert:$val1:$val2");

sub get_data
{
  undef $/;
  open (my $QFH, "< /sql/summary.sql") or die "error can't open this file $!";
  my $sth= $dbh_oracle->prepare(<$QFH>) or
      die ("Cannot connect to the database: ".$DBI::errstr."\n");
  $sth->execute;
  close $QFH;
  my $row = $sth->fetchrow_hashref;
  $sth->finish;
  return @$row{'MYTABLE','FLAG'};
}

sub send_email {
    my $message = shift;
    open (MAIL, "|/usr/sbin/sendmail -t") or die "Can't open sendmail: $!";
    print MAIL "To: me\@test.com\n";
    print MAIL "From: Data\n";
    print MAIL "\n";
    print MAIL $message;
    close MAIL;
}
exit;

运行查询的结果：（超过 1 个记录）

MYTABLE                  FLAG
----------------------- ----------
OUTBOUND_DATA         0
MSGS_BY_DIM                  0
INBOUND_DATA         0

3 rows selected.
4

4 回答 4

9

您可以通过多种不同的方式从语句句柄中检索数据。最常见的非常简单，它们的使用如下所示：

my @row_array = $sth->fetchrow_array;
my $array_ref = $sth->fetchrow_arrayref;
my $hash_ref  = $sth->fetchrow_hashref;

第一个 fetchrow_array 将依次将每一行作为数组返回。使用从上述选择返回的数据的示例可能是：

while (my @row_array = $sth->fetchrow_array) {
    print $row_array[0], " is ", $row_array[1], " years old, and has a " , 
          $row_array[2], "\n";
}

第二个示例类似，但返回的是数组引用而不是数组：

while (my $array_ref = $sth->fetchrow_arrayref) {
    print $array_ref->[0], " is ", $array_ref->[1], 
          " years old, and has a " , $array_ref->[2], "\n";
}

第三个示例 fetchrow_hashref 通常是最易读的：

while (my $hash_ref = $sth->fetchrow_hashref) {
    print $hash_ref->{name}, " is ", $hash_ref->{age}, 
          " years old, and has a " , $hash_ref->{pet}, "\n";
}
于 2012-04-20T20:16:18.217 回答
3

这一行应该是一个循环：

my $row = $sth->fetchrow_hashref;

它应该是：

my @rows;
while ( my $row = $sth->fetchrow_hashref ) {
    push @rows, $row;
}
return @rows;

如果您希望 DBI 为您执行循环，请查看selectall_arrayref或selectall_hashref

于 2012-04-20T20:06:08.310 回答
3

它还取决于您如何构建整个脚本。您的get_data()调用只允许返回一对值。我至少看到了几个选项：要么返回一个包含所有数据的哈希（引用）并让其main组装，要么使用前面提到的循环结构并在子例程中构造消息体，只返回一个标量字符串。

要将所有数据作为哈希引用返回，get_data子例程可能如下所示（注意我使用fetchall_hashref的是fetchrow_hashref：

sub get_data
{
  undef $/;
  open (my $QFH, "< /sql/summary.sql") or die "error can't open this file $!";
  my $sth= $dbh_oracle->prepare(<$QFH>) or
      die ("Cannot connect to the database: ".$DBI::errstr."\n");
  $sth->execute;
  close $QFH;
  my $hash_ref = $sth->fetchall_hashref('MYTABLE');
  $sth->finish;
  return $hash_ref;
}

你调用它main并使用输出如下：

my $hash_ref = get_data();
my $message = "";
foreach my $table (sort keys %$hash_ref) {
    $message .= join(":", "Alert", $table, $$hash_ref{$table}{'FLAG'}) . "\n";
}

这将导致$message包含：

Alert:INBOUND_DATA:0
Alert:MSGS_BY_DIM:0
Alert:OUTBOUND_DATA:0

你可能想礼貌地：

$dbh_oracle->disconnect;

在你退出之前。

这有一些问题，例如，您将 SQL 隐藏在外部脚本中，但我已采用硬编码键（MYTABLE，我假设它在您的查询中是唯一的）和值（FLAG）在脚本，稍后当您想对此进行扩展时会受到限制。

于 2012-04-20T21:34:17.993 回答
2

这些fetchrow_方法实际上一次只获取一行。

如果您想要某些列的所有行，则可以低效地推动数据结构，或者使用针对您的情况的调用。

在我看来，您想使用selectcol_arrayref如下：

my $ary_ref = $dbh->selectcol_arrayref(
    "select id, name from table",
    { Columns=>[1,2] }
);

列索引指的是结果集中列的位置，而不是原始表。

您使用返回结果的方式也需要更改以处理所有返回的行。

此外，您还有：

sub get_data
{
  undef $/;

因为你 slurp 包含 SQL 的文件。但是，$/是一个全局变量。您应该local $/在尽可能小的范围内使用。所以：

my $sql = do { local $/; <$fh> };
于 2012-04-20T22:44:05.257 回答