9

我有first.bat和second.bat。

first.bat 是：call second.bat

第二个是：（echo %~n0显示执行批处理的文件名）

输出是Second.bat，但我希望它显示调用者文件名，而不是它自己的。

这可能吗？

4

3 回答 3

9

此批处理检测调用者脚本的名称，或者即使它是直接从命令行调用的

@echo off
setlocal DisableDelayedExpansion
set "func=%~0"
for /F "delims=\" %%X in ("%func:*\=%") do set "func=%%X"
if ":" == "%func:~0,1%" (
    goto %func%
)
REM *** Get the name of the caller
(
    (goto) 2>nul
    setlocal DisableDelayedExpansion
    call set "caller=%%~f0"
    call set _caller=%%caller:*%%~f0=%%
    if defined _caller (
        set "callType=batch"
        call "%~d0\:mainFunc\..%~pnx0" %*
    ) ELSE (
        set "callType=cmd-line"
        cmd /c "call "%~d0\:mainFunc\..%~pnx0" %*"
    )
    endlocal
)
echo NEVER REACHED
exit /b

:mainFunc
echo :mainFunc of %~nx0 arg1=%1 is called from '%caller%'/%callType%
exit /b

它使用了这样一个事实，即一条(goto)语句将从堆栈中删除一个级别。
这将导致离开当前的批处理文件，并且%~f0将是调用者脚本的名称（以及%~0该批处理的当前函数）或%~f0从命令行调用的文本。

然后再次调用自己的脚本"%~d0\:mainFunc\..%~pnx0"

外部脚本

为了方便使用，您可以添加一个帮助批处理文件。
使用此行在您自己的脚本中使用它

@echo off
<:GetCaller <nul call GetCaller.bat myCallerVar
echo This batch was called from "%myCallerVar%"

将帮助程序批处理文件命名为GetCaller.bat

@echo off
setlocal DisableDelayedExpansion
set "func=%~0"
for /F "delims=\" %%X in ("%func:*\=%") do set "func=%%X"
if ":" == "%func:~0,1%" (
    goto %func%
)

REM *** STEP1
REM *** Get the filename of the caller of this script, needed for later restart that
(
    (goto) 2>nul
    setlocal DisableDelayedExpansion %= it could be reenabled by the GOTO =%
    set "_returnVar=%~1"
    call set "_lastCaller=%%~f0"
    call set "_argToLastCaller=%%*"
    call "%~d0\:Step2\..%~pnx0" %*
)
exit /b %= This is never reached =%

:Step2
REM *** STEP2
REM *** Get the filename/cmd-line of the caller of the script
(
    (goto) 2>nul
    (goto) 2>nul
    setlocal DisableDelayedExpansion %= it could be reenabled by the GOTO =%    
    set "_returnVar=%_returnVar%"
    set "_lastCaller=%_lastCaller%"
    set "_argToLastCaller=%_argToLastCaller%"
    call set "caller=%%~f0"
    call set _caller=%%caller:*%%~f0=%%
    if defined _caller (
        set "callType=batch"
        call "%~d0\:Step3batch\..%~pnx0"
    ) ELSE (
        set "callType=cmd-line"
        cmd /c "call "%~d0\:Step3batch\..%~pnx0" "
    )
    endlocal
)
exit /b %= This is never reached =%

:Step3batch
REM *** STEP3 Restart the requester batch, but jump to the label :GetCaller
call :GetCaller
exit /b %= This is never reached =%

:GetCaller
REM *** This uses the trick, that starting a batch without CALL will jump to the last used label
if "%_returnVar%" NEQ "" set "%_returnVar%=%_caller%"
%_lastCaller% %_argToLastCaller%

echo #6 never reached
于 2017-03-30T16:35:37.323 回答
6

我认为最简单的方法是将第一批的文件名作为参数传递给第二批，就像这样。

REM First.bat
call Second.bat %~n0

REM Second.bat
echo %1

希望这可以帮助！

于 2012-04-10T11:41:01.837 回答
5

%~n0在调用之前将的值存储在环境变量中second.bat

于 2012-04-10T11:30:34.427 回答