2 
 set recordsetname = databasename.openrecordset(SQLString)
    if recordsetname.bof <> true and recordsetname.eof <> true then
    'do something
    end if

2个问题：

  1. 上面的测试可以错误地评估为假，但很少见（我的代码中潜伏了一个，今天它失败了，我相信这是 5 年来日常使用中的第一次——这就是我发现它的方式）。为什么对于非空记录集，bof/eof 中的一个偶尔会为真。它似乎如此罕见，以至于我想知道它为什么会发生。

  2. 这是一个万无一失的替代品：

    if recordsetname.bof <> true or recordsetname.eof <> true then

编辑以添加代码的详细信息：

客户有订单，每个订单以一个项目开始，以一个BeginOrder项目结束，EndOrder中间是订单中的项目。

SQL 是：

' ids are autoincrement long integers '
SQLString = "select * from Orders where type = OrderBegin or type = OrderEnd"           

Dim OrderOpen as Boolean
OrderOpen = False

Set rs = db.Openrecordset(SQLString)
If rs.bof <> True And rs.eof <> True Then
    myrec.movelast
    If rs.fields("type").value = BeginOrder Then
         OrderOpen = True
    End If
End If

If OrderOpen F False Then
    'code here to add new BeginOrder Item to Orders table '
End If

ShowOrderHistory 'displays the customer's Order history '

在这种情况下，看起来这个

BeginOrder
Item a
Item b
...
Item n
EndOrder

BeginOrder
Item a
Item b
...
Item n
EndOrder

BeginOrder
Item a
item b
...
Item m

BeginOrder     <----should not be there as previous order still open
4

6 回答 6

4

该文档明确指出，如果您打开一个Recordset没有记录的文件：

  • BOF将是真的
  • EOF将是真的
  • RecordCount将会0

对于非空Recordset，在您超出第一条或最后一条记录之前，BOF和都不为真。EOF

是不是有时，其他人可能会在您刚刚打开的记录集中的一个表中添加/删除一条记录并更改结果集？
这可能是竞争条件的结果。

而不是使用BOFor EOF，您可以测试Recordcount: 它总是0如果记录集为空。
如果记录集不为空，通常会1在记录集打开后立即返回；Recordcount在这种情况下，这并不是一项昂贵的操作。
真正返回实际记录数的唯一方法是MoveLast在调用之前发出一个Recordcount强制加载所有记录的方法。

通常，如果我需要以只读方式遍历结果集：

Dim db as DAO.Database
Dim rs as DAO.RecordSet

Set db = CurrentDB()
Set rs = db.OpenRecordSet("...", dbOpenForwardOnly)
If Not (rs Is Nothing) Then
    With rs
       Do While Not .EOF
            ' Do stuff '
            .MoveNext
       Loop
       .Close
    End With
    Set rs = Nothing
End If
Set db = Nothing

如果我不需要遍历记录而只需测试是否返回了任何内容：

Set rs = db.OpenRecordSet("...", dbOpenForwardOnly)
If Not (rs Is Nothing) Then
    With rs
       If .RecordCount > 0 Then
          ' We have a result '
       Else
          ' Empty resultset '
       End If
       .Close
    End With
    Set rs = Nothing
End If
Set db = Nothing

它非常具有防御性，你必须适应你的环境，但它每次都能正常工作。

关于您的第二个问题，打开记录集后的测试（BOFOr EOF）应该比And版本更简单，尽管我会使用Recordcount自己。

按照您修改后的问题进行编辑：

从您添加到问题中的代码中，我看到了几个问题，主要是您的 SQL 语句丢失和ORDER BY子句。
问题是您希望结果集位于Begin Order后面的End Order序列中，但您的 SQL 语句并不能保证这一点。
在大多数情况下，由于您使用自动增量作为 ID，数据库引擎将按自然顺序返回数据，但不能保证：

  • 它总是会这样发生
  • 原始数据按预期顺序保存，导致 ID 的顺序“错误”。

