4

我在 Delphi 10.1 Berlin 下使用 FireDac。

为了向用户显示数据，我使用 TDBEdit 等数据感知控件。

我使用 TFDQuery 和 TDataSource 将它们与控件链接起来。

这可行，但需要一些时间才能执行的长 sql 查询会冻结 GUI。

我想知道如何在执行那些长时间运行的查询时阻止 gui 冻结。

我在考虑后台线程。

在 wiki 上，我读到 FireDac 可以使用多线程： http://docwiki.embarcadero.com/RADStudio/XE6/en/Multithreading_(FireDAC)

然而，在 embarcadero 社区论坛线程Jeff Overcash 中写道：

我没有看到询问或 Dmitry 提到的一件事是，您不能针对后台线程查询使用 TDataSource 或 LiveBindings。如果您在后台处理显示结果的查询，您应该断开 LB 或 DataSource，打开并获取所有数据，然后重新建立连接。

这两个将尝试将光标移动到您身上或查询缓冲区以进行显示，而缓冲区非常不稳定，正在不同的线程中移动。

我想知道是否有人也使用 FireDac 并在表单上显示值可以帮助我。

4

1 回答 1

5

下面的代码示例显示了一种使用 FireDAC 在后台线程中从 MSSql 服务器检索记录的方法。这省略了一些细节。例如，在实践中，不是TQueryThreadsExecute只打开一次查询然后终止，您可能希望线程Execute包含一个 while 循环，在该循环中它在调用后等待信号量Synchronize然后关闭/重新打开查询尽可能频繁地更新主线程。

type

  TForm1 = class;

  TQueryThread = class(TThread)
  private
    FConnection: TFDConnection;
    FQuery: TFDQuery;
    FForm: TForm1;
  published
    constructor Create(AForm : TForm1);
    destructor Destroy; override;
    procedure Execute; override;
    procedure TransferData;
    property Query : TFDQuery read FQuery;
    property Connection : TFDConnection read FConnection;
    property Form : TForm1 read FForm;
  end;

  TForm1 = class(TForm)
    FDConnection1: TFDConnection;
    FDQuery1: TFDQuery;
    DataSource1: TDataSource;
    DBGrid1: TDBGrid;
    DBNavigator1: TDBNavigator;
    Button1: TButton;
    procedure Button1Click(Sender: TObject);
    procedure FormCreate(Sender: TObject);
  public
    QueryThread : TQueryThread;
  end;

[...]

constructor TQueryThread.Create(AForm : TForm1);
begin
  inherited Create(True);
  FreeOnTerminate := True;
  FForm := AForm;
  FConnection := TFDConnection.Create(Nil);
  FConnection.Params.Assign(Form.FDConnection1.Params);
  FConnection.LoginPrompt := False;

  FQuery := TFDQuery.Create(Nil);
  FQuery.Connection := Connection;
  FQuery.SQL.Text := Form.FDQuery1.SQL.Text;
end;

destructor TQueryThread.Destroy;
begin
  FQuery.Free;
  FConnection.Free;
  inherited;
end;

procedure TQueryThread.Execute;
begin
  Query.Open;
  Synchronize(TransferData);
end;

procedure TQueryThread.TransferData;
begin
  Form.FDQuery1.DisableControls;
  Form.FDQuery1.Data := Query.Data;
  Form.FDQuery1.EnableControls;
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
  QueryThread.Resume;
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
  QueryThread := TQueryThread.Create(Self);
end;

MJN 关于书签的评论告诉您如何在 gui 中保留当前数据行位置。

顺便说一句，虽然我经常使用 TClientDataSets 完成此操作，但将这个答案放在一起是我第一次尝试使用 FireDAC。在配置组件方面，我所做的只是将组件拖出 Palette，按照您的预期“将它们连接在一起”，然后设置 FDConnection 的 Params 和 FDQuery 的 Sql。

于 2016-06-15T11:47:40.993 回答