5

我已经下载并安装了 comport 库。我有一个模拟器通过串行 RS232 向 Selphi 程序发送数据。这是以下代码片段。

procedure TMainForm.ComPortRxChar(Sender: TObject; Count: Integer);
begin
  ComPort.ReadStr(CPort.Str, Count);
  Memo.Text := Memo.Text + CPort.Str;
end;

至于 CPort 库部分，我补充说：

var
  Str: String;

here is the problem.

通过的数据示例大致如下

$HEHDT,288.45,T*1D
$HEHDT,288.46,T*18
$HEHDT,288.47,T*1A

等等。每行每秒发送一次。因此，使用上面的代码，备忘录将显示所有这些数据。

但是，如果我将代码更改为：

procedure TMainForm.ComPortRxChar(Sender: TObject; Count: Integer);
begin
  ComPort.ReadStr(CPort.Str, Count);
  Memo.Text := Memo.Text + CPort.Str + 'haha';
end;

这是备忘录上出现的内容：

$HEHDT,2haha88.45,T*haha1Dhaha
$HEHDT,2haha88.46,T*haha18haha
$HEHDT,2haha88.47,T*haha1Ahaha

“哈哈”出现在 8 个 ASCII 字符之后。那么这是否意味着在 CPort.pas 库中，在异步/同步部分下，最多仅将 8 个 ASCII 字符分配给变量 Str？

如何更改代码，以便将整个数据字符串（无论其大小）分配给变量 Str 而不是仅 8 个字节。

更新**我意识到 CPort 库的这一部分包含以下代码。谁能告诉我如何编辑代码？或者它是否是我找到的正确块。谢谢！

// split buffer in packets
procedure TComDataPacket.HandleBuffer;

procedure DiscardPacketToPos(Pos: Integer);
var
Str: string;
begin
FInPacket := True;
if Pos > 1 then
begin
  Str := Copy(Buffer, 1, Pos - 1); // some discarded data
  Buffer := Copy(Buffer, Pos, Length(Buffer) - Pos + 1);
  DoDiscard(Str);
end;
end;

procedure FormPacket(CutSize: Integer);
var
Str: string;
begin
Str := Copy(Buffer, 1, CutSize);
Buffer := Copy(Buffer, CutSize + 1, Length(Buffer) - CutSize);
CheckIncludeStrings(Str);
DoPacket(Str);
end;

procedure StartPacket;
var
Found: Integer;
begin
// check for custom start condition
Found := -1;
DoCustomStart(Buffer, Found);
if Found > 0 then
  DiscardPacketToPos(Found);
if Found = -1 then
begin
  if Length(FStartString) > 0 then // start string valid
  begin
    Found := Pos(Upper(FStartString), Upper(Buffer));
    if Found > 0 then
      DiscardPacketToPos(Found);
  end
  else
    FInPacket := True;
end;
end;

procedure EndPacket;
var
Found, CutSize, Len: Integer;
begin
// check for custom stop condition
Found := -1;
DoCustomStop(Buffer, Found);
if Found > 0 then
begin
  // custom stop condition detected
  CutSize := Found;
  FInPacket := False;
end
else
  if Found = -1 then
  begin
    Len := Length(Buffer);
    if (FSize > 0) and (Len >= FSize) then
    begin
      // size stop condition detected
      FInPacket := False;
      CutSize := FSize;
    end
    else
    begin
      Len := Length(FStartString);
      Found := Pos(Upper(FStopString),
        Upper(Copy(Buffer, Len + 1, Length(Buffer) - Len)));
      if Found > 0 then
      begin
        // stop string stop condition detected
        CutSize := Found + Length(FStopString) + Len - 1;
        FInPacket := False;
      end;
    end;
  end;
if not FInPacket then
  FormPacket(CutSize); // create packet
end;
4

3 回答 3

2

