18

我正在尝试在 Perl 中通过 SMTP 发送邮件。

我为此写了一个脚本。

#!perl
use warnings;
use strict;
use Net::SMTP;

my $smtpserver = 'server';
my $smtpport = 25;
my $smtpuser   = 'username';
my $smtppassword = 'password';

my $smtp = Net::SMTP->new($smtpserver, Port=>$smtpport, Timeout => 10, Debug => 1);
die "Could not connect to server!\n" unless $smtp;

$smtp->auth($smtpuser, $smtppassword);
$smtp->to('mymail@gmail.com');
$smtp->data();
$smtp->datasend("To: mymail\@gmail.com\n");
$smtp->quit;

当我运行这个脚本时，我的输出如下：

Net::SMTP>>> Net::SMTP(2.31)
Net::SMTP>>>   Net::Cmd(2.29)
Net::SMTP>>>     Exporter(5.65)
Net::SMTP>>>   IO::Socket::INET(1.31)
Net::SMTP>>>     IO::Socket(1.32)
Net::SMTP>>>       IO::Handle(1.31)
Net::SMTP=GLOB(0x273faf0)<<< 220 server GMX Mailservices E
Net::SMTP=GLOB(0x273faf0)>>> EHLO localhost.localdomain
Net::SMTP=GLOB(0x273faf0)<<< 250-server GMX Mailservices
Net::SMTP=GLOB(0x273faf0)<<< 250-8BITMIME
Net::SMTP=GLOB(0x273faf0)<<< 250-ENHANCEDSTATUSCODES
Net::SMTP=GLOB(0x273faf0)<<< 250-SIZE
Net::SMTP=GLOB(0x273faf0)<<< 250-AUTH=LOGIN PLAIN
Net::SMTP=GLOB(0x273faf0)<<< 250-AUTH LOGIN PLAIN
Net::SMTP=GLOB(0x273faf0)<<< 250 STARTTLS
Net::SMTP=GLOB(0x273faf0)>>> RCPT TO:<mymail@gmail.com>
Net::SMTP=GLOB(0x273faf0)<<< 503 5.5.1 MAIL first {mp-eu001}
Net::SMTP=GLOB(0x273faf0)>>> DATA
Net::SMTP=GLOB(0x273faf0)<<< 503 5.5.1 MAIL first {mp-eu001}
Net::SMTP=GLOB(0x273faf0)>>> To: mymail@gmail.com
Net::SMTP=GLOB(0x273faf0)>>> .
Net::SMTP=GLOB(0x273faf0)<<< 502 5.5.2 Unimplemented {mp-eu001}
Net::SMTP=GLOB(0x273faf0)>>> QUIT
Net::SMTP=GLOB(0x273faf0)<<< 502 5.5.2 Unimplemented {mp-eu001}

我没有足够的关于 Perl 和 SMTP 的信息，所以我无法理解这个错误。

我该如何解决这个问题？

4

6 回答 6

29

You have to start a SMTP session (after authorization, if necessary) with a MAIL command giving the sender's email address. That's why the responses say "MAIL first" (5xx is an error response). So:

$smtp->auth($smtpuser, $smtppassword);
$smtp->mail('sender@example.com');
$smtp->to('mymail@gmail.com');

But if you're not a SMTP expert, why not use a higher-level module like Email::Sender instead of the low-level Net::SMTP?

use strict;
use warnings;

use Email::Sender::Simple qw(sendmail);
use Email::Sender::Transport::SMTP ();
use Email::Simple ();
use Email::Simple::Creator ();

my $smtpserver = 'server';
my $smtpport = 25;
my $smtpuser   = 'username';
my $smtppassword = 'password';

my $transport = Email::Sender::Transport::SMTP->new({
  host => $smtpserver,
  port => $smtpport,
  sasl_username => $smtpuser,
  sasl_password => $smtppassword,
});

my $email = Email::Simple->create(
  header => [
    To      => 'mymail@gmail.com',
    From    => 'sender@example.com',
    Subject => 'Hi!',
  ],
  body => "This is my message\n",
);

