apache-flex - 如何捕获 Flex 中的所有异常？

Question

当我在调试 Flash 播放器中运行 Flex 应用程序时，一旦发生意外情况，就会弹出异常。但是，当客户使用该应用程序时，他不会使用调试 Flash 播放器。在这种情况下，他没有弹出异常，但他的 UI 无法正常工作。

因此，出于可支持性的原因，我想捕获任何可能发生在 Flex UI 中的任何异常，并在 Flex 内部弹出窗口中显示错误消息。通过使用 Java，我只需将整个 UI 代码封装在一个 try/catch 块中，但是对于 Flex 中的 MXML 应用程序，我不知道在哪里可以执行这样一个通用的 try/catch。

score 52 · Accepted Answer

在 Flex 3 中无法收到有关未捕获异常的通知。Adobe 意识到了这个问题，但我不知道他们是否计划创建一个解决方法。

目前唯一的解决方案是将 try/catch 放在合乎逻辑的位置，并确保您正在侦听 ERROR（或 Web 服务的 FAULT）事件以获取任何调度它们的事件。

编辑：此外，实际上不可能捕获事件处理程序引发的错误。我在 Adobe Bug System 上记录了一个错误。

2010 年 1 月 12 日更新：Flash 10.1和AIR 2.0 （均处于测试版）现在支持全局错误处理，并且通过订阅LoaderInfo.uncaughtErrorEvents的 UNCAUGHT_ERROR事件来实现。以下代码取自livedocs 上的代码示例：

public class UncaughtErrorEventExample extends Sprite
{
    public function UncaughtErrorEventExample()
    {
        loaderInfo.uncaughtErrorEvents.addEventListener(
            UncaughtErrorEvent.UNCAUGHT_ERROR, uncaughtErrorHandler);
    }

    private function uncaughtErrorHandler(event:UncaughtErrorEvent):void
    {
        if (event.error is Error)
        {
            var error:Error = event.error as Error;
            // do something with the error
        }
        else if (event.error is ErrorEvent)
        {
            var errorEvent:ErrorEvent = event.error as ErrorEvent;
            // do something with the error
        }
        else
        {
            // a non-Error, non-ErrorEvent type was thrown and uncaught
        }
    }

score 9 · Accepted Answer

Adobe 错误管理系统中有一个错误/功能请求。如果它对您很重要，请投票给它。

http://bugs.adobe.com/jira/browse/FP-444

score 4 · Accepted Answer

它适用于 Flex 3.3。

 if(loaderInfo.hasOwnProperty("uncaughtErrorEvents")){
    IEventDispatcher(loaderInfo["uncaughtErrorEvents"]).addEventListener("uncaughtError", uncaughtErrorHandler);
 }

score 3 · Accepted Answer

请注意，错误 FP-444（上图）链接到http://labs.adobe.com/technologies/flashplayer10/features.html#developer，自 2009 年 10 月以来表明这将在 10.1 时成为可能，目前是 10 月 28 日， 2009 仍未发布 - 所以我想我们会在它发布时看看这是否属实

score 3 · Accepted Answer

替代接受的答案，使用 try-catch。我认为更慢，但更容易阅读。

try {
    loaderInfo.uncaughtErrorEvents.addEventListener("uncaughtError", onUncaughtError);
} catch (e:ReferenceError) {
    var spl:Array = Capabilities.version.split(" ");
    var verSpl:Array = spl[1].split(",");

    if (int(verSpl[0]) >= 10 &&
        int(verSpl[1]) >= 1) {
        // This version is 10.1 or greater - we should have been able to listen for uncaught errors...
        d.warn("Unable to listen for uncaught error events, despite flash version: " + Capabilities.version);
    }
}

当然，您需要使用最新的 10.1 playerglobal.swc 才能成功编译此代码：http: //labs.adobe.com/downloads/flashplayer10.html

score 3 · Accepted Answer

我正在使用 flex 4。我试过loaderInfo.UncaughtErrorEvents,但 loaderInfo 没有初始化，所以它给了我空引用错误。然后我尝试root.loaderInfo.UncaughtErrorEvents了同样的故事。我试过sprite.root.UncaughtErrorEvents了，但是没有精灵对象，我创建了一个，但是没有用。最后我尝试了

systemManager.loaderInfo.uncaughtErrorEvents.addEventListener(UncaughtErrorEvent.UNCAUGHT_ERROR,globalUnCaughtErrorHandler.hanleUnCaughtError);

猜猜看，它就像魔术一样工作。检查这个

score 3 · Accepted Answer

它适用于 Flex 3.5 和 flash player 10：

  <?xml version="1.0" encoding="utf-8"?>
<mx:Application xmlns:mx="http://www.adobe.com/2006/mxml" addedToStage="application1_addedToStageHandler(event)">
    <mx:Script>
        <![CDATA[
            import mx.events.FlexEvent;
            
            protected function application1_addedToStageHandler(event:Event):void{              
                if(loaderInfo.hasOwnProperty("uncaughtErrorEvents")){
                    IEventDispatcher(loaderInfo["uncaughtErrorEvents"]).addEventListener("uncaughtError", uncaughtErrorHandler);
                }
                
                sdk.text = "Flex " + mx_internal::VERSION;
            }
            
            private function uncaughtErrorHandler(e:*):void{
                e.preventDefault();
                
                var s:String;

                if (e.error is Error)
                {
                    var error:Error = e.error as Error;
                    s = "Uncaught Error: " + error.errorID + ", " + error.name + ", " + error.message;
                }
                else
                {
                    var errorEvent:ErrorEvent = e.error as ErrorEvent;
                    s = "Uncaught ErrorEvent: " + errorEvent.text;
                }
                
                msg.text = s;
            }
            
            private function unCaught():void
            {
                var foo:String = null;
                trace(foo.length);
            }
        ]]>
    </mx:Script>
    <mx:VBox>
        <mx:Label id="sdk" fontSize="18"/>
        <mx:Button y="50" label="UnCaught Error" click="unCaught();" />
        <mx:TextArea id="msg" width="180" height="70"/>
    </mx:VBox>
</mx:Application>

谢谢

score 2 · Accepted Answer

我将事件侦听器附加到“根”，这对我有用：

sprite.root.loaderInfo.uncaughtErrorEvents.addEventListener(UncaughtErrorEvent.UNCAUGHT_ERROR, onUncaughtError);

在调试 Flash Player 中，这仍然会出错，但在非调试版本中，错误将出现在 Flash Player 的对话框中 - 然后处理程序将做出响应。要停止出现对话框，请添加：

event.preventDefault();

所以：

    private function onUncaughtError(event:UncaughtErrorEvent):void
    {
        event.preventDefault();
        // do something with this error
    }

我在 AIR 中使用它，但我认为它也适用于标准 AS3 项目。

score 0 · Accepted Answer

现在您可以使用加载器信息：

http://www.adobe.com/devnet/flex/articles/global-exception-handling.html

查看：

loaderInfo.uncaughtErrorEvents.addEventListener(UncaughtErrorEvent.UNCAUGHT_ERROR, onUncaughtError);

private function onUncaughtError(e:UncaughtErrorEvent):void
{
    // Do something with your error.
}

apache-flex - 如何捕获 Flex 中的所有异常？

9 回答 9

Related

Reference