3

在我的 .vimrc 我有线条

:set foldmethod=marker
:set foldmarker=SECTION:,ENDSECTION:

用于自定义代码折叠。在我的文件中，相应语言中的注释字符在代码折叠标记之前，然后是相应部分的标题。例如

# SECTION: First Section
some code
# SECTIION: Subsection
some more code
# ENDSECTION: 
# ENDSECTION: 

# SECTION: Second Section
some other code
# ENDSECTION:

该结构具有为文件生成内容所需的所有内容，例如

First Section
    Subsection
Second Section

（理想情况下，该索引具有类似于 vim 帮助系统的标记，因此我可以轻松跳转到相应的 SECTION；我不知道如何实现这一点）。我可以想到一个生成此文本的简单 perl 脚本，但我更喜欢基于 vim 脚本的解决方案，该脚本在新窗口中显示索引。也许已经有一个解决方案可以做到这一点？

4

1 回答 1

2

把它放在你的 vimrc 中并运行:MkIdxor <leader>z。您也可以将范围传递给命令，但默认为整个缓冲区。

function! MkIdx() range
      let items = filter(getline(a:firstline, a:lastline), 'v:val =~ ''\C^\s*#\s\+SECTION''')
      new
      call setline(1, map(items, 'substitute(v:val, ''^\(\s*\)[^:]\+:\(.\+\)'', ''\1\2'', '''')'))
      " Mapping to jump to section:
      nnore <silent><buffer><leader>x :<C-U>call Go2Section()<CR>
endfunction

function! Go2Section()
      let section = matchstr(getline('.'), '^\s*\zs.*')
      quit
      call search('\C# SECTION:\s\+'.section, 'cw')
endfunction

command! -bar -range=% MkIdx <line1>,<line2>call MkIdx()
" Mapping to build the index:
nnore <silent><leader>z :<C-U>MkIdx<CR>

编辑：将索引放在新缓冲区上。

编辑2：不要留下空行。

编辑 3：允许跳回带有<leader>x.

于 2012-04-09T19:41:36.873 回答