sql - 如何从一个存储过程中从 SYS_REFCURSOR 中获取数据并在另一个过程中使用它？

Question

我有一个存储过程，其基本布局如下，它返回一个 sys_refcursor 作为结果集。（从技术上讲，它会重复四个，但为了清楚起见，我只说一个）。结果集是从临时表中选择的。

procedure aProcedure
( C1 in out sys_refcursor
) is
begin
--populate Temp_Table here with a stored proc call;
OPEN C1 FOR
SELECT Cols
FROM TEMP_TABLE;

我需要使用不同的存储过程将此结果集从 C1 插入到永久表中。这是可行的还是我需要重新构建结果集？

我已经能够找到有关在 oracle 之外使用游标和结果集的信息，但不能在其内部使用它们。

我知道从第一个存储过程中进行插入可能是有意义的，但这并不是我真正需要的。永久保存结果集是一项可选要求。

感谢您提供任何有用的信息。

Answer 1

假设调用者知道aProcedure正在打开的游标的结构，你可以做这样的事情。

declare
  l_rc sys_refcursor;
  l_rec temp_table%rowtype;
begin
  aProcedure( l_rc );
  loop
    fetch l_rc
     into l_rec;
    exit when l_rc%notfound;

    dbms_output.put_line( l_rec.col1 );
  end loop;
  close l_rc;
end;
/

如果您无法获取记录类型，您还可以获取许多其他标量局部变量（数量和类型必须匹配aProcedure其列表中指定的列的数量和类型SELECT）。就我而言，我定义aProcedure为返回两个数字列

declare
  l_rc sys_refcursor;
  l_col1 number;
  l_col2 number;
begin
  aProcedure( l_rc );
  loop
    fetch l_rc
     into l_col1, l_col2;
    exit when l_rc%notfound;
    dbms_output.put_line( l_col1 );
  end loop;
  close l_rc;
end;