41

我想将分号 ( ;) 上的地址拆分为由以下分隔的行<br />

例如如果address= 123 Elm Street,我想输出123 Elm Street

但如果address= 123 Elm Street;PO Box 222,我想输出

123 Elm Street<br />PO Box 222

如果address= 123 Elm Street;PO Box 222;c/o James Jones,我想输出

123 Elm Street<br />PO Box 222<br />c/o James Jones

有没有办法做到这一点?(可能很容易,但我对 XSLT 不太熟悉)

普通的 XSL 选择器是

<xsl:value-of select="address"/>

我想修改这个 XSLT 片段以分号分割。


更新:显然答案涉及使用<xsl:call-template>和功能substring-before()substring-after()

但我是 XSLT 的初学者,我真的可以使用一些帮助来完成这项工作。

4

2 回答 2

70

一、普通的 XSLT 1.0 解决方案:

这种转变

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:template match="text()" name="split">
  <xsl:param name="pText" select="."/>
  <xsl:if test="string-length($pText)">
   <xsl:if test="not($pText=.)">
    <br />
   </xsl:if>
   <xsl:value-of select=
    "substring-before(concat($pText,';'),';')"/>
   <xsl:call-template name="split">
    <xsl:with-param name="pText" select=
     "substring-after($pText, ';')"/>
   </xsl:call-template>
  </xsl:if>
 </xsl:template>
</xsl:stylesheet>

应用于此 XML 文档时

<t>123 Elm Street;PO Box 222;c/o James Jones</t>

产生想要的、更正的结果

123 Elm Street<br />PO Box 222<br />c/o James Jones

二、FXSL 1(用于 XSLT 1.0):

这里我们只是使用了FXSL模板str-map(不必第 999 次编写递归模板):

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:f="http://fxsl.sf.net/"
xmlns:testmap="testmap"
exclude-result-prefixes="xsl f testmap"
>
   <xsl:import href="str-dvc-map.xsl"/>

   <testmap:testmap/>

   <xsl:output omit-xml-declaration="yes" indent="yes"/>

   <xsl:template match="/">
     <xsl:variable name="vTestMap" select="document('')/*/testmap:*[1]"/>
     <xsl:call-template name="str-map">
       <xsl:with-param name="pFun" select="$vTestMap"/>
       <xsl:with-param name="pStr" select=
       "'123 Elm Street;PO Box 222;c/o James Jones'"/>
     </xsl:call-template>
   </xsl:template>

    <xsl:template name="replace" mode="f:FXSL"
         match="*[namespace-uri() = 'testmap']">
      <xsl:param name="arg1"/>

      <xsl:choose>
       <xsl:when test="not($arg1=';')">
        <xsl:value-of select="$arg1"/>
       </xsl:when>
       <xsl:otherwise><br /></xsl:otherwise>
      </xsl:choose>
    </xsl:template>
</xsl:stylesheet>

当将此转换应用于任何 XML 文档(未使用)时,会产生相同的、想要的正确结果

123 Elm Street<br/>PO Box 222<br/>c/o James Jones

三、使用 XSLT 2.0

<xsl:stylesheet version="2.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:template match="text()">
  <xsl:for-each select="tokenize(.,';')">
   <xsl:sequence select="."/>
   <xsl:if test="not(position() eq last())"><br /></xsl:if>
  </xsl:for-each>
 </xsl:template>
</xsl:stylesheet>

当将此转换应用于此 XML 文档时

<t>123 Elm Street;PO Box 222;c/o James Jones</t>

产生了想要的正确结果

123 Elm Street<br />PO Box 222<br />c/o James Jones
于 2011-01-30T22:10:06.827 回答
4

如果您的 XSLT 处理器支持EXSLT,则可以使用str:tokenize,否则,该链接包含使用 substring-before 之类的函数的实现。

于 2011-01-30T21:37:02.317 回答