4

我有一个 Mojolicious Lite 脚本，它“发出”一个可执行文件（用户可以从脚本的 URL 下载文件）。我将编码数据保存在 DATA 部分的内联模板中，然后对其进行编码和 render_data。

get '/download' => sub {
    my $self = shift;

    my $hex_data = $self->render_partial( 'TestEXE' );
    my $bin_data;
    while( $hex_data =~ /([^\n]+)\n?/g ) {
        $bin_data .= pack "H".(length $1), $1;
    }

    my $headers = Mojo::Headers->new; 
    $headers->add( 'Content-Type', 'application/x-download;name=Test.exe' );
    $headers->add( 'Content-Disposition', 'attachment;filename=Test.exe' );
    $headers->add( 'Content-Description', 'File Transfer');

    $self->res->content->headers($headers);
    $self->render_data( $bin_data ); 
};

__DATA__

@@ TestEXE.html.ep
4d5a90000300000004000000ffff0000b8000000000000004000000000000000
00000000000000000000000000000000000000000000000000000000b0000000
0e1fba0e00b409cd21b8014ccd21546836362070726f6772616d2063616e6e6f
....

当我在本地运行它时（通过http://127.0.0.1:3000/上的内置网络服务器，Win7），我得到了正确的文件（大小和内容）。但是当我在共享主机 (Linux) 上以 CGI 模式运行它时，它会以正确的大小返回，但文件的前 8 个字节总是不正确的（并且总是不同的）。文件的其余部分是正确的。

如果在我的潜艇中我指定$hex_data而不是$bin_data我得到假设存在的东西。

我迷路了。

4

1 回答 1

5

render_partial不是你想要的。

首先，将可执行文件重新编码为 base64 格式，并指定模板为 base64 编码（假设您的应用不需要十六进制）：

@@ template-name (base64)

此外，您实际上根本不需要控制器方法。Mojolicious 将为您处理该过程 - 您所要做的就是适当地命名模板。

use Mojolicious::Lite;

app->start;

__DATA__

@@ Test.exe (base64)
...

然后http://127.0.0.1:3000/Test.exe将下载该文件。

-

如果您仍想对特定于应用程序的问题使用控制器方法，请专门获取数据模板：

use Mojolicious::Lite;

get '/download' => sub {
    my $self = shift;

    # http://mojolicio.us/perldoc/Mojolicious/Renderer.pm#get_data_template
    my $data = $self->app->renderer->get_data_template({}, 'Test.exe');

    # Replace content-disposition instead of adding it, 
    # to prevent duplication from elsewhere in the app
    $self->res->headers->header(
        'Content-Disposition', 'attachment;filename=name.exe');

    $self->render_data($data);
};

app->start;

__DATA__

@@ Test.exe (base64)
...

http://127.0.0.1:3000/download将获取模板，设置标题，然后将其下载为name.exe。

于 2012-04-07T20:02:00.210 回答