1

以下 C 函数尝试使用线程本地存储变量以线程安全的方式防止多核代码中的递归。但是，由于有些复杂的原因，我需要在 X64 汇编程序（Intel X86 / AMD 64 位）中编写此函数，并使用 VC2010 中的 ml64.exe 进行汇编。如果我使用全局变量，我知道如何执行此操作，但我不确定如何使用具有 __declspec(thread) 的 TLS 变量正确执行此操作。

__declspec(thread) int tls_VAR = 0;
void norecurse(  )
{
    if(0==tls_VAR)
    {
        tls_VAR=1;
        DoWork();
        tls_VAR=0;
    }
}

注意：这是 VC2010 为该功能踢出的。但是，MASM (ml64.exe) 不支持代码的一部分gs:88或OFFSET FLAT:部分。

; Listing generated by Microsoft (R) Optimizing Compiler Version 16.00.40219.01 

include listing.inc

INCLUDELIB MSVCRTD
INCLUDELIB OLDNAMES

PUBLIC  norecurse
EXTRN   DoWork:PROC
EXTRN   tls_VAR:DWORD
EXTRN   _tls_index:DWORD
pdata   SEGMENT
$pdata$norecurse DD imagerel $LN4
    DD  imagerel $LN4+70
    DD  imagerel $unwind$norecurse
pdata   ENDS
xdata   SEGMENT
$unwind$norecurse DD 040a01H
    DD  06340aH
    DD  07006320aH
; Function compile flags: /Ogtpy
xdata   ENDS
_TEXT   SEGMENT
norecurse PROC
; File p:\hackytests\64bittest2010\64bittest\64bittest.cpp
; Line 19
$LN4:
    mov QWORD PTR [rsp+8], rbx
    push    rdi
    sub rsp, 32                 ; 00000020H
; Line 20
    mov ecx, DWORD PTR _tls_index
    mov rax, QWORD PTR gs:88
    mov edi, OFFSET FLAT:tls_VAR
    mov rbx, QWORD PTR [rax+rcx*8]
    cmp DWORD PTR [rbx+rdi], 0
    jne SHORT $LN1@norecurse
; Line 22
    mov DWORD PTR [rbx+rdi], 1
; Line 23
    call    DoWork
; Line 24
    mov DWORD PTR [rbx+rdi], 0
$LN1@norecurse:
; Line 26
    mov rbx, QWORD PTR [rsp+48]
    add rsp, 32                 ; 00000020H
    pop rdi
    ret 0
norecurse ENDP
_TEXT   ENDS
END
4

3 回答 3

3

正如您的回答表明问题归结为在 Microsoft 的 C++ 编译器生成的汇编列表中找到以下两行的 MASM 等效项：

mov rax, QWORD PTR gs:88
mov edi, OFFSET FLAT:tls_VAR

第一行很简单。只需替换gs:88为gs:[88].

第二行不太明显。OFFSET FLAT:运营商是红鲱鱼。这意味着使用相对于“FLAT”段开头的偏移量。对于 32 位版本的 MASM，FLAT 段是包含整个 4G 地址空间的段。这是用于代码和数据段的段，作为 32 位平面内存模型的一部分。MASM 的 64 位版本不支持内存模型，它本质上总是假定平面内存模型的 64 位版本，因此它不支持 FLAT 关键字。结果，普通OFFSET运算符的结尾含义相同。（实际上对于 32 位汇编器，plainOFFSET通常也意味着同样的事情，因为 PECOFF 只支持平面内存模型。）

但是OFFSET在这里使用是行不通的。那是因为它将使用tls_VAR内存中地址相对于地址0的偏移量。或者换句话说，它将使用tls_VAR内存中的绝对地址。这里需要的是相对于 TLS 数据段开头的偏移量。

所以编译器必须在这里做一些特别的事情。为了找出答案，我在编译您的示例 C 代码时生成的目标文件中转储了重定位：

