2

我读过您需要使用“^”和“！” 运算符，以便构建类似于 ANTLR Works 中显示的解析树（即使您不需要使用它们来获得 ANTLR Works 中的漂亮树）。那么我的问题是如何建造这样一棵树？我已经看过几页关于使用两个运算符和重写的树构造，但说我有一个输入字符串abc abc123和一个语法：

grammar test;

program : idList;
idList : id* ;
id : ID ;

ID : LETTER (LETTER | NUMBER)* ;
LETTER : 'a' .. 'z' | 'A' .. 'Z' ;
NUMBER : '0' .. '9' ;

ANTLR Works 将输出：

ANTLR Works 解释器输出

我不明白的是如何在这棵树的顶部获得“idList”节点（事实上也是语法之一）。如何使用重写和那些运算符重现这棵树？

4

1 回答 1

2

我不明白的是如何在这棵树的顶部获得“idList”节点（事实上也是语法之一）。如何使用重写和那些运算符重现这棵树？

你不能单独使用^和。!这些运算符仅对现有令牌进行操作，而您想创建额外的令牌（并使这些令牌成为子树的根）。您可以使用重写规则并定义一些虚构的标记来做到这一点。

快速演示：

grammar test;

options {
  output=AST;
  ASTLabelType=CommonTree;
}

tokens {
  IdList;
  Id;
}

@parser::members {

  private static void walk(CommonTree tree, int indent) {
    if(tree == null) return;
    for(int i = 0; i < indent; i++, System.out.print("    "));
    System.out.println(tree.getText());
    for(int i = 0; i < tree.getChildCount(); i++) {
      walk((CommonTree)tree.getChild(i), indent + 1);
    }
  }

  public static void main(String[] args) throws Exception {
    testLexer lexer = new testLexer(new ANTLRStringStream("abc abc123"));
    testParser parser = new testParser(new CommonTokenStream(lexer));
    walk((CommonTree)parser.program().getTree(), 0);
  }
}

program : idList EOF -> idList;
idList  : id*        -> ^(IdList id*);
id      : ID         -> ^(Id ID);

ID    : LETTER (LETTER | DIGIT)*;
SPACE : ' ' {skip();};

fragment LETTER : 'a' .. 'z' | 'A' .. 'Z';
fragment DIGIT  : '0' .. '9';

如果您运行上面的演示，您将看到以下内容被打印到控制台：

IdList
    Id
        abc
    Id
        abc123

如您所见，虚构的标记也必须以大写字母开头，就像词法分析器规则一样。如果您想赋予虚构的标记与text它们所代表的解析器规则相同，请改为执行以下操作：

idList  : id*        -> ^(IdList["idList"] id*);
id      : ID         -> ^(Id["id"] ID);

这将打印：

idList
    id
        abc
    id
        abc123
于 2012-04-12T06:23:22.700 回答