5

我是编写自己的 AutoHotKey 脚本的新手，所以这只是我在这里想念的一些愚蠢的东西。

该脚本的目的是让用户选择一些文本并按下热键 ( Win- W)。菜单弹出，他们单击菜单项。然后应将所选文本复制到剪贴板。这就是我现在要做的。

问题是它第一次工作，然后失败，然后工作，然后失败，等等。它基本上只每隔一段时间工作一次。

我正在运行最新AutoHotKey_l版本（unicode 32bit）的 Win7 x64。

我有一个超时ClipWait，它基本上只是等待，从不接收复制的文本，并发出 ErrorLevel 1。

这是代码：

#SingleInstance force
; EXAMPLE #2: This is a working script that creates a popup menu that is displayed when the user presses the Win-w hotkey.

; Create the popup menu by adding some items to it.
Menu, MyMenu, Add, Demo, Demo

return  ; End of script's auto-execute section.

Demo:
clipboard =  ; Start off empty to allow ClipWait to detect when the text has arrived.
Send ^c
ClipWait, 2  ; Wait for the clipboard to contain text.
if ErrorLevel = 1
{
    MsgBox Copy failed
}
else
{
    MsgBox Copy worked
}
return

#w::Menu, MyMenu, Show  ; i.e. press the Win-w hotkey to show the menu.

任何帮助将不胜感激。

4

1 回答 1

8

当您的脚本在其他程序中表现不定期和/或不同时，
首先要尝试的是模拟按键持续时间和/或按键之间的延迟时间。
这是因为有些程序的设计不是为了处理 AutoHotkey 发送
人工击键的速度。

这是最基本的例子：

f1::
Send, {ctrl down}
Sleep, 40
Send, {c down}
Sleep, 40
Send, {c up}
Sleep, 40
Send, {ctrl up}
Return

我们有几种方法可以使它更简洁。
最简单的（但并不总是可取的，因为它在延迟期间阻塞，不像睡眠）
是SetKeyDelay命令，它只适用于 SendEvent 和 SendPlay 模式。

f2::
SetKeyDelay, 40 ; could be set at the top of the script instead.
Send, {ctrl down}{c down}{c up}{ctrl up}
Return

那些使用 AHK_L 的人可以使用 for 循环和数组：

f3::
For i, element in array := ["{ctrl down}","{c down}","{c up}","{ctrl up}"] {
   Sendinput, %element%
   Sleep, 40
} Return

那些使用 AHK basic（或 AHK_L）的人可以使用Loop, Parse：

f4::
list := "{ctrl down},{c down},{c up},{ctrl up}"
Loop Parse, list, `,
{
    Sendinput, %A_LoopField%
    Sleep, 40
} Return

了解这三种Sendmodes很有用。
更多信息可以在发送命令页面的底部找到。

于 2012-04-12T19:55:04.540 回答