首先，我将演示如何转换批处理文件参数%1并将结果打印到屏幕上。
电源外壳
最简单的解决方案是使用 PowerShell。我在Sergey Babkin的 MSDN 博客上找到了以下代码
$long_path = (Get-Item -LiteralPath $path).FullName
将该代码放入批处理脚本并打印结果很简单：
@echo off
powershell "(Get-Item -LiteralPath '%~1').FullName"
但是，出于两个原因，我尽量避免在批处理中使用 PowerShell
- PowerShell 不是 XP 原生的
- PowerShell 的启动时间相当长，因此它使批处理混合相对较慢
CSCRIPT（JScript 或 VBS）
我在Computer Hope 论坛上找到了这个 VBS 片段，它使用虚拟快捷方式从短格式转换为长格式。
set oArgs = Wscript.Arguments
wscript.echo LongName(oArgs(0))
Function LongName(strFName)
Const ScFSO = "Scripting.FileSystemObject"
Const WScSh = "WScript.Shell"
With WScript.CreateObject(WScSh).CreateShortcut("dummy.lnk")
.TargetPath = CreateObject(ScFSO).GetFile(strFName)
LongName = .TargetPath
End With
End Function
我在Microsoft 新闻组存档和旧的 vbscript 论坛中发现了类似的代码。
该代码仅支持文件路径，并且在批处理中嵌入 JScript 会更容易一些。在转换为 JScript 并添加异常处理程序以在文件失败时获取文件夹后，我得到以下混合代码：
@if (@X)==(@Y) @end /* Harmless hybrid line that begins a JScript comment
::----------- Batch Code-----------------
@echo off
cscript //E:JScript //nologo "%~f0" %1
exit /b
------------ JScript Code---------------*/
var shortcut = WScript.CreateObject("WScript.Shell").CreateShortcut("dummy.lnk");
var fso = new ActiveXObject("Scripting.FileSystemObject");
var folder='';
try {
shortcut.TargetPath = fso.GetFile(WScript.Arguments(0));
}
catch(e) {
try {
shortcut.TargetPath = fso.GetFolder(WScript.Arguments(0));
folder='\\'
}
catch(e) {
WScript.StdErr.WriteLine(e.message);
WScript.Quit(1);
}
}
WScript.StdOut.WriteLine(shortcut.TargetPath+folder);
纯批次
令人惊讶的是，我的网络搜索未能找到纯批处理解决方案。所以我独自一人。
如果你知道路径代表一个文件，那么使用dir /b "yourFilePath". 但是，这并不能解析父文件夹的名称。
如果路径代表一个文件夹，情况会更糟。仅使用 DIR 命令无法列出特定文件夹 - 它始终列出文件夹的内容而不是文件夹名称本身。
我尝试了多种策略来处理文件夹路径，但都没有奏效：
- CD 或 PUSHD 到路径，然后查看提示 - 它保留了短文件夹名称
- 带有 /L 和 /F 选项的 XCOPY - 它还保留短文件夹名称
- 参数或 FOR 变量修饰符
%~f1或%%~fA- 保留短名称
- FORFILES - 似乎不支持短名称。
我能想出的唯一解决方案是使用 DIR 迭代地转换路径中的每个文件夹，一次一个。这要求我使用DIR /X /B /AD列出父文件夹中的所有文件夹，包括它们的 8.3 名称，然后使用 FINDSTR 找到正确的短文件夹名称。<DIR>我依赖于这样一个事实，即短文件名总是出现在文本之后的完全相同的位置。一旦找到正确的行，我就可以使用变量子字符串或查找/替换操作，或 FOR /F 来解析出长文件夹名称。我选择使用 FOR /F。
我遇到的另一个绊脚石是确定原始路径是代表文件还是文件夹。IF EXIST "yourPath\" echo FOLDER如果路径涉及符号链接或连接，则经常使用的附加反斜杠和使用不当的方法将文件报告为文件夹，这在公司网络环境中很常见。
我选择使用https://stackoverflow.com/a/1466528/1012053IF EXIST "yourPath\*"上的。
但也可以使用 FOR 变量%%~aF属性修饰符来查找d（目录）属性，该属性位于https://stackoverflow.com/a/3728742/1012053和https://stackoverflow.com/a/8669636/ 1012053。
所以这是一个完全工作的纯批处理解决方案
@echo off
setlocal disableDelayedExpansion
:: Validate path
set "test=%~1"
if "%test:**=%" neq "%test%" goto :err
if "%test:?=%" neq "%test%" goto :err
if not exist "%test%" goto :err
:: Initialize
set "returnPath="
set "sourcePath=%~f1"
:: Resolve file name, if present
if not exist "%~1\*" (
for /f "eol=: delims=" %%F in ('dir /b "%~1"') do set "returnPath=%%~nxF"
set "sourcePath=%~f1\.."
)
:resolvePath :: one folder at a time
for %%F in ("%sourcePath%") do (
if "%%~nxF" equ "" (
for %%P in ("%%~fF%returnPath%") do echo %%~P
exit /b 0
)
for %%P in ("%sourcePath%\..") do (
for /f "delims=> tokens=2" %%A in (
'dir /ad /x "%%~fP"^|findstr /c:"> %%~nxF "'
) do for /f "tokens=1*" %%B in ("%%A") do set "returnPath=%%C\%returnPath%"
) || set "returnPath=%%~nxF\%returnPath%"
set "sourcePath=%%~dpF."
)
goto :resolvePath
:err
>&2 echo Path not found
exit /b 1
如果有很多文件夹，用于迭代单个文件夹的 GOTO 会减慢操作速度。如果我真的想优化速度，我可以使用 FOR /F 调用另一个批处理，并在无限FOR /L %%N IN () DO...循环中解析每个文件夹，并EXIT在到达根目录后使用它来跳出循环。但我没有打扰。
开发可以在变量中返回结果的强大实用程序
鉴于 、 和 都是文件/文件夹名称中的合法字符，有许多边缘情况可能会使健壮脚本的开发^复杂%化!。
CALL 双引号^字符。这个问题没有很好的解决方案，除了使用变量而不是字符串文字通过引用传递值。如果输入路径仅使用短名称，这不是问题。但如果路径混合使用短名称和长名称，则可能会出现问题。
%在批处理参数中传递文字可能很棘手。对于应该将其翻倍的次数（如果有的话）可能会令人困惑。同样，在变量中通过引用传递值可能更容易。
CALLer 可以从 FOR 循环中调用该实用程序。如果变量或参数包含%，则实用程序中循环的扩展%var%或%1循环内可能导致无意的 FOR 变量扩展，因为 FOR 变量在范围内是全局的。该实用程序不得在 FOR 循环中扩展参数，并且如果使用延迟扩展，则只能在 FOR 循环中安全地扩展变量。
!如果启用延迟扩展，包含 FOR 变量的扩展将被破坏。
CALLing 环境可能已启用或禁用延迟扩展。将包含!和^跨越 ENDLOCAL 屏障的值传递到延迟扩展环境需要将引用的!值转义为^!. 此外，quoted^必须转义为^^，但前提是该行包含!。当然，如果 CALLing 环境已禁用延迟扩展，则不应转义这些字符。
我开发了 JScript 和纯批处理解决方案的强大实用程序形式，它们考虑了上述所有边缘情况。
/V默认情况下，实用程序期望路径为字符串文字，但如果使用该选项，则接受包含路径的变量名。
默认情况下，实用程序只需将结果打印到标准输出。但是，如果您将返回变量的名称作为额外参数传递，则结果可以在变量中返回。无论在 CALLing 环境中启用还是禁用延迟扩展，都保证返回正确的值。
完整的文档嵌入在实用程序中，可以使用该/?选项进行访问。
有一些模糊的限制：
- 返回变量名称不能包含
!或%字符
- 同样，
/V选项输入变量名称不得包含!或%字符。
- 输入路径不得包含内部双引号。可以用一组双引号将路径括起来，但其中不应有任何额外的引号。
我还没有测试过这些实用程序是否可以在路径名中使用 unicode，或者它们是否可以使用 UNC 路径。
jLongPath.bat - 混合 JScript / 批处理
@if (@X)==(@Y) @end /* Harmless hybrid line that begins a JScript comment
:::
:::jLongPath [/V] SrcPath [RtnVar]
:::jLongPath /?
:::
::: Determine the absolute long-name path of source path SrcPath
::: and return the result in variable RtnVar.
:::
::: If RtnVar is not specified, then print the result to stderr.
:::
::: If option /V is specified, then SrcPath is a variable that
::: contains the source path.
:::
::: If the first argument is /?, then print this help to stdout.
:::
::: The returned ERROLEVEL is 0 upon success, 1 if failure.
:::
::: jLongPath.bat version 1.0 was written by Dave Benham
:::
::----------- Batch Code-----------------
@echo off
setlocal disableDelayedExpansion
if /i "%~1" equ "/?" (
for /f "tokens=* delims=:" %%A in ('findstr "^:::" "%~f0"') do @echo(%%A
exit /b 0
)
if /i "%~1" equ "/V" shift /1
(
for /f "delims=* tokens=1,2" %%A in (
'cscript //E:JScript //nologo "%~f0" %*'
) do if "%~2" equ "" (echo %%A) else (
endlocal
if "!!" equ "" (set "%~2=%%B" !) else set "%~2=%%A"
)
) || exit /b 1
exit /b 0
------------ JScript Code---------------*/
try {
var shortcut = WScript.CreateObject("WScript.Shell").CreateShortcut("dummy.lnk"),
fso = new ActiveXObject("Scripting.FileSystemObject"),
path=WScript.Arguments(0),
folder='';
if (path.toUpperCase()=='/V') {
var env=WScript.CreateObject("WScript.Shell").Environment("Process");
path=env(WScript.Arguments(1));
}
try {
shortcut.TargetPath = fso.GetFile(path);
}
catch(e) {
shortcut.TargetPath = fso.GetFolder(path);
folder='\\'
}
var rtn = shortcut.TargetPath+folder+'*';
WScript.StdOut.WriteLine( rtn + rtn.replace(/\^/g,'^^').replace(/!/g,'^!') );
}
catch(e) {
WScript.StdErr.WriteLine(
(e.number==-2146828283) ? 'Path not found' :
(e.number==-2146828279) ? 'Missing path argument - Use jLongPath /? for help.' :
e.message
);
}
longPath.bat - 纯批处理
:::
:::longPath [/V] SrcPath [RtnVar]
:::longPath /?
:::
::: Determine the absolute long-name path of source path SrcPath
::: and return the result in variable RtnVar.
:::
::: If RtnVar is not specified, then print the result to stderr.
:::
::: If option /V is specified, then SrcPath is a variable that
::: contains the source path.
:::
::: If the first argument is /?, then prints this help to stdout.
:::
::: The returned ERROLEVEL is 0 upon success, 1 if failure.
:::
::: longPath.bat version 1.0 was written by Dave Benham
:::
@echo off
setlocal disableDelayedExpansion
:: Load arguments
if "%~1" equ "" goto :noPath
if "%~1" equ "/?" (
for /f "tokens=* delims=:" %%A in ('findstr "^:::" "%~f0"') do @echo(%%A
exit /b 0
)
if /i "%~1" equ "/V" (
setlocal enableDelayedExpansion
if "%~2" equ "" goto :noPath
if not defined %~2!! goto :notFound
for /f "eol=: delims=" %%F in ("!%~2!") do (
endlocal
set "sourcePath=%%~fF"
set "test=%%F"
)
shift /1
) else (
set "sourcePath=%~f1"
set "test=%~1"
)
:: Validate path
if "%test:**=%" neq "%test%" goto :notFound
if "%test:?=%" neq "%test%" goto :notFound
if not exist "%test%" goto :notFound
:: Resolve file name, if present
set "returnPath="
if not exist "%sourcePath%\*" (
for /f "eol=: delims=" %%F in ('dir /b "%sourcePath%"') do set "returnPath=%%~nxF"
set "sourcePath=%sourcePath%\.."
)
:resolvePath :: one folder at a time
for /f "delims=* tokens=1,2" %%R in (^""%returnPath%"*"%sourcePath%"^") do (
if "%%~nxS" equ "" for %%P in ("%%~fS%%~R") do (
if "%~2" equ "" (
echo %%~P
exit /b 0
)
set "returnPath=%%~P"
goto :return
)
for %%P in ("%%~S\..") do (
for /f "delims=> tokens=2" %%A in (
'dir /ad /x "%%~fP"^|findstr /c:"> %%~nxS "'
) do for /f "tokens=1*" %%B in ("%%A") do set "returnPath=%%C\%%~R"
) || set "returnPath=%%~nxS\%%~R"
set "sourcePath=%%~dpS."
)
goto :resolvePath
:return
set "delayedPath=%returnPath:^=^^%"
set "delayedPath=%delayedPath:!=^!%"
for /f "delims=* tokens=1,2" %%A in ("%delayedPath%*%returnPath%") do (
endlocal
if "!!" equ "" (set "%~2=%%A" !) else set "%~2=%%B"
exit /b 0
)
:noPath
>&2 echo Missing path argument - Use longPath /? for help.
exit /b 1
:notFound
>&2 echo Path not found
exit /b 1