37

我正在尝试从 Excel 文件外部运行 Excel 宏。我目前正在使用从命令行运行的“.vbs”文件，但它一直告诉我找不到宏。这是我正在尝试使用的脚本

Set objExcel = CreateObject("Excel.Application")
Set objWorkbook = objExcel.Workbooks.Open("test.xls")

objExcel.Application.Visible = True
objExcel.Workbooks.Add
objExcel.Cells(1, 1).Value = "Test value"

objExcel.Application.Run "Macro.TestMacro()"
objExcel.ActiveWorkbook.Close


objExcel.Application.Quit
WScript.Echo "Finished."
WScript.Quit

这是我试图访问的宏：

Sub TestMacro()
'first set a string which contains the path to the file you want to create.
'this example creates one and stores it in the root directory
MyFile = "C:\Users\username\Desktop\" & "TestResult.txt"
'set and open file for output
fnum = FreeFile()
Open MyFile For Output As fnum
'write project info and then a blank line. Note the comma is required
Write #fnum, "I wrote this"
Write #fnum,
'use Print when you want the string without quotation marks
Print #fnum, "I printed this"
Close #fnum
End Sub

我尝试了位于是否可以从外部命令在 Excel 中运行宏的解决方案？走到这一步（当然还有修改），但它似乎没有用。我不断收到错误“Microsoft Office Excel：找不到宏“Macro.TestMacro”。

编辑：Excel 2003。

4

8 回答 8

44

好吧，其实很简单。假设您的宏在一个模块中，而不是在其中一张表中，您使用：

  objExcel.Application.Run "test.xls!dog" 
  'notice the format of 'workbook name'!macro

对于带有空格的文件名，请用引号将文件名括起来。

如果您已将宏放在工作表下，例如 sheet1，则假设 sheet1 拥有该函数，它确实如此。

    objExcel.Application.Run "'test 2.xls'!sheet1.dog"

注意：您不需要一直使用的 macro.testfunction 表示法。

于 2012-04-19T16:42:32.183 回答
23

此代码将打开文件 Test.xls 并运行宏，该宏TestMacro将依次写入文本文件TestResult.txt

Option Explicit

Dim xlApp, xlBook

Set xlApp = CreateObject("Excel.Application")
'~~> Change Path here
Set xlBook = xlApp.Workbooks.Open("C:\Test.xls", 0, True)
xlApp.Run "TestMacro"
xlBook.Close
xlApp.Quit

Set xlBook = Nothing
Set xlApp = Nothing

WScript.Echo "Finished."
WScript.Quit
于 2012-04-19T16:50:48.327 回答
5

由于我的相关问题在我杀死了一整天搜索如何击败“找不到或禁用宏”错误后被正义之手删除，因此在这里发布唯一对我有用的语法（application.run 没有，无论如何我试过的）

Set objExcel = CreateObject("Excel.Application")

' Didn't run this way from the Modules
'objExcel.Application.Run "c:\app\Book1.xlsm!Sub1"
' Didn't run this way either from the Sheet
'objExcel.Application.Run "c:\app\Book1.xlsm!Sheet1.Sub1"
' Nor did it run from a named Sheet
'objExcel.Application.Run "c:\app\Book1.xlsm!Named_Sheet.Sub1"

' Only ran like this (from the Module1)

Set objWorkbook = objExcel.Workbooks.Open("c:\app\Book1.xlsm")
objExcel.Run "Sub1"

Excel 2010，赢 7

于 2016-04-20T23:20:49.357 回答
4

我试图将@Siddhart 的代码调整为运行我的open_form宏的相对路径，但它似乎不起作用。这是我的第一次尝试。我的工作解决方案如下。

Option Explicit

Dim xlApp, xlBook
dim fso
dim curDir
set fso = CreateObject("Scripting.FileSystemObject")
curDir = fso.GetAbsolutePathName(".")
set fso = nothing

Set xlApp = CreateObject("Excel.Application")
'~~> Change Path here
Set xlBook = xlApp.Workbooks.Open(curDir & "Excels\CLIENTES.xlsb", 0, true)
xlApp.Run "open_form"
xlBook.Close
xlApp.Quit

Set xlBook = Nothing
Set xlApp = Nothing

WScript.Echo "Finished."

编辑

我实际上已经解决了，以防万一有人想运行一个用户表单“类似”一个独立的应用程序：

我面临的问题：

1 - 我不想使用 Workbook_Open 事件，因为 excel 被锁定为只读。2 - 批处理命令受到限制，即（据我所知）它不能调用宏。

我首先编写了一个宏来在隐藏应用程序的同时启动我的用户窗体：

Sub open_form()
 Application.Visible = False
 frmAddClient.Show vbModeless
End Sub

然后我创建了一个 vbs 来启动这个宏（使用相对路径来做这件事很棘手）：

dim fso
dim curDir
dim WinScriptHost
set fso = CreateObject("Scripting.FileSystemObject")
curDir = fso.GetAbsolutePathName(".")
set fso = nothing

Set xlObj = CreateObject("Excel.application")
xlObj.Workbooks.Open curDir & "\Excels\CLIENTES.xlsb"
xlObj.Run "open_form"

我终于做了一个批处理文件来执行VBS ......

@echo off
pushd %~dp0
cscript Add_Client.vbs

请注意，我还在我的Userform_QueryClose：

Private Sub cmdClose_Click()
Unload Me
End Sub

Private Sub UserForm_QueryClose(Cancel As Integer, CloseMode As Integer)
    ThisWorkbook.Close SaveChanges:=True
    Application.Visible = True
    Application.Quit
