26

我在 Lee Naish 的论文Higher-order logic programming in Prolog中遇到了一些不熟悉的 Prolog 语法。这是论文中的第一个代码示例：

% insertion sort (simple version)
isort([], []).
isort(A.As, Bs) :-
    isort(As, Bs1),
    isort(A, Bs1, Bs).

% insert number into sorted list
insert(N, [], [N]).
insert(N, H.L, N.H.L) :-
    N =< H.
insert(N, H.LO, H.L) :-
    N > H,
    insert(N, LO, L).

我的困惑在于A.Asin isort(A.As, Bs) :-。从上下文来看，它似乎是列表的另一种 cons 语法，相当于isort([A|As], Bs) :-.

也N.H.L似乎是一种更方便的说法[N|[H|L]]。

但是 SWI Prolog 不会接受这种不寻常的语法（除非我做错了什么）。

有人认得吗？我的假设正确吗？哪个 Prolog 解释器接受它作为有效语法？

4

3 回答 3

33

点运算符用于 1972 年第一个 Prolog 系统中的列表，用 Algol-W 编写，有时称为 Prolog 0。它的灵感来自 LISP 系统中的类似符号。以下示例来自 Alain Colmerauer 和 Philippe Roussel（Prolog 的创造者）的论文Prolog 的诞生。

+ELEMENT(*X, *X.*Y).
+ELEMENT(*X, *Y.*Z) -ELEMENT(*X, *Z).

那个时候，[]曾经NIL。

下一个 Prolog 版本由 Battani & Meloni 用 Fortran 编写，使用案例来区分原子和变量。然后，DECsystem 10 Prolog 引入了方括号表示法，替换niland X.Xswith []and [X,..Xs]，在后来的 DECsystem 10 版本中，它[X|Xs]作为替代方案被接收。在 ISO Prolog 中，只有[X|Xs],.(X,Xs)和 as 规范语法'.'(X,Xs)。

请注意，点在 ISO Prolog 中有许多不同的角色。它已经作为

  • 后跟一个%或布局字符（如 SPACE、NEWLINE、TAB）时的结束标记。

  • 浮点数中的小数点，例如3.14159

  • 图形标记 char形成图形标记为=..

因此，如果您现在声明.为中缀运算符，则必须非常小心。无论是您编写的内容还是 Prolog 系统将读取的内容。一个额外的空格可以改变一个术语的含义。考虑两种符号中的两个数字列表：

[1,2.3,4]. [5].
1 .2.3.4.[]. 5.[].

请注意，您必须在 . 之后添加一个空格1。在这种情况下，数字前面的额外空格可能会改变您的术语的含义。像这样：

[1|2.3]. [4]. 5. [].
1 .2.3. 4.[]. 5. [].

这是另一个可能更有说服力的例子：

[1,-2].
1.(-2).[].

负数需要点列表中的圆括号。

今天，只剩下 YAP 和 XSB 仍然.默认提供中缀——而且它们的做法不同。XSB 甚至无法识别上述点语法：您需要在一些非负数周围加上圆括号。

你写的那N.H.L似乎是一种更方便的说法[N|[H|L]]。有一个简单的经验法则可以简化 ISO Prolog 中的此类表达式：每当您在列表中看到标记|并且[紧随其后时，您可以将它们替换为,（并删除]右侧的相应标记）。所以你现在可以写：[N,H|L]看起来还不错。

您也可以在另一个方向使用该规则。如果我们有一个列表[1,2,3,4,5]，我们可以将|其用作“剃须刀片”，如下所示 [1,2,3|[4,5]]：

再说一句，因为您正在阅读 Naish 的论文：同时，很好理解onlycall/N是必需的！并且 ISO Prolog支持最多call/1.call/2call/8

于 2012-04-05T13:02:09.933 回答
9

是的，你是对的，点是列表cons中缀运算符。它实际上是 ISO Prolog 标准所要求的，但通常是隐藏的。我前段时间发现（并使用过）该语法：

:- module(eog, []).
:- op(103, xfy, (.)).

% where $ARGS appears as argument, replace the call ($ARGS) with a VAR
% the calle goes before caller, binding the VAR (added as last ARG)
funcs(X, (V, Y)) :-
    nonvar(X),
    X =.. W.As,

    % identify meta arguments
    (   predicate_property(X, meta_predicate M)
        % explicitly exclude to handle test(dcg)
        % I'd like to handle this case in general way...
    ,   M \= phrase(2, ?, ?)
    ->  M =.. W.Ms
    ;   true
    ),

    seek_call(As, Ms, Bs, V),
    Y =.. W.Bs.

% look for first $ usage
seek_call([], [], _Bs, _V) :-
    !, fail.
seek_call(A.As, M.Ms, A.Bs, V) :-
    M @>= 0, M @=< 9, % skip meta arguments
    !, seek_call(As, Ms, Bs, V).
seek_call(A.As, _, B.As, V) :-
    nonvar(A),
    A = $(F),
    F =.. Fp.FAs,
    (   current_arithmetic_function(F) % inline arith
    ->  V = (PH is F)
    ;   append(FAs, [PH], FBs),
        V =.. Fp.FBs
    ),
    !, B = PH.
seek_call(A.As, _.Ms, B.As, V) :-
    nonvar(A),
    A =.. F.FAs,
    seek_call(FAs, Ms, FBs, V),
    !, B =.. F.FBs.
seek_call(A.As, _.Ms, A.Bs, V) :-
    !, seek_call(As, Ms, Bs, V).

:- multifile user:goal_expansion/2.
user:goal_expansion(X, Y) :-
    ( X = (_ , _) ; X = (_ ; _) ; X = (_ -> _) )
    -> !, fail % leave control flow unchanged (useless after the meta... handling?)
    ;  funcs(X, Y).

/* end eog.pl */

有人建议我不要这样做。实际上，[A|B] 语法是 . 运算符，为了可读性而引入。

OT：那是什么代码？

上面的代码是我尝试用函数使 Prolog 变得更甜。即，根据要求引入$算术表达式所需的临时变量（例如）

fact(N, F) :-
     N > 1 -> F is N * $fact($(N - 1)) ; F is 1.

每个 $ 引入一个变量。展开后，我们有一个更传统的事实/2

?- listing(fact).
plunit_eog:fact(A, C) :-
    (   A>1
    ->  B is A+ -1,
        fact(B, D),
        C is A*D
    ;   C is 1
    ).

在我们有很多表达方式的地方，这可能很有用......

于 2012-04-05T06:52:44.180 回答
8

此语法来自 NU-Prolog。见这里。它可能只是普通的列表仿函数 '.'/2 重新定义为中缀运算符，而不需要尾随的空列表：

?- L= .(a,.(b,[])).
L = [a,b]
Yes (0.00s cpu)
?- op(500, xfy, '.').
Yes (0.00s cpu)
?- L = a.b.[].
L = [a,b]
Yes (0.00s cpu)
于 2012-04-05T06:22:37.467 回答