2

我正在尝试使用该功能加入两个视图“ A ”和“ B ”。op:join-left-outer

对于 JOIN，我有两个“开启条件”：

  1. 第一个是一个简单的op:on函数。（而不是我的问题的一部分）
  2. 第二个应该是按值 ( $myValue) 连接列的 ON 条件。但op:on不支持值，仅支持列引用。所以下面的代码不起作用：
let $aView := op:from-view("foobar", "A")
let $bView := op:from-view("foobar", "B")

let $myValue := "42"

let $opticQuery := op:join-left-outer(
  $aView, 
  $bView, 
  (
    op:on(op:view-col("A", "SOME_COLUMN"), op:view-col("B", "SOME_COLUMN")),
    
    (: Not working pseudo code following :)
    op:on(op:view-col("B", "SOME_OTHER_COLUMN"), $myValue)
  )
)

在 SQL 中，我会这样写：

SELECT * FROM A
LEFT JOIN B
ON A.SOME_COLUMN = B.SOME_COLUMN
AND B.SOME_OTHER_COLUMN = '42'

我的问题： 有没有办法在 Optic API 中做同样的事情，还是我做错了什么？

4

1 回答 1

2

有趣的是，当尝试op:on()在左侧和右侧使用第二个列引用时（通过将 42 绑定为 aView 上的新列），我也没有得到预期的结果。

但是，如果以不同的方式表达，Optic API 似乎确实允许您做您想做的事情：

因此，我希望您可以删除第二个op:on()并将以下内容用作第四个参数：op:eq(op:view-col("B", "SOME_OTHER_COLUMN"), $myValue)

下面是一个独立的示例 - 生成的第二行对于外部连接表具有空值

xquery version "1.0-ml";
import module namespace op="http://marklogic.com/optic"
 at "/MarkLogic/optic.xqy";

let $myVal := 42

let $plan-table-1 := op:from-literals((
        map:entry("col1", 1) => map:with("val", "a"),
        map:entry("col1", 2) => map:with("val", "b")
        ), "table1")     

let $plan-table-2 := op:from-literals((
        map:entry("col1", 1) => map:with("val2", "c") => map:with("someOtherCol", 42),
        map:entry("col1", 2) => map:with("val2", "d") => map:with("someOtherCol", 8)
        ), "table2")


return op:join-left-outer(
  $plan-table-1,
  $plan-table-2, 
  op:on(op:view-col("table1", "col1"), op:view-col("table2", "col1")), 
  op:eq(op:view-col("table2", "someOtherCol"), $myVal)
)=>op:result()
于 2022-01-13T14:48:36.267 回答