concurrency - Erlang进程消息抑制

Question

我想产生一些将响应他们收到的消息的进程。这很简单。但是，我也希望有一个能够阻止另一个进程的输出的进程。

在另一种语言中，我可能会设置一个标志并在发送消息之前检查该标志的状态。但是由于 Erlang 没有可变变量，我该如何实现呢？

我当然可以在 a 中添加一个模式receive来监视抑制消息。我只是不知道下一步该做什么。

我真的不喜欢为此使用 ETS 表的想法，因为这破坏了一个很好的分布式模型。同样，我不太关心并发问题，但我想以最合适的方式设计它。

Answer 1

每个回显服务器都可以有自己的状态，指示它当前是否处于静音状态。其他进程可以使用静音/取消静音消息切换该状态。在响应消息之前，回显服务器将检查状态并采取适当的行动。

例如：

1> {ok, Pid} = echo:start_link().
{ok,<0.99.0>}
2> echo:echo(Pid, "this message will be echoed.").
#Ref<0.0.0.443>
3> echo:echo(Pid, "as will this message..").
#Ref<0.0.0.447>
4> echo:mute(Pid).
ok
5> echo:echo(Pid, "this message will not.").
#Ref<0.0.0.457>
6> echo:unmute(Pid).
ok
7> echo:echo(Pid, "but this one will..").
#Ref<0.0.0.461>
8> flush().
Shell got {#Ref<0.0.0.443>,"this message will be echoed."}
Shell got {#Ref<0.0.0.447>,"as will this message.."}
Shell got {#Ref<0.0.0.461>,"but this one will.."}
ok
9> echo:stop(Pid).
ok

代码：

-module(echo).

-behaviour(gen_server).

%% API
-export([start_link/0,
     echo/2,
     mute/1,
     unmute/1,
     stop/1]).

%% gen_server callbacks
-export([init/1, handle_call/3, handle_cast/2, handle_info/2,
     terminate/2, code_change/3]).

-define(SERVER, ?MODULE). 

-record(state, {mute=false}).

%%%===================================================================
%%% API
%%%===================================================================

start_link() ->
    gen_server:start_link(?MODULE, [], []).

echo(Pid, Msg) ->
    Ref = make_ref(),
    gen_server:cast(Pid, {echo, self(), Ref, Msg}),
    Ref.

mute(Pid) ->
    gen_server:cast(Pid, mute).

unmute(Pid) ->
    gen_server:cast(Pid, unmute).

stop(Pid) ->
    gen_server:cast(Pid, stop).

%%%===================================================================
%%% gen_server callbacks
%%%===================================================================

init([]) ->
    {ok, #state{}}.

handle_call(_Request, _From, State) ->
    Reply = ok,
    {reply, Reply, State}.

handle_cast({echo, From, Tag, Msg}, #state{mute=false} = State) ->
    From ! {Tag, Msg},
    {noreply, State};
handle_cast({echo, _From, _Tag, _Msg}, #state{mute=true} = State) ->
    {noreply, State};
handle_cast(mute, State) ->
    {noreply, State#state{mute=true}};
handle_cast(unmute, State) ->
    {noreply, State#state{mute=false}};
handle_cast(stop, State) ->
    {stop, normal, State};
handle_cast(_Msg, State) ->
    {noreply, State}.

handle_info(_Info, State) ->
    {noreply, State}.

terminate(_Reason, _State) ->
    ok.

code_change(_OldVsn, State, _Extra) ->
    {ok, State}.