13

我正在尝试在 Haskell 中使用并发进行特定优化，其中只需要两个值中的一个，并且根据情况，创建其中一个值可能比另一个快得多。

我想我可以只用 forkIO 运行 2 个线程，然后等到一个值放入 M​​Var 中。这是我为此编写的一个简单测试：

import Control.Concurrent

main = do out <- newEmptyMVar
          t1 <- forkIO (makeString out)
          t2 <- forkIO (makeInt out)
          v <- takeMVar out
          killThread t1
          killThread t2
          case v of
               Left s -> putStrLn s
               Right i -> putStrLn $ show i

makeString out = do s <- return ( show (primes !! 10000))
                    putMVar out $ Left s

makeInt out = do i <- return 2
                 putMVar out $ Right i

primes = sieve [2..] 
 where sieve (x:xs) = x : (sieve $ filter ((/=0).(flip mod x)) xs)

编译：

ghc --make -threaded Test

然而，只有 Left 的情况下，尽管获得质数应该需要足够长的时间才能启动 makeInt 线程（并且 return 2 真的不应该花费那么多时间）。为什么会这样，我该如何解决？

4

2 回答 2

20

这里的问题是懒惰。这makeString只是插入一个 thunk 来计算show (primes !! 10000)，然后由主线程评估。插入 thunk 非常快，因此在这种情况下它恰好赢得了比赛。

要强制在线程内进行评估，您可以更改return为evaluate：

makeString out = do s <- evaluate $ show (primes !! 10000)
                    putMVar out $ Left s

在大多数情况下，这应该会导致makeInt赢得比赛（尽管不能保证）。

于 2012-04-20T13:56:02.493 回答
10

是的，线程确实是不确定的（在 GHC 中）。

碰巧您的特定代码的结构和优化方式使 t1 总是获胜。没有任何保证。

如果您想尝试对其进行按摩以产生不同的结果，请尝试打开优化 ( -O2) 和/或使用多核 ( +RTS -N)。

例如在我的机器上，连续两次运行：

$ ghc -O2 -threaded --make A.hs -rtsopts -fforce-recomp
[1 of 1] Compiling Main             ( A.hs, A.o )
Linking A.exe ...
$ ./A +RTS -N2
2
$ ./A +RTS -N2
104743

正如 hammar 指出的那样，您还可以构建代码以强制在线程中进行更多工作（或切换到使用严格的 mvars）。

于 2012-04-20T13:50:49.407 回答