4

我不喜欢就组件的外观问太多问题，但是这些天在应用程序中的外观似乎同样重要。

无论如何，请看下面的图片：

在此处输入图像描述

两者都使用 TActionManager 和 TActionMainMenuBar 创建我的主菜单。图片左侧的菜单使用的是 Platform Default Style，右侧的菜单使用的是我的 TActionManager 定义的 XP 样式。

请注意，当左侧菜单突出显示时，字形保持不变，这是完美的。

现在看右边的XP风格菜单，字形画了一个阴影，稍微弹出来，可以看到透明度让字形显得有些奇怪。

我想为我的 UI 启用 XP 样式，但我不喜欢绘制字形的方式。我还想将我的 TToolbar 更改为 TActionToolBar 并应用相同的 XP 样式，但这也会呈现相同的字形。

如何制作 TActionManager 中定义的 XP 样式菜单，而不是像这样渲染字形？

谢谢。

编辑

这就是现在的结果，应用了以下答案中的一些技术：

在此处输入图像描述

克雷格。

4

2 回答 2

6

这是一些覆盖 XP STYLE 的示例代码，创建了一个您可以随意调整的派生类。第一步是替换您自己的派生菜单项类，并更改其 DrawGlyph 代码，正如 David 告诉您的那样。我想你也许可以使用一些示例代码。

这只是一个快速演示。它不会在带有字形的已检查项目周围绘制一个框，因此此自定义样式与已检查项目不兼容，除非它们没有字形。你必须弄清楚你想如何绘制选中的字形项目（如果设置了 Action.Checked 属性，我写的 DrawGlyphFrame 将是一个添加东西以在字形周围绘制选中状态矩形的好地方）。

unit MyActionControlStyle;

// Using this unit: Add it to your project. In your project set your
// style at runtime, add the unit to your uses clause and then set the style
// in that form's formcreate event:
//   ActionManager1.Style := MyActionControlStyle.MyStyle;

interface

uses Forms,
     Types,
     Controls,
     XPActnCtrls,
     XPStyleActnCtrls,
     ActnMan,
     ActnList,
     ActnMenus,
     ActnCtrls;

type

 TMyStyleMenuItem = class(TXPStyleMenuItem)
  protected
      procedure DrawGlyph(const Location: TPoint); override;

//      procedure DrawGlyphFrame(const Location:TPoint);

 end;
 TMyStyleMenuButton = class(TXPStyleMenuButton)
 end;

 TMyStyleActionBars = class(TXPStyleActionBars)
   // override the stuff that I want different than XP Style:
    function GetControlClass(ActionBar: TCustomActionBar;
      AnItem: TActionClientItem): TCustomActionControlClass; override;

 end;

var
 MyStyle:TMyStyleActionBars;

implementation


uses ToolWin, Classes, Windows, Graphics, GraphUtil, ImgList;
{ TMyStyleActionBars }

function TMyStyleActionBars.GetControlClass(ActionBar: TCustomActionBar;
  AnItem: TActionClientItem): TCustomActionControlClass;
begin
 if ActionBar is TCustomActionPopupMenu then
    Result := TMyStyleMenuItem
  else
  if ActionBar is TCustomActionMainMenuBar then
    Result := TMyStyleMenuButton
  else
    Result := inherited GetControlClass(ActionBar,AnItem);

end;

{ TMyStyleMenuItem }

procedure TMyStyleMenuItem.DrawGlyph(const Location: TPoint);
var
  ImageList: TCustomImageList;
  DrawEnabled: Boolean;
begin
//  DrawGlyphFrame(Location);
  if not HasGlyph and IsChecked then
  begin
    Canvas.Pen.Color := ActionBar.ColorMap.FontColor;
    DrawCheck(Canvas, Point((TextBounds.Left - 5) div 2, Height div 2), 2);
  end;

  if not HasGlyph then exit;
  if Assigned(Action) then
    ImageList := ActionClient.Action.ActionList.Images
  else
    ImageList := ActionClient.OwningCollection.ActionManager.Images;
  if not Assigned(ImageList) then exit;
  DrawEnabled := Enabled and (ActionClient.ImageIndex <> -1) or
    (csDesigning in ComponentState);
  ImageList.Draw(Canvas, Location.X, Location.Y, ActionClient.ImageIndex,
    dsTransparent, itImage, DrawEnabled);

end;

initialization
  MyStyle := TMyStyleActionBars.Create;
  RegisterActnBarStyle(MyStyle);
finalization
  UnregisterActnBarStyle(MyStyle);
  MyStyle.Free;
end.
于 2011-05-15T02:50:52.543 回答
1

这是在 VCL 代码中设计完成的。相关代码TXPStyleMenuItem.DrawGlyph()在 XPActnCtrls.pas 中。

更改行为的最简单方法是注册您自己的 XP 操作栏样式版本，基于TXPStyleActionBars. 有很多钩子可以让你覆盖TXPStyleMenuItem.DrawGlyph().

于 2011-05-14T21:52:12.693 回答