5

给定以下 XML：

<?xml version="1.0" encoding="UTF-8" ?>
<?xml-stylesheet type="text/xsl" href="form.xsl"?>
<Document>
  <Translations>
    <Translation name="Resource">Invariant Resource</Translation>
    <Translation name="Resource" lang="en">English Resource</Translation>
    <Translation name="Resource" lang="en-CA">Canadian English Resource</Translation>
    <Translation name="Resource" lang="en-GB">British English Resource</Translation>
    <Translation name="Message">Invariant Message</Translation>
    <Translation name="Message" lang="en">English Message</Translation>
    <Translation name="Message" lang="en-CA">Canadian English Message</Translation>
    <Translation name="Message" lang="en-AU">Australian English Message</Translation>
  </Translations>
</Document>

我需要选择一组翻译元素，以便该集合包含“名称”属性的唯一值，以及给定语言环境的“最佳匹配”（'en-US'、'es-MX'、'fr'、 ETC。）。当我说最佳匹配时，我想首先查找具有完全匹配语言环境的元素，然后仅根据前两个字符查找匹配，然后查找未指定语言的元素。

例如，如果我在转换上述数据时传入“en-CA”的语言环境，我想得到以下两个元素：

<Translation name="Resource" lang="en-CA">Canadian English Resource</Translation>
<Translation name="Message" lang="en-CA">Canadian English Message</Translation>

但如果我传入“en-GB”，我想得到：

<Translation name="Resource" lang="en-GB">British English Resource</Translation>
<Translation name="Message" lang="en">English Message</Translation>

最后，如果我传入一个诸如“es”或“es-MX”之类的值，我希望得到：

<Translation name="Resource">Invariant Resource</Translation>
<Translation name="Message">Invariant Message</Translation>

我对 XSLT 非常陌生，但我认为我有一些有用的东西。我只需要知道是否有更好的方法（更简单、更优雅、更高效等）

这是我的第一次尝试：

<?xml version="1.0" encoding="UTF-8" ?>
<xsl:stylesheet version="1.0" xmlns:fn="http://www.w3.org/2005/xpath-functions" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output encoding="utf-8" indent="yes" method="xml" omit-xml-declaration="yes"/>

  <xsl:key match="Translation" name="TranslationName" use="concat(@name,':',@lang)"/>

  <xsl:template match="/">
    <!-- locale parameter for translation -->
    <xsl:param name="locale"/>

    <xsl:for-each select="Document/Translations/Translation[@lang=$locale or @lang=substring($locale,1,2) or not(@lang)]">
      <xsl:choose>
        <xsl:when test="@lang=$locale and count(key('TranslationName', concat(@name,':',$locale)))=1">
          <xsl:element name="p">
            <xsl:value-of select="."/>
          </xsl:element>
        </xsl:when>
        <xsl:when test="@lang=substring($locale,1,2) and count(key('TranslationName', concat(@name,':',$locale)))=0">
          <xsl:element name="p">
            <xsl:value-of select="."/>
          </xsl:element>
        </xsl:when>
        <xsl:when test="not(@lang) and count(key('TranslationName', concat(@name,':',$locale))|key('TranslationName', concat(@name,':',substring($locale,1,2))))=0">
          <xsl:element name="p">
            <xsl:value-of select="."/>
          </xsl:element>
        </xsl:when>
      </xsl:choose>
    </xsl:for-each>
  </xsl:template>
</xsl:stylesheet>

这是我第一次发布问题，所以如果我需要添加/编辑/删除任何内容，请告诉我。

谢谢！

4

2 回答 2

0

如果您可以使用 msxsl:node-set 等，您可以这样做：

<xsl:template match="/">
    <xsl:param name="locale" select="'en-AU'"/>
<!-- locale parameter for translation -->
    <xsl:variable name="sorted">
        <xsl:for-each select="Document/Translations/Translation">
            <xsl:sort select="@name"/>
            <xsl:sort select="not(@lang=$locale)"/>
            <xsl:sort select="not(starts-with(@lang, substring($locale,1,2)))"/>
            <xsl:sort select="@lang"/>
            <xsl:copy-of select="."/>
        </xsl:for-each>
    </xsl:variable>
    <xsl:for-each select="msxsl:node-set($sorted)/*">
        <xsl:if test="position() = 1 or @name!=preceding-sibling::*[1]/@name">
            <xsl:copy-of select="."/>
        </xsl:if>
    </xsl:for-each>
</xsl:template>

PS这可能适用于标准1.0

<xsl:template match="/">
    <xsl:param name="locale" select="'en-AU'"/>
