xml - 有没有办法将字符串评估为 xslt 上的操作？

Question

我想将字符串变量的内容评估为操作。

我的变量是这个字符串：1+1+0

我想进行操作并获得值 2。

在此先感谢，古斯塔沃

Answer 1

XSLT 1.0 或 XSLT 2.0 中没有通用机制来评估作为字符串值提供的 XPath 表达式。许多产品都有一个扩展来做到这一点（参见例如 saxon:evaluate()）。XSLT 3.0 中引入了一种通用机制：xsl:evaluate 指令。

Answer 2

在 XSLT 2.0 中，这可以通过使用tokenize(),number()和sum()函数来完成，例如下面的。请注意，我在+标志周围包含了可能的空格。

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>

    <xsl:variable name="test1">1+1+0</xsl:variable>
    <xsl:variable name="test2"> 3 + 
    5   +           12 </xsl:variable>

    <xsl:template match="/">
        <xsl:variable name="testSplit1" select="tokenize($test1,'\s*\+\s*')"/>
        <xsl:variable name="testSplitNum1">
            <xsl:for-each select="$testSplit1">
                <item><xsl:value-of select="number(.)"/></item>
            </xsl:for-each>
        </xsl:variable>

        <xsl:variable name="testSplit2" select="tokenize($test2,'\s*\+\s*')"/>
        <xsl:variable name="testSplitNum2">
            <xsl:for-each select="$testSplit2">
                <item><xsl:value-of select="number(.)"/></item>
            </xsl:for-each>
        </xsl:variable>

        <root>
            <items1><xsl:copy-of select="$testSplitNum1"/></items1>
            <sum1><xsl:value-of select="sum($testSplitNum1/item)"/></sum1>
            <items2><xsl:copy-of select="$testSplitNum2"/></items2>
            <sum2><xsl:value-of select="sum($testSplitNum2/item)"/></sum2>
        </root>

    </xsl:template>

</xsl:stylesheet>

结果（带有虚拟输入文件）是

<?xml version="1.0" encoding="UTF-8"?>
<root>
    <items1>
        <item>1</item>
        <item>1</item>
        <item>0</item>
    </items1>
    <sum1>2</sum1>
    <items2>
        <item>3</item>
        <item>5</item>
        <item>12</item>
    </items2>
    <sum2>20</sum2>
</root>