End Sub

无论如何，感谢您的帮助，如果有人需要，我希望这会有所帮助

于 2014-01-05T08:22:55.303 回答
3

我尝试了上述方法，但出现“找不到宏”错误。这是有效的最终代码！

Option Explicit

Dim xlApp, xlBook

Set xlApp = CreateObject("Excel.Application")
xlApp.Visible = True

  ' Import Add-Ins
xlApp.Workbooks.Open "C:\<pathOfXlaFile>\MyMacro.xla"
xlApp.AddIns("MyMacro").Installed = True

'
Open Excel workbook
Set xlBook = xlApp.Workbooks.Open("<pathOfXlsFile>\MyExcel.xls", 0, True)

' Run Macro
xlApp.Run "Sheet1.MyMacro"

xlBook.Close
xlApp.Quit

Set xlBook = Nothing
Set xlApp = Nothing

WScript.Quit

在我的例子中，MyMacro 恰好在 Sheet1 下，因此是 Sheet1.MyMacro。

于 2016-01-20T09:26:14.417 回答
1

我通常将我的宏xlam与我的工作簿分开存储在加载项中，所以我想打开一个工作簿，然后运行一个单独存储的宏。

因为这需要一个 VBS 脚本，所以我想让它“可移植”，这样我就可以通过传递参数来使用它。这是最终的脚本，它需要 3 个参数。

  • 工作簿的完整路径
  • 宏名称
  • [可选] 使用宏分隔工作簿的路径

我像这样测试它：

"C:\Temp\runmacro.vbs" "C:\Temp\Book1.xlam" "Hello"

"C:\Temp\runmacro.vbs" "C:\Temp\Book1.xlsx" "Hello" "%AppData%\Microsoft\Excel\XLSTART\Book1.xlam"

运行宏.vbs：

Set args = Wscript.Arguments

ws = WScript.Arguments.Item(0)
macro = WScript.Arguments.Item(1)
If wscript.arguments.count > 2 Then
 macrowb= WScript.Arguments.Item(2)
End If

LaunchMacro

Sub LaunchMacro() 
  Dim xl
  Dim xlBook  

  Set xl = CreateObject("Excel.application")
  Set xlBook = xl.Workbooks.Open(ws, 0, True)
  If wscript.arguments.count > 2 Then
   Set macrowb= xl.Workbooks.Open(macrowb, 0, True)
  End If
  'xl.Application.Visible = True ' Show Excel Window
  xl.Application.run macro
  'xl.DisplayAlerts = False  ' suppress prompts and alert messages while a macro is running
  'xlBook.saved = True ' suppresses the Save Changes prompt when you close a workbook
  'xl.activewindow.close
  xl.Quit

End Sub
于 2020-01-10T17:11:38.370 回答
0

如果您尝试从您的个人工作簿运行宏，它可能无法正常工作，因为使用 VBScript 打开 Excel 文件不会自动打开您的 PERSONAL.XLSB。你需要做这样的事情：

Dim oFSO
Dim oShell, oExcel, oFile, oSheet
Set oFSO = CreateObject("Scripting.FileSystemObject")
Set oShell = CreateObject("WScript.Shell")
Set oExcel = CreateObject("Excel.Application")
Set wb2 = oExcel.Workbooks.Open("C:\..\PERSONAL.XLSB") 'Specify foldername here

oExcel.DisplayAlerts = False


For Each oFile In oFSO.GetFolder("C:\Location\").Files
    If LCase(oFSO.GetExtensionName(oFile)) = "xlsx" Then
        With oExcel.Workbooks.Open(oFile, 0, True, , , , True, , , , False, , False)



            oExcel.Run wb2.Name & "!modForm"


            For Each oSheet In .Worksheets



                oSheet.SaveAs "C:\test\" & oFile.Name & "." & oSheet.Name & ".txt", 6


            Next
            .Close False, , False
        End With
    End If



Next
oExcel.Quit
oShell.Popup "Conversion complete", 10

因此，在循环开始时，它打开 personals.xlsb 并从那里为所有其他工作簿运行宏。只是想我应该在这里发帖，以防有人像我一样遇到这个问题，但无法弄清楚为什么宏仍然没有运行。

于 2013-11-20T20:38:53.733 回答
0

嗨，使用这个线程来获得解决方案，然后我想分享我所做的以防万一有人可以使用它。

我想要的是调用一个宏来更改一些单元格并删除一些行，但我需要超过 1500 个 excel（每个文件大约花费 3 分钟）

主要问题： - 当从 vbe 调用宏时，我遇到了同样的问题，从 PERSONAL.XLSB 调用宏是不可能的，当脚本打开时，excel 没有执行 personal.xlsb 并且宏窗口中没有任何选项

我通过保持打开一个加载了宏的excel文件（a.xlsm）（在执行脚本之前）解决了这个问题

然后我从脚本打开的excel中调用宏

    Option Explicit
    Dim xl
    Dim counter

   counter =10



  Do

  counter = counter + 1

  Set xl = GetObject(, "Excel.Application")
  xl.Application.Workbooks.open "C:\pruebas\macroxavi\IA_030-08-026" & counter & ".xlsx"
  xl.Application.Visible = True
  xl.Application.run "'a.xlsm'!eraserow" 
  Set xl = Nothing


  Loop Until counter = 517

  WScript.Echo "Finished."
  WScript.Quit
于 2015-05-28T15:11:47.123 回答