perl - 使用perl合并两个文件将原始文件的副本保留在另一个文件中

Question

我必须像 A.ini 和 B.ini 这样的文件，我想合并 A.ini 中的两个文件

examples of files:
A.ini::

a=123
b=xyx
c=434

B.ini contains:
a=abc
m=shank
n=paul

my output in files A.ini should be like

a=123abc
b=xyx
c=434
m=shank
n=paul

我想用 perl 语言完成这种合并，我想将旧 A.ini 文件的副本保留在其他地方以使用旧副本

Answer 1

命令行变体：

perl -lne '
($a, $b) = split /=/;
$v{$a} = $v{$a} ? $v{$a} . $b : $_;
END {
  print $v{$_} for sort keys %v
}' A.ini B.ini >NEW.ini

Answer 2

How about:

#!/usr/bin/perl
use strict;
use warnings;

my %out;
my $file = 'path/to/A.ini';
open my $fh, '<', $file or die "unable to open '$file' for reading: $!";
while(<$fh>) {
    chomp;
    my ($key, $val) = split /=/;
    $out{$key} = $val;
}
close $fh;

$file = 'path/to/B.ini';
open my $fh, '<', $file or die "unable to open '$file' for reading: $!";
while(<$fh>) {
    chomp;
    my ($key, $val) = split /=/;
    if (exists $out{$key}) {
        $out{$key} .= $val;
    } else {
        $out{$key} = $val;
    }
}
close $fh;

$file = 'path/to/A.ini';
open my $fh, '>', $file or die "unable to open '$file' for writing: $!";
foreach(keys %out) {
    print $fh $_,'=',$out{$_},"\n";
}
close $fh;

Answer 3

要合并的两个文件可以一次读取，不需要被视为单独的源文件。这允许使用<>读取在命令行上作为参数传递的所有文件。

保留 的备份副本A.ini只是在将合并的数据写入同名的新文件之前重命名它的问题。

该程序似乎可以满足您的需求。

use strict;
use warnings;

my $file_a = $ARGV[0];

my (@keys, %values);

while (<>) {
  if (/\A\s*(.+?)\s*=\s*(.+?)\s*\z/) {
    push @keys, $1 unless exists $values{$1};
    $values{$1} .= $2;
  }
}

rename $file_a, "$file_a.bak" or die qq(Unable to rename "$file_a": $!);
open my $fh, '>', $file_a or die qq(Unable to open "$file_a" for output: $!);
printf $fh "%s=%s\n", $_, $values{$_} for @keys;

输出（in A.ini）

a=123abc
b=xyx
c=434
m=shank
n=paul