3

我正在开发一个组件，使用 Delphi 2006，该组件检索系统信息并写入文件。要求是我必须在组件中合并一个全局异常处理程序，因此当异常发生时，它将被捕获并将我的自定义消息显示给用户。

  procedure Tmy.GlobalExceptionHandlerThis(Sender : TObject; E : Exception );
  begin
    //catch the exception and show the message
      TakeScreenShotAndSaveInapplicationFolder;
      MessageDlg('Exception has Occured  , Detail  '+E.Message,mtError,[mbOK],0);
  end;

这工作正常，但根据要求我必须捕获错误屏幕截图（这是为了直观地找到异常弹出的表单）

所以我这样做了，从delphigeist.com截取屏幕截图代码：

procedure TakeScreenShotAndSaveInapplicationFolder;
var
  thisBitmap: TBitmap;
  sDate : string;
begin
  DateSeparator :='_';
  TimeSeparator:='_';
  sDate :=DateTimeToStr(now);
  thisBitmap := TBitmap.Create;
  ScreenshotArea(thisBitmap, Screen.DesktopRect, True);
  thisBitmap.SaveToFile(ExtractFilePath(Application.ExeName)+sDate+'.jpg');
  FreeAndNil(thisBitmap);
end;

问题：

发生异常时，我也想截取消息的屏幕截图，但使用我的代码会发生这种情况

在此处输入图像描述

谁能告诉我怎样才能得到这样的屏幕截图？那就是沿着表格获取消息

在此处输入图像描述

MessageDlg('Exception has Occured, Detail ' + E.Message,mtError,[mbOK],0); 是模态的，所以在消息之后我无法截屏。在我不能之前，那么当显示异常消息时，我什么时候可以直接截屏？

procedure Tmy.GlobalExceptionHandlerThis(Sender : TObject; E : Exception );
begin
  //catch the exception and show the message
  TakeScreenShotAndSaveInapplicationFolder;
  MessageDlg('Exception has Occured  , Detail  '+E.Message,mtError,[mbOK],0);
  TakeScreenShotAndSaveInapplicationFolder;
end;
4

4 回答 4

2

修改此消息框（围绕 的包装Windows.MessageBox），如下所示：

{ TAwMessageBox }

type
  TAwMessageBox = class(TObject)
  private
    FCaption: String;
    FFlags: Cardinal;
    FHookProc: TFarProc;
    FText: String;
    FWndHook: HHOOK;
    function Execute: Integer;
    procedure HookProc(var Message: THookMessage);
  end;

function TAwMessageBox.Execute: Integer;
begin
  try
    try
      FHookProc := MakeHookInstance(HookProc);
      FWndHook := SetWindowsHookEx(WH_CALLWNDPROCRET, FHookProc, 0,
        GetCurrentThreadID);
      Result := Application.MessageBox(PChar(FText), PChar(FCaption), FFlags);
    finally
      if FWndHook <> 0 then
        UnhookWindowsHookEx(FWndHook);
      if FHookProc <> nil then
        FreeHookInstance(FHookProc);
    end;
  except
    Result := 0;
  end;
end;

procedure TAwMessageBox.HookProc(var Message: THookMessage);
var
  Data: PCWPRetStruct;
  Title: array[0..255] of Char;
begin
  with Message do
    if nCode < 0 then
      Result := CallNextHookEx(FWndHook, nCode, wParam, lParam)
    else
      Result := 0;
  if Message.nCode = HC_ACTION then
  begin
    Data := PCWPRetStruct(Message.lParam);
    if (Data.message = WM_ACTIVATE) and (LoWord(Data.wParam) = WA_INACTIVE) then
    begin
      ZeroMemory(@Title, SizeOf(Title));
      GetWindowText(Data.hwnd, @Title, SizeOf(Title));
      if String(Title) = FCaption then
      begin
        TakeScreenShotAndSaveInapplicationFolder;
        UnhookWindowsHookEx(FWndHook);
        FWndHook := 0;
        FreeHookInstance(FHookProc);
        FHookProc := nil;
      end;
    end;
  end;
end;

function MsgBox(const Text: String; Flags: Cardinal;
  const Caption: String): Integer;
begin
  with TAwMessageBox.Create do
  try
    FCaption := Caption;
    FFlags := Flags;
    FText := Text;
    Result := Execute;
  finally
    Free;
  end;
end;

测试代码和屏幕截图：

procedure TForm1.ApplicationEvents1Exception(Sender: TObject; E: Exception);
begin
  MsgBox('Exception has occured. Details:'#13#10#13#10 + E.Message,
    MB_OK or MB_ICONERROR, 'Error');
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
  raise Exception.Create('Test exception');
end;

截屏

于 2012-04-18T15:23:07.080 回答
1

消息对话框（和异常对话框）是模态的，因此第一个 TakeScreenShotAndSaveInApplicationFolder 调用将在它显示之前执行，第二个调用将在它关闭之前执行。

您可以创建自己的消息对话框，将屏幕捕获作为其 Show 例程的一部分，但我建议您应该查看客户的需求，而不是他们的要求并获得更好的解决方案。

从它的声音来看，他们希望能够准确地看到应用程序在错误发生时所处的状态。这意味着screengrab +错误详细信息，我不明白为什么错误详细信息需要专门作为screengrab的一部分。

为什么不考虑使用第 3 方错误记录系统（MadExcept、JclDebug）并将其扩展为捕获应用程序的屏幕截图而不显示错误消息？

这将为您提供同样多的信息（更多，由于异常日志可以产生的附加信息），而无需在出现错误对话框时尝试截屏。

另外，我会质疑抓住整个桌面屏幕。它很容易在不经意间抓取背景窗口上的敏感信息。

参考链接：

Jcl - http://sourceforge.net/projects/jcl/

MadExcept - http://madshi.net/madExceptDescription.htm

于 2012-04-18T12:30:54.460 回答
1

使用您自己的自定义表单来显示错误对话框并让该表单控制屏幕截图。

于 2012-04-18T14:56:47.357 回答
0

在通过@NGLN 想法（上面的答案）和@Pieter B 想法通过表单本身截屏之后，我设法得到了我想要的东西。所以我使用Open-Source-SynTaskDialog来显示我的异常消息，如下所示

 procedure Tmy.GlobalExceptionHandlerThis(Sender : TObject; E : Exception );
   begin
    var Task: TTaskDialog;
       begin
          Task.Title:='Error message';
          Task.Inst := 'An error/exception has occured';
          Task.Content := 'the details are ...';
          Task.Execute([],0,[],tiError ,tfiShield ,200);
       end;

我在里面SynTaskDialog.pas做了这个

          procedure TTaskDialogForm.ButtonClick(Sender: TObject);
            begin

           TakeScreenShotAndSaveInapplicationFolder; {<--take the snap shot here..!!!}
          if (Sender<>nil) and Sender.InheritsFrom(TSynButton) then
          with TSynButton(Sender) do begin
          self.Tag := Tag;
          if Tag in [mrOk..mrNo] then
          self.ModalResult := Tag;
          Close;
         end;
        end;

在此处输入图像描述

这是我做的，button click因为onshow快照只有一半

于 2012-04-20T06:50:39.877 回答