perl - 按字典顺序排序

Question

我从以下代码中看到了结果，但我不完全理解在以下示例 中如何or知道该做什么：sort

use Data::Dumper;

$animals{'man'}{'name'} = 'paul';
$animals{'man'}{'legs'} = 2;
$animals{'cheeta'}{'name'} = 'mike';
$animals{'cheeta'}{'legs'} = 3;
$animals{'zebra'}{'name'} = 'steve';
$animals{'zebra'}{'legs'} = 4;
$animals{'cat'}{'name'} = '';
$animals{'cat'}{'legs'} = 3;
$animals{'dog'}{'name'} = '';
$animals{'dog'}{'legs'} = 4;
$animals{'rat'}{'name'} = '';
$animals{'rat'}{'legs'} = 5;

@animals = sort {
      $animals{$a}{'name'} cmp $animals{$b}{'name'}
   or $animals{$a}{'legs'} <=> $animals{$b}{'legs'}
} keys %animals;

print Dumper(\@animals);

Answer 1

sortsub（{}后面的东西sort）定义了一个两层排序：首先按名称，然后按腿数。实现了两个标准之间的or交叉。更容易看出您是否以不同的方式格式化代码：

@animals = sort {
    $animals{$a}{'name'} cmp $animals{$b}{'name'} or
    $animals{$a}{'legs'} <=> $animals{$b}{'legs'}
} keys %animals;

cmpand运算符返回三个值之一（<=>-1、0 或 1），具体取决于左侧参数是小于、等于还是大于右侧参数。（cmp进行字符串比较，<=>进行数字比较。）在 Perl 中，0 为假，而 -1 和 1 为真。如果cmp返回真值，则or立即返回该值，并sort适当地重新排序元素。如果cmp返回 false，<=>则计算 并返回其结果。

在进行多层排序时，通常使用“map-sort-map”技术（又名Schwartzian Transform）：

@animals =
  map  { $_->[0] }
  sort {
    $a->[1] cmp $b->[1] ||
    $a->[2] <=> $b->[2]
  }
  map { [$_, $animal{$_}{name}, $animal{$_}{legs}] }
  keys %animal;

这不是很清楚，但因为它通常具有更好的性能，所以它是一个常见的习语。当比较的操作数是函数时，这一点尤其重要——这种技术可以防止对每次比较进行不必要的（并且可能是昂贵的）重新计算。例如，如果您按长度对字符串进行排序，则只需计算每个字符串的长度一次。

Answer 2

or是一个短路求值器，因此如果它为真（即任何非零值），它将返回左侧的值，否则将评估右侧的值。

所以在这种情况下，如果动物的名字比较相等，（0 - 假），腿的数量将被计算用于排序目的。

Answer 3

我可以建议Sort::Key作为当前代码的替代方案吗？

use Sort::Key::Multi qw(sikeysort);  # sort keyed on (string, integer)
@animals = sikeysort { $animals{$_}{name}, $animals{$_}{legs} } keys %animals;

# alternately,
use Sort::Key::Maker sort_by_name_then_legs =>
    sub { $animals{$_}{name}, $animals{$_}{legs} }, qw(string integer);
@animals = sort_by_name_then_legs keys %animals;