8

我有一个自定义组件（继承自TCustomPanel），它由两个其他组件（假设是两个编辑）组成。使用组件时如何正确获取标签顺序？

在标签顺序设计器中，我只能访问无法获得焦点的组件本身，因为它是一个面板。运行时发生的情况是，我可以使用 tab 键访问编辑，但只有在组件下方的两个按钮获得焦点之后。

在这种情况下如何更改标签顺序？

4

1 回答 1

13

组件中这些嵌套控件的 Tab 键顺序与组件所在表单的 Tab 键顺序不同。表单的 Tab 键顺序列表中组件的 Tab 键顺序在您选择嵌套控件时决定。一旦所有的标签顺序列表组合在一起，它们就会产生最终的循环：

  • 窗体上的控件 ( TabOrder=0)
  • 窗体上的另一个控件 ( TabOrder=1)
  • 您的面板组件 ( TabOrder=2)
    • 编辑 1 ( TabOrder=0)
    • 编辑 2 ( TabOrder=1)
  • 窗体上的另一个控件 ( TabOrder=3)

为了能够设置面板组件设计时的 Tab 键顺序：

  • 使用设计器中的跳位顺序编辑器（右键单击组件的父级）并使用编辑器中的箭头更改跳位顺序，或

  • 发布TabOrder组件的属性并在对象检查器中设置它：

    type 
  TMyPanel = class(TCustomPanel) 
  published 
    property TabOrder; 
  end;

在运行时，总是可以设置组件的 Tab 键顺序，因为该TabOrder属性在TWinControl.

...因为它是一个面板，所以不能有焦点。

不，面板可以很好地获得焦点，但默认情况下不会。这由默认情况下的TabStop属性处理。False您不想为您的组件TabStop进行设置True，因为 (1) 面板没有具有焦点的指示器，并且 (2) 不需要（我想）。

更改嵌套控件的选项卡顺序最好在组件的构造函数中或在运行时完成。

为了能够在设计时设置组件内嵌套控件的 Tab 键顺序，需要做更多的工作。我认为您不希望这样，但是由于我之前的回答（已删除）是垃圾（并且奇怪地投票了），因此我已经制定了一个示例作为补偿。

首先，请注意在设计器中使用标签顺序编辑器设置这些编辑的标签顺序（右键单击面板组件）将更改标签顺序，但不会持续。这是因为这些更改不会流式传输到 DFM。

为了能够流式传输/保存控件的设计时更改，您需要发布它们：

type
  TMyPanel = class(TCustomPanel)
  private
    FEdit1: TEdit;
    FEdit2: TEdit;
  public
    constructor Create(AOwner: TComponent); override;
  published 
    property Edit1: TEdit read FEdit1;
    property Edit2: TEdit read FEdit2;
  end;

constructor TMyPanel.Create(AOwner: TComponent);
begin
  inherited Create(AOwner);
  FEdit1 := TEdit.Create(Self);
  FEdit1.SetBounds(10, 10, 100, 21);
  FEdit1.Name := 'Edit1';
  FEdit1.Parent := Self;
  FEdit1.SetSubComponent(True);
  FEdit2 := TEdit.Create(Self);
  FEdit2.SetBounds(10, 41, 100, 21);
  FEdit2.Name := 'Edit2';
  FEdit2.Parent := Self;
  FEdit2.SetSubComponent(True);
end;

当然，这会发布这些控件的所有属性，现在用户可以更改他们想要的任何内容。为防止这种情况，请考虑限制TEdit控件的已发布属性：

unit MyPanelEdit;

interface

uses
  DesignEditors, Unit2, DesignIntf, SysUtils, Classes, TypInfo, StdCtrls;

type
  TEditProperty = class(TComponentProperty)
  private
    function FilterFunc(const ATestEditor: IProperty): Boolean;
  public
    function GetAttributes: TPropertyAttributes; override;
    procedure GetProperties(Proc: TGetPropProc); override;
  end;

procedure Register;

implementation

procedure Register;
begin
  RegisterPropertyEditor(TypeInfo(TEdit), TMyPanel, '', TEditProperty);
end;

{ TEditProperty }

function TEditProperty.FilterFunc(const ATestEditor: IProperty): Boolean;
begin
  Result := ATestEditor.GetName = 'TabOrder';
end;

function TEditProperty.GetAttributes: TPropertyAttributes;
begin
  Result := [paSubProperties];
end;

procedure TEditProperty.GetProperties(Proc: TGetPropProc);
var
  LComponents: IDesignerSelections;
  LDesigner: IDesigner;
begin
  LComponents := GetSelections;
  if LComponents <> nil then
  begin
    if not Supports(
        FindRootDesigner(LComponents[0]), IDesigner, LDesigner) then
      LDesigner := Designer;
    GetComponentProperties(LComponents, [tkInteger], LDesigner, Proc,
      FilterFunc);
  end;
end;

end.

这将已发布TEdit属性的属性限制为仅显示TabOrder。

于 2012-04-17T15:54:05.510 回答