1

我正在使用 Haskell 和 gtk2hs 绑定在 GTK 中编写一个简单的计算器。我正在尝试使用 Glade 在 Windows 计算器中实现基本/科学视图。

我有一个 GTKTable 按钮，但是当我尝试隐藏其中一些按钮时，会在按钮所在的位置留下空白。要隐藏按钮，我有一些这样的代码：

bSqrt <- xmlGetWidget xml castToButton "bSqrt"
widgetHide bSqrt

但是当我隐藏我想要的四个按钮时，我在右侧有一个如下所示的间隙： 在此处输入图像描述

我是 GTK 的新手，在 java swing 中找不到像你这样的布局管理器。有没有更简单的方法来做到这一点？我可以以某种方式调用布局管理器来为我调整按钮的大小吗？我无法在文档中找到执行此操作的方法。

提前致谢，

4

1 回答 1

1

考虑使用HBox和VBox的嵌套组合来实现类似表格的效果。调用widgetHideAll“科学”按钮的 VBox 将隐藏该列并根据需要刷新显示。

import Control.Monad (forM_)
import Data.IORef as IORef
import qualified Graphics.UI.Gtk as Gtk

data Mode = Basic | Scientific

main = do
    Gtk.initGUI

    window <- Gtk.windowNew
    outerVbox <- Gtk.vBoxNew False 0

    -- Create a "table" of buttons as an HBox of VBoxes.
    hbox <- Gtk.hBoxNew True 5

    -- Load the "table" with dummy 'basic' buttons.
    forM_ [0..2] $ \i -> do
        vbox <- Gtk.vBoxNew False 5
        forM_ [0..2] $ \j -> do
            dummy <- Gtk.buttonNewWithLabel $ show (3*i+j :: Int)
            Gtk.boxPackStartDefaults vbox dummy
        Gtk.boxPackStartDefaults hbox vbox

    -- Load rightmost column with 'scientific' buttons.
    scibox <- Gtk.vBoxNew False 5
    forM_ [0..2] $ \j -> do
        dummy <- Gtk.buttonNewWithLabel $ "sci" ++ show (j :: Int)
        Gtk.boxPackStartDefaults scibox dummy
    Gtk.boxPackStartDefaults hbox scibox

    -- Begin in Scientific mode.
    let mode = Scientific
    modeRef <- IORef.newIORef mode

    -- Create a mode-toggling Button.
    button <- Gtk.buttonNewWithLabel $ getButtonText mode
    Gtk.on button Gtk.buttonActivated $
        toggleMode button modeRef scibox

    -- Pack the "table" and button vertically into window.
    Gtk.boxPackStartDefaults outerVbox hbox
    Gtk.boxPackStartDefaults outerVbox button
    Gtk.containerAdd window outerVbox

    -- Standard Gtk stuff.
    Gtk.onDestroy window Gtk.mainQuit
    Gtk.widgetShowAll window
    Gtk.mainGUI

getButtonText Basic = "Switch to Scientific"
getButtonText Scientific = "Switch to Basic"


toggleMode button modeRef scibox = do
    mode <- IORef.readIORef modeRef
    case mode of
        Basic -> do
            IORef.writeIORef modeRef Scientific
            Gtk.buttonSetLabel button $ getButtonText Scientific
            Gtk.widgetShowAll scibox
        Scientific -> do
            IORef.writeIORef modeRef Basic
            Gtk.buttonSetLabel button $ getButtonText Basic
            Gtk.widgetHideAll scibox
于 2011-12-05T06:52:40.960 回答