2

这是Perl 正则表达式匹配 IP 地址的后续内容。我想展示如何正确解决问题，但遇到了意想不到的行为。

use 5.010;
use strictures;
use Data::Munge qw(list2re);
use Regexp::IPv6 qw($IPv6_re);
use Regexp::Common qw(net);

our $port_re = list2re 0..65535;

sub ip_port_from_netloc {
    my ($sentence) = @_;
    return $sentence =~ /
        (                   # capture either
          (?<= \[ )
            $IPv6_re        #  IPv6 address without brackets
          (?=  \] )
        |                   # or
            $RE{net}{IPv4}  #  IPv4 address
        )
        :                   # colon sep. host from port
        ($port_re)          #   capture port
    /msx;
}

my ($ip, $port);
($ip, $port) = ip_port_from_netloc 'The netloc is 216.108.225.236:60099';
say $ip;
($ip, $port) = ip_port_from_netloc 'The netloc is [fe80::226:5eff:fe1e:dfbe]:60099';
say $ip;

第二场比赛失败。use re 'debugcolor'显示在 IPv6 地址中:($port_re)已经匹配。:5这让我感到惊讶，因为我没有用?. 我希望它会吞噬所有内容，直到]，然后才匹配分隔冒号以及之后的内容。

为什么会发生这种情况，补救措施是什么？

4

2 回答 2

6

*只有当你的一个原子可以选择它可以匹配多少（即，如果你使用、或）时+，贪婪才会发挥作用。这不是贪婪的问题。?{n,m}

问题是正则表达式只会匹配一个 IPv6 地址，如果它紧随其后的是“ ]”和“ :”。这不可能发生。

您可以使用两个不同的匹配项，也可以使用如下内容：

my $port_re = list2re 0..65535;
my $IPv4_re = $RE{net}{IPv4};

sub ip_port_from_netloc {
    my ($sentence) = @_;
    return if $sentence !~ /
        (?: \[ ( $IPv6_re ) \]
        |      ( $IPv4_re )
        )
        : ($port_re)
    /msx;

    return ($1 // $2, $3);
}

也许这有点清洁？

my $port_re = list2re 0..65535;
my $IPv4_re = $RE{net}{IPv4};

sub ip_port_from_netloc {
    my ($sentence) = @_;
    return if $sentence !~ /
        (?: \[ (?<addr> $IPv6_re ) \]
        |      (?<addr> $IPv4_re )
        )
        : (?<port> $port_re )
    /msx;

    return ( $+{addr}, $+{port} );
}
于 2012-04-15T18:44:42.337 回答
3

零宽度断言不会被消耗，因此文字右括号仍然存在以匹配跟随第一个捕获组。此调整似乎有效：

/
    \[?(                   # capture either
      (?<= \[ )
        $IPv6_re        #  IPv6 address without brackets
      (?=  \] )
    |                   # or
        (?<! \[ )
        $RE{net}{IPv4}  #  IPv4 address
        (?! \] )
    )\]?
    :                   # colon sep. host from port
    ($port_re)          #   capture port
/msx;
于 2012-04-15T18:41:26.237 回答