1

如何在 SQL 中使用宏？（对于每一件事，这是被选中的）

我的意思是这样的：

&VarTable是一个表，它有两个变量：（例如）Lib和Table

中的每个观察&VarTable都是表的名称：Lib.Table

我想为每张桌子做一些事情：

1）存在吗？

2）排序

最后一个条件：每个表（如果存在）都有一个变量&VarField。

   %macro mSortedTable(vLib,vTab,vVar);
        %if %sysfunc(exist(&vLib..&vTab)) %then %do;
             proc sort data = &vLib..&vTab;
                 by &vVar; 
             run;
             &vLib..&vTab
        %end; 
        %else %do; "" %end;
   %mend mSortedTable;

   proc sql noprint;
          select %mSortedTable(vLib=Lib,vTab=Table,vVar=&VarField)
              into: AccumVar separated by " "
          from &VarTable;
   quit;

如何用 sql 和宏来做到这一点？

4

2 回答 2

2

你必须使用sql和宏吗？一个简单的数据步骤，call execute可以在这里做你需要的。

下面是一个示例，它采用具有要处理的表列表的数据集，检查表是否存在，如果存在，则按 &VarField 对其进行排序。如果需要，这可以很容易地扩展为通过一组自定义变量对每个表进行排序。

如果该表不存在，则会生成一条警告消息。

/* create fake data */
data testdat;
length lib $8 table $32;
input lib $ table $;
datalines;
work test1
work test2
work test3
work doesnotexist
;
run;
/* create 3 data sets */
data work.test1 work.test2 work.test3;
input var1 var2 var3;
datalines;
1 34 8
2 54 5
12 5 6
;
run;
/* end create data */

%let VarTable=work.testdat;
%let VarField=var2 var3;


data _null_;
  set &VarTable;
  dsname=catx('.',lib,table);
  if exist(dsname) then do;
    call execute("proc sort data=" || strip(dsname) || "; by &VarField; run;");
  end;
  else do;
    put "WARNING: The data set does not exist: " lib= table=;
  end;
run;
于 2012-04-10T20:36:24.247 回答
1

调用执行是一个很好的解决方案，但是如果“执行”的数据步骤代码很复杂（在这个例子中不是这样），我发现很难调试。

另一种方法是将所有变量放入宏变量中，然后在宏do-loop中循环遍历它们；

（基于@cmjohns 数据）

/* create fake data */
data testdat;
 length lib $8 table $32;
 input lib $ table $;
 datalines;
 work test1
 work test2
 work test3
 work doesnotexist
 ;
run;

/* create 3 data sets */
data work.test1 work.test2 work.test3;
 input var1 var2 var3;
 datalines;
 1 34 8
 2 54 5
 12 5 6
 ;
run;
/* end create data */

%let VarTable=work.testdat;
%let VarField=var2 var3;

proc sql noprint;
 select count(lib)
 into :cnt
 from &vartable;

 %Let cnt=&cnt;

 select strip(lib), strip(table)
 into :lib1 - :lib&cnt, :table1 - :table&cnt
 from &vartable;
quit;

%Macro test;
 %Do i = 1 %to &cnt;

  %Let lib=&&lib&i;
  %Let table=&&table&i;
  %Let dsn=&lib..&table;

  %if %sysfunc(exist(&dsn)) %then %do;
   Proc sort data=&dsn;
    by &varfield;
   run;
  %end;
  %else %do;
   %put WARNING: The data set does not exist: &dsn;
  %end;

 %end;
%Mend;
%test
于 2012-04-12T14:37:21.887 回答