2

我有很多 pdf 文档要合并在一起，所以我编写了这段代码来完成它。它适用于我只有两个要合并的 pdf 文档的情况，但如果我给它两个以上，额外的文档就会出现乱码。你能帮我找出问题所在吗？

#!/usr/bin/perl

use PDF::API2;
use List::Util qw( reduce );


# Given two pdfs and a page number, appends the given page of the second pdf to the first pdf
sub append_page_to_pdf {
    my ( $pdf1, $pdf2, $pg ) = @_;
    $pdf1->importpage( $pdf2, $pg );
}

# Given two pdfs, appends the second to the first.  Closes pdf2
sub merge_2_pdfs {
    my ($pdf1, $pdf2) = @_;
    map &append_page_to_pdf( $pdf1, $pdf2, $_ ), 1..$pdf2->pages;
    $pdf2->end;
    return $pdf1;
}

# does what it says
sub open_pdf {
    my $file = $_[0];
    my $pdf = PDF::API2->open( $file );
    print "Opened pdf ( $file )\n";
    return $pdf;
}

# reduces merge_2_pdfs over an array of pdfs
sub merge_pdfs {
    my @files = @_;
    my $starting_filename = shift @files;
    my $start_pdf = &open_pdf( $starting_filename );
    my $final_pdf = reduce { &merge_2_pdfs( $a, &open_pdf( $b ) ) } $start_pdf, @files;
    return $final_pdf;
}

# Get the arguments ie save_name, file1, file2, file3, ...
my @files = @ARGV;
my $save_name = shift @files;
my $save = &merge_pdfs( @files );
$save->saveas( $save_name );
4

3 回答 3

4

您的代码中的实际问题是因为您shift在合并它们之前关闭了其中一个文件。

my $save_name = shift @files; 
# which should be 
my $save_name = $files[0];

否则，代码实际上可以工作，我没有发现任何乱码。

一些提示：

  1. use strict和use warnings

  2. 现在的一般做法是&在您的子例程调用中省略 。有关该规则的例外情况，请参见此处。

  3. 在这种情况下，子例程会使您的代码变得冗长，从而使其更难遵循。这里有更简洁的东西。

    use strict;
use warnings;
use List::Util 'reduce';
use PDF::API2;

my $new
  = reduce { $a->importpage($b, $_) foreach 1 .. $b->pages; $a }
    map { PDF::API2->open($_) }
    @ARGV;
$new->saveas('new.pdf');

  4. 一个简单的循环比使用更容易阅读reduce。

    use PDF::API2;

my $new = PDF::API2->new;
foreach my $filename (@ARGV) {
    my $pdf = PDF::API2->open($filename);
    $new->importpage($pdf, $_) foreach 1 .. $pdf->pages;
}
$new->saveas('new.pdf');
于 2012-04-13T01:03:02.640 回答
1

PDF::重用。

prFile('myFile.pdf');
for my $pdf (@PDFS) {
    prDoc($pdf);
}
prEnd();
于 2012-04-12T17:24:01.103 回答
1

另一种可能性是我的图书馆CAM::PDF。

my $pdf1 = CAM::PDF->new($file1) or die;
my $pdf2 = CAM::PDF->new($file2) or die;
my $pdf3 = CAM::PDF->new($file3) or die;
$pdf1->appendPDF($pdf2);
$pdf1->appendPDF($pdf3);
$pdf1->cleanoutput($outfile);

或者也许将它包装在@ARGV 上的循环中。对于两个 PDF，我有一个简单的 cmdline 包装器来做同样的事情：

appendpdf.pl file1.pdf file2.pdf out.pdf

于 2012-05-05T03:08:28.470 回答