3

在 Unix shell 脚本中，可以从内部脚本本身重定向标准错误和标准输出，如下所示：

#!/bin/ksh
# script_name: test.sh
export AUTO_LOGFILE=`basename $0 .sh`.log
# stdout and stderr Redirection. This will save the old stdout on FD 3, and the old stderr on FD 4.
exec 3>&0 4>&1 >>$AUTO_LOGFILE 2>&1
echo "Hello World"
# The above echo will be printed to test.log

实际上，test.sh 可以简单地执行为：

test.sh

代替：

test.sh >> test.log 2>&1

我正在尝试在批处理脚本中做类似的事情。我的批处理代码如下：

@echo off & setlocal enableextensions enabledelayedexpansion
REM script_name=test.bat
set AUTO_LOGFILE=%~n0.log
REM How to do the stdout and stderr redirection from within the script itself here?

如何从批处理脚本本身重定向标准错误和标准输出？我更感兴趣的是将此 unix shell 脚本语句转换为等效的批处理代码：

exec 3>&0 4>&1 >>$AUTO_LOGFILE 2>&1
4

2 回答 2

5

下面的test.bat批处理文件在功能上等同于您的 Unix 脚本，即它将所有标准输出发送到日志文件并将错误输出发送到屏幕：

@echo off
if defined reEntry goto reEntry
set reEntry=TRUE

set AUTO_LOGFILE=%~N0.log
rem stdout Redirection. Leave stderr as is.

"%~F0" %* >>%AUTO_LOGFILE%

:reEntry
set reEntry=
echo "Hello World"
rem The above echo will be printed to test.log
rem and error messages will be printed to the screen:
verify badparam

附录：

我以为 OP 想将 stdout 与 stderr 分开以在屏幕上查看错误消息，但也许我误解了他。要将 stdout 和 stderr 都发送到文件，请使用下面的行，如 dbenham 在他的评论中指出的那样：

"%~F0" %* >>%AUTO_LOGFILE% 2>&1

或者以上面评论中已经建议的更简单的方式：

@echo off
set AUTO_LOGFILE=%~N0.log
rem stdout and stderr Redirection.

call :Main %* >>%AUTO_LOGFILE% 2>&1
goto :EOF

:Main
echo "Hello World"
rem The above echo will be printed to test.log

但是，如果目的是将错误消息与正常输出区分开来，则可以通过以下技巧在同一屏幕中完成：

"%~F0" %* 2>&1 1>&3 | findstr /N /A:4E "^"

这样，错误消息就会出现在红色背景上的黄色行号之前。这种方法可以在多种情况下直接使用；例如，在任何编程语言源程序的编译中：

anycompiler %1 2>&1 1>&3 | findstr /N /A:4E "^"
于 2012-04-21T17:03:40.513 回答
1

将行括在括号中

(
  REM How to do the stdout redirection from within the script itself here?
  ECHO is this redirected?
  ECHO yes it is
) >out.txt
于 2012-04-20T08:02:38.953 回答