6

我正在开发我的第一个 Cuda 应用程序，并且我有一个“低于预期吞吐量”的内核，这似乎是目前最大的瓶颈。

内核的任务是计算一个 N × N 大小的矩阵 ( DD)，其中包含数据矩阵上所有元素之间的平方距离。数据矩阵 ( Y) 的大小为 N × D（以支持多维数据）并存储为行优先。

来源：

__global__ void computeSquaredEuclideanDistance(const float * __restrict__ Y, float * __restrict__ DD, const int N, const int D) {
    int index = blockIdx.x * blockDim.x + threadIdx.x;
    int stride = blockDim.x * gridDim.x;

    for (int i = index; i < N * N; i += stride) {
        const int m = i / N;
        const int n = i % N;
        float tmp = 0;
        for (int d = 0; d < D; ++d) {
            const float Ynd = Y[d + D * n];
            const float Ymd = Y[d + D * m];
            const float Ydiff = Ynd - Ymd;
            tmp += Ydiff * Ydiff;
        }
        DD[n + N * m] = tmp;
    }
}

这是用size_t blockSize = 256and调用的size_t numBlocks = (N*N + blockSize - 1)/blockSize。

如何优化这个内核？我最初的想法是，耗时的部分是在不利用某种共享内存的情况下读取数据，但是谁能给我一些关于如何解决这个问题的指针？

nvvc分析工具的备注：

  • 延迟分析：
    • 计算利用率约为 40%
    • 内存（L2 缓存）利用率约为 35%
  • 入住不是问题
    • Active Warps 为 57.59，理论值为 64
    • 入住率为理论 100 的 90%

对于我的应用程序，典型值为：

  • 5k < N< 30k
  • D是 2 或 3
4

1 回答 1

6

我通常不理会这些类型的优化问题，因为在我看来，它们处于偏离主题的边缘。最糟糕的是，您没有提供MCVE，因此任何试图回答的人都必须编写自己的所有支持代码来编译和基准测试您的内核。而这类工作确实需要基准测试和代码分析。但是因为你的问题基本上是一个线性代数问题（我喜欢线性代数），所以我回答了它，而不是把它投票给它太宽泛了......

说完我的胸膛。有几件事会立即出现在代码中，可以改进，并且可能会对运行时间产生重大影响。

首先是内部循环的行程计数是先验已知的。任何时候遇到这样的情况，让编译器知道。循环展开和代码重新排序是一种非常强大的编译器优化，NVIDIA 编译器非常擅长它。如果将 D 移动到模板参数中，则可以执行以下操作：

template<int D>
__device__ float esum(const float *x, const float *y)
{
    float val = 0.f;
#pragma unroll
    for(int i=0; i<D; i++) { 
        float diff = x[i] - y[i];
        val += diff * diff;
    }
    return val;
}

template<int D>
__global__ 
void vdistance0(const float * __restrict__ Y, float * __restrict__ DD, const int N)
{
    int index = blockIdx.x * blockDim.x + threadIdx.x;
    int stride = blockDim.x * gridDim.x;
    for (int i = index; i < N * N; i += stride) {
        const int m = i / N;
        const int n = i % N;
        DD[n + N * m] = esum<D>(Y + D * n, Y + D * m);
    }
}

template __global__ void vdistance0<2>(const float *, float *, const int);
template __global__ void vdistance0<3>(const float *, float *, const int);

编译器将内联esum和展开内部循环，然后它可以使用其重新排序启发式来更好地交错加载和触发器以提高吞吐量。生成的代码也具有较低的寄存器占用空间。当我在 N=10000 和 D=2 的情况下运行它时，我得到了大约 35% 的速度提升（7.1ms 与 CUDA 9.1 的 GTX 970 上的 4.5ms）。

但是还有比这更明显的优化。您正在执行的计算将产生一个对称的输出矩阵。您只需要执行(N*N)/2计算完整矩阵的操作，而不是N*N您在代码中执行的操作[技术上N(N/2 -1)因为对角线条目为零，但为了讨论的目的，让我们忘记对角线]。

所以采用不同的方法并使用一个块来计算上三角输出矩阵的每一行，然后你可以这样做：

struct udiag
{
    float *p;
    int m;

    __device__ __host__ udiag(float *_p, int _m) : p(_p), m(_m) {};
    __device__ __host__ float* get_row(int i) { return p + (i * (i + 1)) / 2; };
};


template<int D>
__global__ 
void vdistance2(const float * __restrict__ Y, float * __restrict__ DD, const int N)
{
     int rowid = blockIdx.x;
     int colid = threadIdx.x;
     udiag m(DD, N);

     for(; rowid < N; rowid += gridDim.x) {
         float* p = m.get_row(rowid);
         const float* y = Y + D * rowid;
         for(int i=colid; i < (N-rowid); i += blockDim.x) {
             p[i] = esum<D>(y, y + D * i);
         }
    }
}
template __global__ void vdistance2<2>(const float *, float *, const int);
template __global__ void vdistance2<3>(const float *, float *, const int);

这使用一个小助手类来封装上三角输出矩阵的寻址方案所需的三角形数。这样做可以节省大量内存和内存带宽，并减少计算的总 FLOP 计数。如果您之后需要做其他事情，BLAS（和 CUBLAS）支持上三角矩阵或下三角矩阵的计算。使用它们。当我运行它时，我得到了大约 75% 的加速（在同一 GTX 970 上为 7.1 毫秒与 1.6 毫秒）。

巨大的免责声明：您在这里看到的所有代码都是在 45 分钟的午休时间编写的，并且经过了非常轻微的测试。我绝对没有声称这个答案中的任何内容实际上都是正确的。我已经确认它可以编译并且在我运行它以获取分析数据时不会产生运行时错误。这就对了。Cavaet Emptor等等。

于 2018-01-03T13:12:27.277 回答