0

在下面的示例中，您可以看到应用程序在红色背景矩形 (512x260) 上水平并排绘制了两个 256x256 像素的位图（黄色和蓝色）（0-255 和 256-511）。没有缩放。问题是，为什么在两者之间可以看到背景（红色）的垂直像素线？德尔福 10.1 

unit Unit1;

interface

uses
  System.SysUtils, System.Types, System.UITypes, System.Classes,
    System.Variants,
  FMX.Types, FMX.Controls, FMX.Forms, FMX.Graphics, FMX.Dialogs, FMX.Objects,
  FMX.Controls.Presentation, FMX.StdCtrls;

type
  TForm1 = class(TForm)
    PaintBox1: TPaintBox;
    procedure PaintBox1Paint(Sender: TObject; Canvas: TCanvas);
    procedure FormCreate(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
  private
    { Private declarations }
    bm1: TBitmap;
    bm2: TBitmap;
    br: TStrokeBrush;
    bShift: Boolean;
  public
    { Public declarations }
  end;

var
  Form1: TForm1;

implementation

{$R *.fmx}

procedure TForm1.FormCreate(Sender: TObject);
begin
  bm1 := TBitmap.Create(256, 256);
  if bm1.Canvas.BeginScene then
    try
      bm1.Canvas.Fill.Color := TAlphaColorRec.Yellow;
      bm1.Canvas.FillRect(RectF(0, 0, bm1.Width, bm1.Height
        ),
        0, 0, AllCorners, 1);
    finally
      bm1.Canvas.EndScene;
    end;
  bm2 := TBitmap.Create(256, 256);
  if bm2.Canvas.BeginScene then
    try
      bm2.Canvas.Fill.Color := TAlphaColorRec.Blue;
      bm2.Canvas.FillRect(RectF(0, 0, bm2.Width, bm2.Height
        ),
        0, 0, AllCorners, 1);
    finally
      bm2.Canvas.EndScene;
    end;

end;

procedure TForm1.FormDestroy(Sender: TObject);
begin
  bm1.Free;
  bm2.Free;
end;

procedure TForm1.PaintBox1Paint(Sender: TObject; Canvas: TCanvas);
var
  RecPic: TRectF;
  RecCanvas: TRectF;
  RecCanvas2: TRectF;
begin
  if Canvas.BeginScene then
    try
      Canvas.Fill.Color := TAlphaColorRec.White;
      Canvas.FillRect(RectF(0, 0, PaintBox1.Width, PaintBox1.Height
        ),
        0, 0, AllCorners, 1);

      Canvas.Fill.Color := TAlphaColorRec.Red;
      Canvas.FillRect(RectF(0, 0, 511, 260
        ),
        0, 0, AllCorners, 1);
      RecPic := RectF(0, 0, 255, 255);
      RecCanvas := RectF(0, 0, 255, 255);
      Canvas.DrawBitmap(bm1, RecPic, RecCanvas, 1);

      RecCanvas2 := RectF(256, 0, 511, 255);
      Canvas.DrawBitmap(bm2, RecPic, RecCanvas2, 1);
    finally
      Canvas.EndScene;
    end;
end;

end.

非常感谢

4

1 回答 1

0

您必须将 RecCanvas 用作 RectF(0, 0, 256, 256) 并将 RecCanvas2 用作 RectF(256, 0, 512, 256)，因为位图绘图区域不包括右边框和下边框

于 2016-09-03T10:02:46.303 回答