<!-- locale parameter for translation -->
    <xsl:variable name="path" select="Document/Translations/Translation"/>
    <xsl:for-each select="$path">
        <xsl:variable name="curName" select="$path[@name=current()/@name]"/>
        <xsl:if test="count($curName[1] | .)=1">
            <xsl:for-each select="$curName">
            <xsl:sort select="not(@lang=$locale)"/>
            <xsl:sort select="not(starts-with(@lang, substring($locale,1,2)))"/>
            <xsl:sort select="@lang"/>
            <xsl:if test="position()=1">
                <xsl:copy-of select="."/>
            </xsl:if>
            </xsl:for-each>
        </xsl:if>
    </xsl:for-each>
</xsl:template>

PPS 如果您不想排序，您可以只进行过滤（保留文档顺序）。此外，不同的分组机制：

<xsl:template match="/">
    <xsl:param name="locale" select="'en'"/>
    <xsl:variable name="locale-lang" select="substring($locale,1,2)"/>
<!-- locale parameter for translation -->
    <xsl:variable name="path" select="Document/Translations/Translation"/>
    <xsl:for-each select="$path[not(preceding-sibling::Translation/@name=@name)]">
        <xsl:variable name="curName" select="$path[@name=current()/@name]"/>
        <xsl:variable name="test1" select="$curName[@lang=$locale]"/>
        <xsl:variable name="test2" select="$curName[@lang=$locale-lang]"/>
        <xsl:variable name="test3" select="$curName[starts-with(@lang, $locale-lang)]"/>
        <xsl:variable name="test4" select="$curName[not(@lang)]"/>
        <xsl:choose>
            <xsl:when test="$test1">
                <xsl:copy-of select="$test1[1]"/>
            </xsl:when>
            <xsl:when test="$test2">
                <xsl:copy-of select="$test2[1]"/>
            </xsl:when>
            <xsl:when test="$test3">
                <xsl:copy-of select="$test3[1]"/>
            </xsl:when>
            <xsl:when test="$test4">
                <xsl:copy-of select="$test4[1]"/>
            </xsl:when>
        </xsl:choose>
    </xsl:for-each>
</xsl:template>
于 2012-04-05T22:06:18.413 回答
0

这个简短而简单的转换（无变量，xsl:choose, xsl:when, xsl:otherwise, xsl:if, xsl:sort, xsl:element）：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:param name="pCode" select="'en-GB'"/>

 <xsl:key name="kTransName" match="@name" use="."/>

 <xsl:key name="Resource" match="Translation[@name='Resource']"
          use="@lang"/>
 <xsl:key name="Message" match="Translation[@name='Message']"
          use="@lang"/>
 <xsl:key name="Resource" match="Translation[@name='Resource']"
                          use="boolean(@lang)"/>
 <xsl:key name="Message" match="Translation[@name='Message']"
                          use="boolean(@lang)"/>

 <xsl:template match="/">

  <xsl:for-each select=
   "/*/*/*/@name[generate-id()=generate-id(key('kTransName', .)[1])]">
      <xsl:copy-of select=
       "key(., $pCode)
       |
        key(., substring($pCode, 1, 2))
          [not(key(current(), $pCode))]
       |
        key(., 'false')
          [not(key(current(), $pCode)
              |
               key(current(), substring($pCode, 1, 2))
              )
          ]
       "/>
   </xsl:for-each>
 </xsl:template>
</xsl:stylesheet>

应用于提供的 XML 文档时：

<Document>
    <Translations>
        <Translation name="Resource">Invariant Resource</Translation>
        <Translation name="Resource" lang="en">English Resource</Translation>
        <Translation name="Resource" lang="en-CA">Canadian English Resource</Translation>
        <Translation name="Resource" lang="en-GB">British English Resource</Translation>
        <Translation name="Message">Invariant Message</Translation>
        <Translation name="Message" lang="en">English Message</Translation>
        <Translation name="Message" lang="en-CA">Canadian English Message</Translation>
        <Translation name="Message" lang="en-AU">Australian English Message</Translation>
    </Translations>
</Document>

产生想要的正确结果：

<Translation name="Resource" lang="en-GB">British English Resource</Translation>
<Translation name="Message" lang="en">English Message</Translation>

如果我们将全局/外部参数更改为：

 <xsl:param name="pCode" select="'en-CA'"/>

再次产生正确的结果：

<Translation name="Resource" lang="en-CA">Canadian English Resource</Translation>
<Translation name="Message" lang="en-CA">Canadian English Message</Translation>

如果我们将全局/外部参数更改为：

 <xsl:param name="pCode" select="'es-MX'"/>

再次产生了想要的结果：

<Translation name="Resource">Invariant Resource</Translation>
<Translation name="Message">Invariant Message</Translation>
于 2012-04-06T03:09:52.167 回答