2

我有一个类似的本体：

:indi_1 a :Segment; a [ :builds only {:indi_2}]; :hasID 1.

现在我想找到indi_1建造的个人。我做了以下查询：

SELECT distinct ?a
WHERE {:indi_1 a ?b. ?b a _:blankNode}

但我仍然在我的结果中得到这个部分。另外，我无法到达空白节点内部来检索indi_2.

我应该如何构建我的查询？

4

1 回答 1

4

我不知道你为什么期望?ba :blankNode要求?b是一个空白节点。 :blankNode是一个空白节点，它在像这样的 SPARQL 查询中充当变量，因此它只要求?b具有某种类型。您的书面查询甚至不合法。它看起来像你想要:indi_1 a ?b . ?b a _:blankNode的（注意.，而不是 a ;）。

无论如何，要检查某个东西是否为空白节点，请查看SPARQL 1.1 规范，并注意有一个isBlank函数。这就是您用来过滤结果的方法。你会有这样的事情：

select * {
  ?a a ?b 
  filter isBlank(?b)
}

但是，如果您真正要查找的是个人列表，那么您实际上需要更仔细地查看数据的 RDF 序列化。您实际上并不关心?b是否为空白，而是它是具有正确属性的限制。从如下公理：

    :a 仅构建 {:b, :c}

你最终得到这样的RDF：

:a      a       owl:NamedIndividual , owl:Thing ;
        a       [ a                  owl:Restriction ;
                  owl:allValuesFrom  [ a          owl:Class ;
                                       owl:oneOf  ( :c :b )
                                     ] ;
                  owl:onProperty     :builds
                ] .

所以你的查询是：

prefix :      <http://www.example.org/>
prefix owl:   <http://www.w3.org/2002/07/owl#>
prefix rdf:   <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
prefix rdfs:  <http://www.w3.org/2000/01/rdf-schema#>

select ?x ?y {
  ?x a [ owl:allValuesFrom [ owl:oneOf/rdf:rest*/rdf:first ?y ] ] .
}

-----------
| x  | y  |
===========
| :a | :c |
| :a | :b |
-----------

你可以用更多的属性路径来清理它：

select ?x ?y {
  ?x rdf:type/owl:allValuesFrom/owl:oneOf/rdf:rest*/rdf:first ?y .
}

OWL 与 RDF 不同。SPARQL 是一种 RDF 查询语言。OWL 可以序列化为 RDF，但序列化并不总是那么漂亮，因此 SPARQL 不一定是查询 OWL 的最佳方式，即使 OWL 可以序列化为 RDF。这有点像通过搜索文件中的特定字节或位来搜索文档中的文本。它可能有效，但如果有人要更改字符编码，您可能拥有相同的text，但字节或位不同，因此查询可能不再有效。

于 2017-07-25T14:51:59.083 回答