16

警告：背景信息很长。如果您认为在背景信息之前需要问题，请跳到底部。欣赏这将花费的时间！

我一直在网上（阅读谷歌），我还没有找到一个好的答案。是的，在 erlang.org 网站上有很多 Mnesia 文档的链接和参考，但即使是这些链接也会受到版本炎的影响。

因此，在最简单的情况下，您当前连接的 node() 与表集的所有者相同，那么备份/恢复将起作用。例如：

$ erl -sname mydatabase

> mnesia:start().
> mnesia:create_schema(...).
> mnesia:create_table(...).
> mnesia:backup("/tmp/backup.bup").
> mnesia:restore("/tmp/backup.bup", [{default_op, recreate_tables}]).

嘿，这很好用！

但是，如果数据库实际上运行在远程节点（）或远程节点（）上的远程交配上，那么您必须以这种方式启动备份：

$ erl -sname mydbadmin

> rpc:call(mydatabase@host, mnesia, backup, ["/tmp/backup.bup"]).
> rpc:call(mydatabase@host, mnesia, restore, ["/tmp/backup.bup", [{default_op, recreate_tables}]]).

当然这也很简单。现在这里是棘手的事情......

  • 假设您正在进行每日备份。你的 mnesia 数据库服务器死了，你被迫更换硬件。如果要按原样还原数据库，则需要使用与以前相同的名称命名新硬件，并且还需要将节点命名为相同。
  • 如果您想更改硬件和/或 node() 的名称...或者您想在另一台机器上恢复，那么您需要完成 node_change 过程。（在此处和 mnesia 文档中进行了描述）

但这就是事情变得复杂的地方。虽然我的熟人是 erlang 和 mnesia 专家，但他们认为 mnesia 的复制存在严重缺陷，您不应该使用它（目前我所知道的没有替代方案，并且您将实施更好的版本的可能性有多大；不是可能）

因此，您有两个 nodes() 正在复制基于 ram 和磁盘的表。您一直在维护使用默认 BackupMod 使用标准备份定期备份数据库的策略。有一天，一位经理要求您验证备份。只有当您尝试恢复数据库时，您才会得到：

{atomic,[]}

根据文档，这意味着没有错误……但没有恢复任何表。

不想运行 change_node 过程，您记得 node() 和主机名必须匹配，因此您更改主机名和 -sname 参数以匹配备份数据的机器。然而这一次你得到一个奇怪的错误：

{aborted,{'EXIT',{aborted,{bad_commit,{missing_lock,mydatabase@otherhost}}}}}

仍然不想运行 change_node 过程，我快速克隆恢复我的服务器，以便我有两台类似的机器。然后我适当地命名以匹配生产服务器。然后我开始恢复过程。尤里卡！我现在在恢复服务器上有真实的工作数据。

我想说这是路的尽头......但我还没有问过一个问题，那么 SO.... 的意义就在这里吗？

问题：如果我想恢复从复制的 mnesia 节点集群中获取的备份，如何修改文件（类似于 change_node 过程）以便忽略或从备份中删除其他节点？

略有不同的问题：如何在单个节点（）上恢复复制的多节点（） mnesia 数据库？

4

2 回答 2

12

我认为这个问题属于与一个简单问题相关的更广泛的 Mnesia 问题类别：

如何重命名 Mnesia 节点？

如果您的数据库不大，第一个也是最简单的解决方案是使用 mnesia:traverse_backup 函数（请参阅Mnesia 用户指南）。以下是 Mnesia 用户指南中的示例：

change_node_name(Mod, From, To, Source, Target) ->
    Switch =
        fun(Node) when Node == From -> To;
           (Node) when Node == To -> throw({error, already_exists});
           (Node) -> Node
        end,
    Convert =
        fun({schema, db_nodes, Nodes}, Acc) ->
                {[{schema, db_nodes, lists:map(Switch,Nodes)}], Acc};
           ({schema, version, Version}, Acc) ->
                {[{schema, version, Version}], Acc};
           ({schema, cookie, Cookie}, Acc) ->
                {[{schema, cookie, Cookie}], Acc};
           ({schema, Tab, CreateList}, Acc) ->
                Keys = [ram_copies, disc_copies, disc_only_copies],
                OptSwitch =
                    fun({Key, Val}) ->
                            case lists:member(Key, Keys) of
                                true -> {Key, lists:map(Switch, Val)};
                                false-> {Key, Val}
                            end
                    end,
                {[{schema, Tab, lists:map(OptSwitch, CreateList)}], Acc};
           (Other, Acc) ->
                {[Other], Acc}
        end,
    mnesia:traverse_backup(Source, Mod, Target, Mod, Convert, switched).

view(Source, Mod) ->
    View = fun(Item, Acc) ->
                   io:format("~p.~n",[Item]),
                   {[Item], Acc + 1}
           end,
    mnesia:traverse_backup(Source, Mod, dummy, read_only, View, 0).

这里最重要的部分是{schema, db_nodes, Nodes}元组的操作，它可以让您重命名或替换数据库节点。

顺便说一句，我过去曾使用过该功能，我注意到的一件事是备份条款格式在 mnesia 版本之间发生变化，但也许只是我编写了错误的代码。如果你想确定的话，只需打印一个小型 mnesia 数据库的备份日志来检查备份术语格式。

希望这可以帮助！

于 2012-04-15T20:28:48.927 回答
2

我很难让它工作，所以我将分享我经历的步骤。

首先备份分布式系统中要恢复的节点（到单个节点）：

> mnesia:backup("/path/to/backup").

change_node_name确保在要恢复到的节点上可以使用以下适配：

-module(move_backup).
-export([set_node_name/4]).                                                                                                    

set_node_name(From, To, Source, Target) ->
    Switch =
        fun (Nodes) ->
                case lists:member(From, Nodes) of
                    true -> [To];
                    false -> []
                end
        end,
    Convert =
        fun({schema, db_nodes, Nodes}, Acc) ->
                {[{schema, db_nodes, Switch(Nodes)}], Acc};
           ({schema, version, Version}, Acc) ->
                {[{schema, version, Version}], Acc};
           ({schema, cookie, Cookie}, Acc) ->
                {[{schema, cookie, Cookie}], Acc};
           ({schema, Tab, CreateList}, Acc) ->
                Keys = [ram_copies, disc_copies, disc_only_copies],
                OptSwitch =
                    fun({Key, Val}) ->
                            case lists:member(Key, Keys) of
                                true -> {Key, Switch(Val)};
                                false-> {Key, Val}
                            end
                    end,
                {[{schema, Tab, lists:map(OptSwitch, CreateList)}], Acc};
           (Other, Acc) ->
                {[Other], Acc}
        end,
    mnesia:traverse_backup(Source, Target, Convert, switched).

转换备份：

> move_backup:set_node_name('before@host', 'after@host', "/path/to/backup", "/path_to_backup_converted").

我将假设新节点完全为空（如果不是这种情况，您可能需要更改default_op参数）。有两种选择，一种用于实时恢复：

> mnesia:restore("/path/to/backup_converted", [{default_op, recreate_tables}]).

这很好，但如果您有一个大型数据库（我的数据库约为 10GB，因此这导致内存不足异常），可能会使用大量内存。另一种方法是安装一个后备，然后重新启动你的 shell：

> mnesia:install_fallback("/path/to/backup_converted").
> q().

然后当您重新启动 shell（假设您使用正确的节点名称）时，它将导入完整的数据库。

于 2019-03-06T14:34:33.020 回答