sendmail($email, { transport => $transport });
于 2012-04-04T09:54:51.013 回答
8

这是当前使用 STARTTLS 与 Gmail 一起使用的 cjm 脚本的更新版本（未使用其他 SMTP 服务进行测试）它使用 Email::Sender::Transport::SMTPS 而不是 Email::Sender::Transport::SMTP

您的 gmail 帐户必须允许“访问不太安全的应用程序”（“打开”）——其中“不太安全”并不意味着未加密，它似乎意味着不使用 OAuth 2.0

use strict;
use warnings;

use Email::Sender::Simple qw(sendmail);
use Email::Sender::Transport::SMTPS;
use Email::Simple ();
use Email::Simple::Creator ();

my $smtpserver = 'smtp.gmail.com';
my $smtpport = 587;
my $smtpuser   = 'user@gmail.com';
my $smtppassword = 'password';

my $transport = Email::Sender::Transport::SMTPS->new({
  host => $smtpserver,
  ssl  => 'starttls',
  port => $smtpport,
  sasl_username => $smtpuser,
  sasl_password => $smtppassword,
  debug => 1,
});


my $email = Email::Simple->create(
  header => [
    To      => 'user@example.com',
    From    => 'whatever@gmail.com',
    Subject => 'Hi!',
  ],
  body => "This is my message\n",
);

sendmail($email, { transport => $transport });
于 2015-05-14T13:55:07.303 回答
2

它抱怨缺少MAIL FROM:SMTP 命令。不看任何文档，我猜它看起来像$smtp->from('you@example.net')就像@cjm 写的那样，你需要$smtp->mail('you@example.net');

诚然，在您刚刚通过身份验证后必须提供用户名似乎有点愚蠢，但从历史和向后兼容性的角度来看，这是有道理的（STARTTLS ESMTP 规范可以简单地说明您需要做什么来进行身份验证，然后会话的其余部分就像身份验证完成后的常规 SMTP 一样发生）。Net::SMTP不过，让您免受这些实现细节的影响是有意义的。

于 2012-04-04T09:52:08.047 回答
0

可悲的是，在 2014 年末（非常），Net::SMTP::SSL 未能通过 1 次安装测试中的 1 次，因此无法访问 gmail（和任何其他）基于 Web 的服务器。在不安装我自己的邮件服务器的情况下，我能找到从 Perl 发送电子邮件的唯一方法是将 OLE 发送到 Outlook。然后 Outlook 将使用其连接来实现。

我希望有人能证明我错了。

于 2014-12-25T03:14:36.863 回答
0

顺便说一句 - 虽然有点晚了，但对于未来的读者来说，你真的收到了邮件吗？

附加的输出中没有错误。您已在构造函数中启用调试 (Debug=>1)。一旦将其设置为 0，这些消息就会消失。使用 SMTP 的优点是它包含在库存安装中。无需添加模块。

于 2014-04-30T09:05:09.183 回答
0

对于使用 STARTTLS 的电子邮件服务，最好使用较新的 NET::SMTPS 模块。试试下面的代码：

my $msg = MIME::Lite ->new (  
From => 'from@bellsouth.net',
To => 'to@gmail.com',
Subject => 'Test Message',
Data => 'This is a test',
Type => 'text/html'
);

my $USERNAME = 'from@bellsouth.net';
my $PASSWORD = 'abc123'; 

my $smtps = Net::SMTPS->new("smtp.mail.att.net", Port => 587,  doSSL => 'starttls', SSL_version=>'TLSv1');

$smtps->auth ( $USERNAME, $PASSWORD ) or die("Could not authenticate with bellsouth.\n");

$smtps ->mail('from@bellsouth.net');
$smtps->to('to@gmail.com');
$smtps->data();
$smtps->datasend( $msg->as_string() );  
$smtps->dataend();  
$smtps->quit;
于 2017-07-08T04:55:35.340 回答