> dumpbin /relocations t215a.obj
...  
RELOCATIONS #4
                                                Symbol    Symbol
 Offset    Type              Applied To         Index     Name
 --------  ----------------  -----------------  --------  ------
 00000008  REL32                      00000000        14  _tls_index
 00000016  SECREL                     00000000         8  tls_VAR
 0000002D  REL32                      00000000         C  DoWork
...

如您所见，它会生成类型的重定位以SECREL供引用tls_VAR. 这使得重定位相对于该符号出现在生成的可执行文件中的节的基部。在这种情况下，这就是.tls节，因此此重定位会生成相对于用于静态 TLS 数据的节的开头的偏移量。

所以现在的问题变成了如何让 MASM 生成编译器发出的相同的 SECREL 重定位。事实证明这也有一个简单的解决方案，只需替换OFFSET FLAT:为SECTIONREL.

因此，通过这些更改（以及一些优化），您的功能变为：

    EXTERN  tls_VAR:DWORD
    EXTERN  _tls_index:DWORD
    EXTERN  DoWork:PROC

    PUBLIC  norecurse
_TEXT SEGMENT
norecurse PROC
    push rbx
    sub rsp, 32
    mov rax, gs:[88]
    mov ecx, _tls_index
    mov rbx, [rax + rcx * 8]
    cmp DWORD PTR [rbx + SECTIONREL tls_VAR], 0
    jne return
    mov DWORD PTR [rbx + SECTIONREL tls_VAR], 1
    call DoWork
    mov DWORD PTR [rbx + SECTIONREL tls_VAR], 0
return:
    add rsp, 32
    pop rbx
    ret
norecurse ENDP
_TEXT ENDS
    END
于 2015-11-16T19:43:10.337 回答
1

我能够解决这个问题。我在汇编中的实现比 C 编译器生成的代码效率低，因为我无法弄清楚如何使用以下两种寻址模式：

  1. mov rax, QWORD PTR gs:88
  2. mov edi，偏移平面：tls_VAR

对于 (1)，我必须将 88 加载到 rax 并使用 gs:[rax] 来访问线程的 TLS 基础。

对于 (2)，OFFSET FLATMASM (ml64.exe) 中的缺失意味着我必须更加聪明。_tls_start我通过从线程的 TLS 基数中减去可应用于汇编程序中的 TLS 变量以访问其线程本地值的线程来计算偏移量。

PUBLIC  norecurse
EXTRN   _tls_index:DWORD
EXTRN   _tls_start:DWORD
EXTRN   tls_VAR:DWORD
EXTRN   DoWork:PROC

_TEXT   SEGMENT

norecurse           PROC
    ; non-volatile
    push            rbx
    sub             rsp,32

    ; The gs segment register refers to the base address of the TEB on x64.
    ; 88 (0×58) is the offset in the TEB for the ThreadLocalStoragePointer member on x64
    mov             rax,88
    mov             edx, DWORD PTR _tls_index
    mov             rax, gs:[rax]
    mov             r11, QWORD PTR [rax+rdx*8]
    lea             r10, _tls_start
    ; r11 will be the the offset-adjusted TLS-Base
    sub             r11, r10

    ; ebx will be the the thread local address of tls_VAR
    lea             rdx, tls_VAR
    lea             rbx,[r11+rdx]

    cmp             DWORD PTR [rbx], 0
    jne             @F

    mov             DWORD PTR [rbx], 1

    call            DoWork

    mov             DWORD PTR [rbx], 0
@@:

    add             rsp,32
    pop             rbx

    ret
norecurse       ENDP

_TEXT   ENDS

    END

我很想看到更有效的方法或指针，说明如何实际使用我无法用 MASM (ml64.exe) 弄清楚的两种寻址模式。

于 2012-04-26T16:30:36.623 回答
0

查看TlsGetValue、 TlsSetvalue 和朋友。

于 2012-04-20T16:30:30.190 回答