因此，只要您对结果集的顺序有期望，就必须明确对其进行排序。

我还将重构这段代码：

' ids are autoincrement long integers '
SQLString = "select * from Orders where type = OrderBegin or type = OrderEnd"           

Dim OrderOpen as Boolean
OrderOpen = False

Set rs = db.Openrecordset(SQLString)
If rs.bof <> True And rs.eof <> True Then
   myrec.movelast
    If rs.fields("type").value = BeginOrder Then
        OrderOpen = True
    End If
End If

变成一个单独的函数，类似于：

' Returns true if the given CustID has a Open Order, '
' false if they are all closed.'
Public Function IsOrderOpen(CustID as Long) As Boolean
    Dim result as Boolean
    result = False

    Dim sql as String
    ' Here I assume that the Orders table has a OrderDateTime field that '
    ' allows us to sort the order in the proper chronological sequence '
    ' To avoid loading the complete recordset, we sort the results in a way '
    ' that will return the last used order type as the first record.'
    sql = sql & "SELECT Type " 
    sql = sql & "FROM Orders "
    sql = sql & "WHERE ((type = OrderBegin) OR (type = OrderEnd)) "
    sql = sql & "      AND (CustID=" & CustID & ")"
    sql = sql & "ORDER BY OrderDateTime DESC, Type DESC;"

    Dim db as DAO.Database
    Dim rs as DAO.Recordset
    Set db = CurrentDB()
    Set rs = db.Openrecordset(sql, dbOpenForwardOnly)

    If Not (rs Is Nothing) Then
        If rs.RecordCount > 0 Then
            result = (rs!type = BeginOrder)
        End If
        rs.Close
    End If

    Set rs = Nothing
    Set db = Nothing

    IsOrderOpen = result
End Function

这将使整个事情更加健壮。

于 2009-06-19T02:27:45.747 回答
2

@Renaud Bompuis 的回答非常好。让我强调一点，对于非空记录集，DAO 记录计数永远不会为零，这是我在确定记录集是否返回记录时唯一测试过的。我使用 .EOF 循环遍历记录，但在我已经测试过是否返回记录之前不要开始单步执行记录。

于 2009-06-20T23:40:19.377 回答
2

我一直使用的模式是：

Set rs = db.OpenRecordset(...)

Do while Not rs.EOF

    ' Rest of your code here.

    rs.MoveNext
Loop

我从未见过这种失败（还没有！）。此处对此进行了描述：如何：检测 DAO 记录集的限制

顺便说一句，Allen Browne 的 VBA Traps: Working with Recordsets可能很有趣。

于 2009-06-19T00:38:11.427 回答
1

我偶尔会在访问中遇到完全相同的错误（今天在 Access 2007 中将它链接到 sql server 后端），其中语句

如果 rst.bof 和 rst.eof

尽管 rst 表示空记录集，但计算结果为 false。当它发生时，VBA 启动并且直接窗格中的调试器显示，确实 rst.bof 为真，rst.eof 为真，所以它似乎发生了一毫秒，然后被纠正，但在测试了逻辑之后。

于 2010-05-11T23:38:57.750 回答
1

这是DAO，对吧？我自己更像是一个 ADO 人，但 IIRC 在某些情况下（动态集？）您需要导航 EOF 以便评估最终的行数。在这种状态下，EOF 是否为真，BOF 是否为假（因为它尚未被导航），但一旦 BOF 被导航，它就为真（显然）并且 EOF 仍然为真。据推测，当预期为零行时的初始状态应该是瞬时的，但五年一次的异常时间事件意味着您在非常早期的初始状态中捕获了它？

于 2009-06-19T07:27:14.143 回答
0

这是一个可能的解决方案

可能是您的表单或模块已损坏。导出/导入受影响的模块或表单，或尝试 /decompile 选项。在我的情况下，一个查询在不应该有的时候返回空，但我认为核心问题可能是相似的。

于 2009-08-20T12:58:55.370 回答