1

您好，我需要用逗号分隔数据并添加新数据。

<fields>
<field name="example"><value>example,i,am,new,to,xslt</value></field>
<fields>

我需要将此 xml 转换为

<fields>
<field name="example"><value>example</value><value>i</value>am</value><value>new</value><value>to</value><value>xslt</value></field>
<fields>

谁能解释我如何使用 XSLT 做到这一点

4

1 回答 1

2

一、XSLT 2.0 解决方案：

<xsl:stylesheet version="2.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output omit-xml-declaration="yes" indent="yes"/>
    <xsl:strip-space elements="*"/>

 <xsl:template match="node()|@*">
     <xsl:copy>
       <xsl:apply-templates select="node()|@*"/>
     </xsl:copy>
 </xsl:template>

 <xsl:template match="value">
   <xsl:for-each select="tokenize(., ',')">
     <value><xsl:value-of select="."/></value>
   </xsl:for-each>
 </xsl:template>
</xsl:stylesheet>

当此转换应用于提供的 XML 文档时（已更正！！！为了格式正确）：

<fields>
    <field name="example">
        <value>example,i,am,new,to,xslt</value>
    </field>
</fields>

产生了想要的正确结果：

<fields>
   <field name="example">
      <value>example</value>
      <value>i</value>
      <value>am</value>
      <value>new</value>
      <value>to</value>
      <value>xslt</value>
   </field>
</fields>

二、XSLT 1.0 解决方案：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="node()|@*">
     <xsl:copy>
       <xsl:apply-templates select="node()|@*"/>
     </xsl:copy>
 </xsl:template>

 <xsl:template match="value" name="tokenize">
  <xsl:param name="pText" select="."/>

  <xsl:if test="string($pText)">
   <value>
    <xsl:value-of select=
     "substring-before(concat($pText, ','), ',')"/>
   </value>

   <xsl:call-template name="tokenize">
     <xsl:with-param name="pText" select=
        "substring-after($pText, ',')"/>
   </xsl:call-template>
  </xsl:if>
 </xsl:template>
</xsl:stylesheet>

当此转换应用于同一个 XML 文档（如上）时，会产生相同的正确结果：

<fields>
   <field name="example">
      <value>example</value>
      <value>i</value>
      <value>am</value>
      <value>new</value>
      <value>to</value>
      <value>xslt</value>
   </field>
</fields>

说明：

  1. 使用身份规则“按原样”复制所有内容。

  2. 覆盖匹配的（标识模板的）模板value。

  3. 在解决方案 I 中——适当使用标准 XPath 2.0 函数tokenize()。

  4. 在解决方案 II 中——使用命名模板实现类似函数——因为在 XPath 1.0/XSLT 1.0tokenize()中没有定义。tokenize()

  5. 在解决方案 II 中，为方便起见，我们将模板匹配value与执行逗号标记的命名模板合并。

于 2012-04-19T13:14:54.987 回答