1

可能重复：
如何在运行时在主题和非主题之间切换应用程序？

我创建了一个运行时主题选项设置为未启用的 GUI 应用程序，并且需要在应用程序初始化期间手动启用嵌入式清单的选项。

问题：

VCL 是否允许扩展点来实现它？

让我解释：

  • 自定义清单作为字符串常量嵌入到二进制文件中。
  • 使用命令行参数开关启用运行时主题，例如：MyApp.exe -themeOn

我已经深入研究了 Forms.TApplication，希望能找到一个句柄，但没有发现任何有趣的东西指向一个方向。

4

1 回答 1

5

我会反过来做。我将通过在项目设置中启用运行时主题来包含标准 comctl v6 清单。然后我会SetThemeAppProperties在启动时从 .dpr 文件中调用，以在必要时禁用运行时主题。

procedure DisableRuntimeThemes;
begin
  InitThemeLibrary;
  if Assigned(SetThemeAppProperties) then
    SetThemeAppProperties(STAP_ALLOW_NONCLIENT);
end;

begin
  if not FindCmdLineSwitch('themeOn') then
    DisableRuntimeThemes;
  Application.Initialize;
  Application.MainFormOnTaskbar := True;
  Application.CreateForm(TMainForm, MainForm);
  Application.Run;
end.

您需要确保它UxTheme在 .dpr uses 子句中，或者甚至更好地将该功能移至其自己的专用单元。

正常包含清单然后禁用运行时主题更容易。启用运行时主题的替代方案涉及激活上下文，这比这种方法涉及更多。

已经说过这比使用激活上下文更容易，我决定看看其中涉及到什么。这就是我想出的：

unit ActivateRuntimeThemes;

interface

implementation

uses
  Windows, SysUtils;

type
  TActivationContext = class
  private
    FActCtxHandle: THandle;
    FCreateActCtx: function(var pActCtx: TActCtx): THandle; stdcall;
    FActivateActCtx: function(hActCtx: THandle; var lpCookie: LongWord): BOOL; stdcall;
    FDeactivateActCtx: function(dwFlags: DWORD; ulCookie: LongWord): BOOL; stdcall;
    FReleaseActCtx: procedure(hActCtx: THandle); stdcall;
    FCookie: LongWord;
    FSucceeded: Boolean;
  public
    constructor Create;
    destructor Destroy; override;
  end;

constructor TActivationContext.Create;
var
  ActCtx: TActCtx;
  hKernel32: HMODULE;
begin
  inherited;
  hKernel32 := GetModuleHandle(kernel32);
  FCreateActCtx := GetProcAddress(hKernel32, 'CreateActCtxW');
  if Assigned(FCreateActCtx) then
  begin
    FReleaseActCtx := GetProcAddress(hKernel32, 'ReleaseActCtx');
    FActivateActCtx := GetProcAddress(hKernel32, 'ActivateActCtx');
    FDeactivateActCtx := GetProcAddress(hKernel32, 'DeactivateActCtx');
    ZeroMemory(@ActCtx, SizeOf(ActCtx));
    ActCtx.cbSize := SizeOf(ActCtx);
    ActCtx.lpSource := 'C:\desktop\comctlv6.manifest.txt';
    FActCtxHandle := FCreateActCtx(ActCtx);
    FSucceeded := (FActCtxHandle<>INVALID_HANDLE_VALUE) and FActivateActCtx(FActCtxHandle, FCookie);
  end
  else
    FActCtxHandle := INVALID_HANDLE_VALUE;
end;

destructor TActivationContext.Destroy;
begin
  if FSucceeded then
    FDeactivateActCtx(0, FCookie);
  if FActCtxHandle<>INVALID_HANDLE_VALUE then
    FReleaseActCtx(FActCtxHandle);
  inherited;
end;

var
  ActivationContext: TActivationContext;

procedure FinaliseActivationContext;
begin
  ActivationContext.Free;
end;

initialization
  if FindCmdLineSwitch('themeOn') then
    ActivationContext := TActivationContext.Create;

finalization
  ActivationContext.Free;

end.

您应该尽早将本单元包含在您的 .dpr 文件中。在任何内存管理器之后，但在任何 RTL/VCL 单元之前。在项目设置中将运行时主题设置为无。您可能希望将清单文件作为资源包含在内，但为了方便起见，我在此处将其作为文件完成。

于 2012-04-09T14:44:38.013 回答