sql - 如何从存储过程中返回多行？（甲骨文 PL/SQL）

Question

我想创建一个带有一个参数的存储过程，该参数将根据参数返回不同的记录集。这样做的方法是什么？我可以从普通 SQL 调用它吗？

Answer 1

以下是如何构建一个函数，该函数返回一个可以像查询表一样查询的结果集：

SQL> create type emp_obj is object (empno number, ename varchar2(10));
  2  /

Type created.

SQL> create type emp_tab is table of emp_obj;
  2  /

Type created.

SQL> create or replace function all_emps return emp_tab
  2  is
  3     l_emp_tab emp_tab := emp_tab();
  4     n integer := 0;
  5  begin
  6     for r in (select empno, ename from emp)
  7     loop
  8        l_emp_tab.extend;
  9        n := n + 1;
 10       l_emp_tab(n) := emp_obj(r.empno, r.ename);
 11     end loop;
 12     return l_emp_tab;
 13  end;
 14  /

Function created.

SQL> select * from table (all_emps);

     EMPNO ENAME
---------- ----------
      7369 SMITH
      7499 ALLEN
      7521 WARD
      7566 JONES
      7654 MARTIN
      7698 BLAKE
      7782 CLARK
      7788 SCOTT
      7839 KING
      7844 TURNER
      7902 FORD
      7934 MILLER

Answer 2

我想你想返回一个 REFCURSOR：

create function test_cursor 
            return sys_refcursor
            is
                    c_result sys_refcursor;
            begin
                    open c_result for
                    select * from dual;
                    return c_result;
            end;

更新：如果您需要从 SQL 调用它，请使用@Tony Andrews 建议的表函数。

Answer 3

您可以使用 Oracle 流水线函数

基本上，当您希望将 PLSQL（或 java 或 c）例程作为数据的“源”而不是表时，您将使用流水线函数。

简单示例 - 生成一些随机数据
如何根据输入参数创建 N 个唯一随机数？

create type array
as table of number;


create function  gen_numbers(n in number default null)
return array
PIPELINED
as
begin
  for i in 1 .. nvl(n,999999999)
  loop
     pipe row(i);
 end loop;
 return;
end;

假设我们需要三行来做某事。我们现在可以通过以下两种方式之一做到这一点：

select * from TABLE(gen_numbers(3));

COLUMN_VALUE

---

       1
       2
       3

或者

select * from TABLE(gen_numbers)
 where rownum <= 3;

COLUMN_VALUE

---

       1
       2
       3

管道函数 1 管道函数2

Answer 4

如果您想在纯 SQL 中使用它，我会让存储过程用结果行填充一个表或临时表（或使用@Tony Andrews 方法）。
如果要使用@Thilo 的解决方案，则必须使用 PL/SQL 循环游标。这里有一个例子：（我使用了一个过程而不是一个函数，就像@Thilo 所做的那样）

create or replace procedure myprocedure(retval in out sys_refcursor) is
begin
  open retval for
    select TABLE_NAME from user_tables;
end myprocedure;

 declare 
   myrefcur sys_refcursor;
   tablename user_tables.TABLE_NAME%type;
 begin
   myprocedure(myrefcur);
   loop
     fetch myrefcur into tablename;
     exit when myrefcur%notfound;
     dbms_output.put_line(tablename);
   end loop;
   close myrefcur;
 end;

Answer 5

create procedure <procedure_name>(p_cur out sys_refcursor) as begin open p_cur for select * from <table_name> end;