xml - 基于多个属性从 XML 中读取

Question

我有以下格式的 XML：

<Accounts>
  <Account ID="1"   City="Bangalore" Amount="2827561.95" /> 
  <Account ID="225" City="New York"  Amount="12312.00" /> 
  <Account ID="236" City="London"    Amount="457656.00" /> 
  <Account ID="225" City="London"    Amount="23462.40" /> 
  <Account ID="236" City="Bangalore" Amount="2345345.00" /> 
</Accounts>

在这里，使帐户独一无二的是属性ID和City.

我如何阅读Amount独特的？如何读取ID和City属性组合的数量？

例如，我需要使用 和 获取帐户Amount的。如果我使用类似的代码ID=225City=London

Node.GetAttribute('ID')=225

它总是给我第一个 ID=225 的节点

感谢您。

Answer 1

试试XPath，用这句话./Accounts/Account[@ID="225"][@City="London"]定位节点。

试试这个样本

{$APPTYPE CONSOLE}

uses
  MSXML,
  SysUtils,
  ActiveX,
  ComObj;

Const
 XmlStr =
' <Accounts>'+
'  <Account ID ="1"   City="Bangalore" Amount="2827561.95"/>'+
'  <Account ID="225" City="New York"  Amount="12312.00"/>'+
'  <Account ID="236" City="London"    Amount="457656.00"/>'+
'  <Account ID="225" City="London"    Amount="23462.40"/>'+
'  <Account ID="236" City="Bangalore" Amount="2345345.00"/>'+
'</Accounts>';

procedure Test;
Var
  XMLDOMDocument  : IXMLDOMDocument;
  XMLDOMNode      : IXMLDOMNode;
begin
  XMLDOMDocument:=CoDOMDocument.Create;
  XMLDOMDocument.loadXML(XmlStr);
  XMLDOMNode := XMLDOMDocument.selectSingleNode(Format('./Accounts/Account[@ID="%s"][@City="%s"]', ['225', 'London']));
  if XMLDOMNode<>nil then
    Writeln(Format('Amount %s',[String(XMLDOMNode.attributes.getNamedItem('Amount').Text)]));
end;

begin
 try
    CoInitialize(nil);
    try
      Test;
    finally
      CoUninitialize;
    end;
 except
    on E:EOleException do
        Writeln(Format('EOleException %s %x', [E.Message,E.ErrorCode]));
    on E:Exception do
        Writeln(E.Classname, ':', E.Message);
 end;
 Writeln('Press Enter to exit');
 Readln;
end.

Answer 2

function getAmount(Id, City: string): string;
begin
  Result := ''
  aNode := xmldocument1.DocumentElement.ChildNodes['Accounts'];
  for i := 0 to ChildNodes.Count do 
    with aNode.Nodes[i] do
      if (Attributes['ID'] = Id) and (Attributes['City'] = City) then 
      begin
        Result:= Attributes['Amount'];
        Break;
      end;
  end;
end;