你应该做自己的缓冲。这使您可以更灵活地确定消息的界限。例如，如果您使用回车符 (#13) 分隔消息，则可以执行以下操作：

var Buf: string;

procedure DoSomething(const Str: String);
begin
  Memo.Text := Memo.Text + Str;
end;

procedure TMainForm.ComPortRxChar(Sender: TObject; Count: Integer);
var I: Integer;
begin
  ComPort.ReadStr(CPort.Str, Count);
  Buf := Buf + CPort.Str;        
  for i := 1 to Length(Buf) do
    if Buf[i] = #13 then
    begin
      DoSomething(Copy(Buf, 1, i)); 
      Delete(Buf, 1, i+1);
      Break;
    end;
end;
于 2012-04-04T08:48:47.533 回答
2

具有完整错误检查的简约解决方案是：

更新 ：

（假设接收到的字符串以 CRLF 组合结尾，并且包长度不是恒定的。这是一个 NMEA 0183 包）

var
  finalBuf: AnsiString;

// Example packet: $HEHDT,10.17,T*28 + CRLF
// This is a NMEA 0183 protocol (Marine and GPS standard)
// Subset for reading the heading.
// HDT Heading – True
//       1   2 3
//       |   | |
//$--HDT,x.x,T*hh
//1) Heading Degrees, true
//2) T = True
//3) Checksum
// HE stands for: Heading – North Seeking Gyro

{- Checking packet and checksum, calculating heading }
Function ParseAndCheckNMEA_HDT(const parseS: AnsiString;
  var heading: Double): Integer;
// Example packet: $HEHDT,10.17,T*28 + CRLF
var
  i, p, err: Integer;
  xorSum: Byte;
  xorStr: AnsiString;
  headingStr: AnsiString;
begin
  Result := 0; // Assume ok
  if (Pos('$HEHDT', parseS) = 1) then // Start header ok ?
  begin
    p := Pos('*', parseS);
    if (p <> 0) and (Length(parseS) >= p + 2) then
    // Assumes a checksum in packet
    begin
      xorSum := Ord(parseS[2]);
      for i := 3 to p - 1 do // Calculate checksum
        xorSum := xorSum xor Ord(parseS[i]);
      xorStr := IntToHex(xorSum, 2);
      if (UpperCase(xorStr) = Copy(parseS, p + 1, 2)) then // Checksum ok ?
      begin
        // Validate heading
        headingStr := Copy(parseS, 8, p - 10);
        Val(headingStr, heading, err);
        if (err <> 0) then
          Result := 4; // Not a valid float
      end
      else
        Result := 3; // Wrong checksum
    end
    else
      Result := 2; // No checksum
  end
  else
    Result := 1; // Wrong header
end;


procedure TMainForm.ComPortRxChar(Sender: TObject; Count: Integer);
var
  i,err: Integer;
  strBuf: AnsiString;
  heading: Double;
begin
  ComPort.ReadStr(CPort.Str, Count);
  strBuf := CPort.str;
  for i := 1 to Length(strBuf) do
    case strBuf[i] of
      '$' : 
        finalBuf := '$';  // Start of package
      #10 :
        begin
          if (finalBuf <> '') and (finalBuf[1] = '$') then  // Simple validate check 
            begin
              SetLength( finalBuf, Length(finalBuf) - 1); // Strips CR
              err := ParseAndCheckNMEA_HDT(finalBuf, heading);
              if (err = 0) then 
                Memo.Lines.Add(finalBuf); // Add validated string
              //else
              //  Memo.Lines.Add('Error:' + IntToStr(err)); 
            end;
          finalBuf := '';
        end; 
    else
      finalBuf := finalBuf + strBuf[i];  
    end;
end;

知道开始字符和数据包结束，这应该是相当安全的使用。标记包裹结束的#13 和#10 (CR LF) 字符被剥离，并检查包裹的有效校验和，并计算得到的标题值。然后将经过验证的字符串添加到备忘录中。

更新 2

要回答直接问题，为什么您的接收方法可以在数据字符串的中间添加您的“哈哈”字符串：

comport 例程以自己的节奏传递数据、一个或多个字符。您无法控制何时获取数据或将有多少字符。使用我的回答中的方案，数据会被缓冲，直到交付完整的包裹。借助 TComPort 的数据包支持，可以做到这一点。

根据您的评论，似乎有几种 NMEA 0183 传感器类型连接到串行端口。（给出其他长度的包，但都以 $ 字符开头）。

在这种情况下，将 ParseAndCheckNMEA_HDT 替换为以下函数以验证字符串：

Function ParseAndCheckNMEA(const parseS: AnsiString): Integer;
// Example packet: $HEHDT,10.17,T*28 + CRLF
var
  i, p: Integer;
  xorSum: Byte;
  xorStr: AnsiString;
begin
  Result := 0; // Assume ok
  if (Pos('$', parseS) = 1) then // Start header ok ?
  begin
    p := Pos('*', parseS);
    if (p <> 0) and (Length(parseS) >= p + 2) then
    // Assumes a checksum in packet
    begin
      xorSum := Ord(parseS[2]);
      for i := 3 to p - 1 do // Calculate checksum
        xorSum := xorSum xor Ord(parseS[i]);
      xorStr := IntToHex(xorSum, 2);
      if (UpperCase(xorStr) <> Copy(parseS, p + 1, 2)) then // Checksum ok ?
        Result := 3; // Wrong checksum
    end
    else
      Result := 2; // No checksum
  end
  else
    Result := 1; // Wrong header
end;
于 2012-04-05T07:07:12.223 回答
0

如果您使用 Dejan Crnila 的 ComPort 库，您应该查看该TComDataPacket组件，尤其是它的OnPacket和OnCustomStop事件。

更新： 这是一个代码示例。假设起始字符串始终相同，结束字符串以 ',T*' 开头，后跟两个字符（可能是 CRC 码）。如果该假设是错误的，则必须调整停止逻辑。

procedure TForm136.ComDataPacketCustomStop(Sender: TObject; const Str: string;
    var Pos: Integer);
begin
  Pos := System.Pos(',T*', Str);
  if (Pos > 0) then begin
    Inc(Pos, 4);
    if Pos <= Length(Str) then Exit;
  end;
  Pos := -1;
end;

procedure TForm136.FormCreate(Sender: TObject);
begin
  ComDataPacket.ComPort := ComPort;
  ComDataPacket.StartString := '$HEHDT,';
  ComDataPacket.OnCustomStop := ComDataPacketCustomStop;
end;
于 2012-04-04T08:31:38.023 回答