sml - ML : 匹配非穷举

Question

我想让函数命名为headcol：

headcol[[1,2],[3,4]] = [1,3]; 

所以我做了这样的功能：

fun headcol [] = [] 
  | headcol [x::xs',y::ys'] = [x,y]

但是当我调用它时，我会得到一个非穷尽的匹配。

Answer 1

IIUC，headcol将提取参数中的所有列表头，其类型为'a-list-list. 你的数学只是[]and [x::xs', y::ys']，而不是其他任何东西。因此，如果您的论点有 2 个以上的子列表，则 execption 将引发：

- headcol[[1,2],[3,4], [4, 5, 9]]; 

uncaught exception Match [nonexhaustive match failure]
  raised at: a.sml:9.34
- 

如果你只想处理两个元素的列表，pair 是更好的选择。否则，您应该匹配更多案例：

fun headcol list =
    case list of
        [] => []
      | x::xs' =>
        case x of
            [] => headcol xs'
         |  h::t => h::(headcol xs')

输出：

- headcol[[1,2],[3,4], [4, 5, 9]]; 
- val it = [1,3,4] : int list

Answer 2

正如陈力指出的那样，很难回答仅由函数名称及其尝试解决方案定义的问题。尽管如此，head听起来您想获取每个子列表的第一个元素，并且col听起来您将此列表列表视为矩阵，其中列与子列表正交。

递归解决方案也可能如下所示：

fun headcol [] = []
  | headcol ((x::_)::xss) = x :: headcol xss
  | headcol ([]::xss) = headcol xss

以下是使用内置高阶列表组合器的方法：

fun headcol xss =
    List.concat (List.map (fn xs => List.take (xs, 1)) xss)

我不只是这样做的原因：

fun headcol xss =
    List.map hd xss

是因为hd是偏函数，所以hd []会在运行时崩溃。

另一方面，List.take ([], 1)将返回[]。

并将List.concat临时结果[[1],[2],[3]]合并为[1,2,3].

或者，如果缺少一列，则[[1],[],[3]]进入[1,3].

测试用例：

val test_headcol_0 = headcol [] = []
val test_headcol_1 = headcol [[1]] = [1]
val test_headcol_2 = headcol [[1,2],[3,4]] = [1,3]
val test_headcol_3 = headcol [[1,2,3],[4,5,6],[7,8,9]] = [1,4,7]
val test_headcol_4 = headcol [[1],[2,3],[4,5,6]] = [1,2,4]
val test_headcol_5 = headcol [[1],[],[2,3]] = [1,2]

当然，headcol对于没有头列的不规则矩阵，我不知道这是否是您所期望的行为。这是一个你不会进入的极端案例。在函数式编程中，您经常将错误处理嵌入到返回值中，而不是抛出异常。

因此，例如，您可能希望 fromheadcol返回一个'a list optionwhereSOME [1,4,7]表明每一行确实有一个头列，并NONE表明至少有一行未能生成一列。

或者，您可以使用其他数据类型'a list list来表示不允许缺少列的行的矩阵，例如Array2。